Haskell Language
Monoid

Экземпляр Monoid для списков

instance Monoid [a] where
    mempty  = []
    mappend = (++)

Проверка законов Monoid для этого экземпляра:

mempty `mappend` x = x   <->   [] ++ xs = xs  -- prepending an empty list is a no-op

x `mappend` mempty = x   <->   xs ++ [] = xs  -- appending an empty list is a no-op

x `mappend` (y `mappend` z) = (x `mappend` y) `mappend` z
    <->
xs ++ (ys ++ zs) = (xs ++ ys) ++ zs           -- appending lists is associative

Свертывание списка моноидов в одно значение

mconcat :: [a] -> a это еще один метод Monoid класса типов :

ghci> mconcat [Sum 1, Sum 2, Sum 3]
Sum {getSum = 6}
ghci> mconcat ["concat", "enate"]
"concatenate"

Его определение по умолчанию - mconcat = foldr mappend mempty .

Числовые моноиды

Числа являются моноидальными двумя способами: добавлением с 0 в качестве единицы измерения и умножением на 1 в качестве единицы. Оба они одинаково важны и полезны в разных обстоятельствах. Поэтому вместо того, чтобы выбирать предпочтительный экземпляр для чисел, есть два типа newtypes , Sum и Product чтобы пометить их для разных функций.

newtype Sum n = Sum { getSum :: n }

instance Num n => Monoid (Sum n) where
    mempty = Sum 0
    Sum x `mappend` Sum y = Sum (x + y)

newtype Product n = Product { getProduct :: n }

instance Num n => Monoid (Product n) where
    mempty = Product 1
    Product x `mappend` Product y = Product (x * y)

Это позволяет разработчику выбирать, какую функциональность использовать, обертывая значение в соответствующем newtype .

Sum 3     <> Sum 5     == Sum 8
Product 3 <> Product 5 == Product 15

Экземпляр Monoid for ()

() является Monoid . Поскольку существует только одно значение типа () , есть только одна вещь mempty и mappend могли бы сделать:

instance Monoid () where
    mempty = ()
    () `mappend` () = ()