Haskell Language
Monoid

Instancja Monoid dla list

instance Monoid [a] where
    mempty  = []
    mappend = (++)

Sprawdzanie praw Monoid dla tego wystąpienia:

mempty `mappend` x = x   <->   [] ++ xs = xs  -- prepending an empty list is a no-op

x `mappend` mempty = x   <->   xs ++ [] = xs  -- appending an empty list is a no-op

x `mappend` (y `mappend` z) = (x `mappend` y) `mappend` z
    <->
xs ++ (ys ++ zs) = (xs ++ ys) ++ zs           -- appending lists is associative

Zwijanie listy monoidów w jedną wartość

mconcat :: [a] -> a to kolejna metoda klasy Monoid :

ghci> mconcat [Sum 1, Sum 2, Sum 3]
Sum {getSum = 6}
ghci> mconcat ["concat", "enate"]
"concatenate"

Jego domyślna definicja to mconcat = foldr mappend mempty .

Monoidy numeryczne

Liczby są monoidalne na dwa sposoby: dodając 0 jako jednostkę i mnożąc przez 1 jako jednostkę. Oba są równie ważne i przydatne w różnych okolicznościach. Zamiast wybierać preferowane wystąpienie liczb, istnieją dwa nowe newtypes , Sum i Product aby oznaczyć je różnymi funkcjami.

newtype Sum n = Sum { getSum :: n }

instance Num n => Monoid (Sum n) where
    mempty = Sum 0
    Sum x `mappend` Sum y = Sum (x + y)

newtype Product n = Product { getProduct :: n }

instance Num n => Monoid (Product n) where
    mempty = Product 1
    Product x `mappend` Product y = Product (x * y)

Pozwala to skutecznie programistom na wybór funkcji, która ma być użyta, poprzez zawinięcie wartości w odpowiedni newtype .

Sum 3     <> Sum 5     == Sum 8
Product 3 <> Product 5 == Product 15

Instancja Monoid dla ()

() to Monoid . Ponieważ istnieje tylko jedna wartość type () , istnieje tylko jedna rzecz, mappend mogą zrobić mempty i mappend :

instance Monoid () where
    mempty = ()
    () `mappend` () = ()