Haskell Language
Rury

Uwagi

Producenci

Producer to pewna monadyczna akcja, która może yield wartości dla dalszego zużycia:

type Producer b = Proxy X () () b
yield :: Monad m => a -> Producer a m ()

Na przykład:

naturals :: Monad m => Producer Int m ()
naturals = each [1..] -- each is a utility function exported by Pipes

Możemy oczywiście mieć Producer które są również funkcjami innych wartości:

naturalsUntil :: Monad m => Int -> Producer Int m ()
naturalsUntil n = each [1..n]

Konsumenci

Consumer może jedynie await wartości z wyższego szczebla.

type Consumer a = Proxy () a () X
await :: Monad m => Consumer a m a

Na przykład:

fancyPrint :: MonadIO m => Consumer String m ()
fancyPrint = forever $ do
  numStr <- await
  liftIO $ putStrLn ("I received: " ++ numStr)

Rury

Rury mogą zarówno await jak i yield .

type Pipe a b = Proxy () a () b

Ta rura oczekuje na Int i konwertuje ją na String :

intToStr :: Monad m => Pipe Int String m ()
intToStr = forever $ await >>= (yield . show)

Rurociągi z runEffect

Używamy runEffect do uruchamiania naszej Pipe :

main :: IO ()
main = do
  runEffect $ naturalsUntil 10 >-> intToStr >-> fancyPrint

Zauważ, że runEffect wymaga Effect , który jest samodzielnym Proxy bez żadnych danych wejściowych lub wyjściowych:

runEffect :: Monad m => Effect m r -> m r
type Effect = Proxy X () () X

(gdzie X jest pustym typem, znanym również jako Void ).

Rury łączące

Użyj >-> aby połączyć Producer , Consumer i Pipe aby utworzyć większe funkcje Pipe .

printNaturals :: MonadIO m => Effect m ()
printNaturals = naturalsUntil 10 >-> intToStr >-> fancyPrint

Producer typy Producer , Consumer , Pipe i Effect są zdefiniowane w kategoriach ogólnego typu Proxy . Dlatego >-> można wykorzystać do różnych celów. Typy zdefiniowane przez lewy argument muszą pasować do typu używanego przez prawy argument:

(>->) :: Monad m => Producer b m r -> Consumer b   m r -> Effect       m r
(>->) :: Monad m => Producer b m r -> Pipe     b c m r -> Producer   c m r
(>->) :: Monad m => Pipe   a b m r -> Consumer b   m r -> Consumer a   m r
(>->) :: Monad m => Pipe   a b m r -> Pipe     b c m r -> Pipe     a c m r

Transformator monad proxy

Podstawowym typem danych pipes jest monadowy transformator Proxy . Pipe , Producer , Consumer itd. Są zdefiniowani w kategoriach Proxy .

Ponieważ Proxy jest transformatorem monadowym, definicje Pipe przybierają formę skryptów monadycznych, które await i yield wartości, dodatkowo wykonując efekty z podstawowej monady m .

Łączenie rur i komunikacja sieciowa

Rury obsługują prostą komunikację binarną między klientem a serwerem

W tym przykładzie:

1. klient łączy się i wysyła FirstMessage
2. serwer odbiera i odpowiada DoSomething 0
3. klient otrzymuje i odpowiada DoNothing
4. kroki 2 i 3 są powtarzane w nieskończoność

Typ danych polecenia wymieniany przez sieć:

-- Command.hs
{-# LANGUAGE DeriveGeneric #-}
module Command where
import Data.Binary
import GHC.Generics (Generic)

data Command = FirstMessage
           | DoNothing
           | DoSomething Int
           deriving (Show,Generic)

instance Binary Command

Tutaj serwer czeka na połączenie klienta:

module Server where

import Pipes 
import qualified Pipes.Binary as PipesBinary
import qualified Pipes.Network.TCP as PNT
import qualified Command as C
import qualified Pipes.Parse as PP
import qualified Pipes.Prelude as PipesPrelude

pageSize :: Int
pageSize = 4096

-- pure handler, to be used with PipesPrelude.map
pureHandler :: C.Command -> C.Command 
pureHandler c = c  -- answers the same command that we have receveid

-- impure handler, to be used with PipesPremude.mapM
sideffectHandler :: MonadIO m => C.Command -> m C.Command
sideffectHandler c = do
  liftIO $ putStrLn $ "received message = " ++ (show c)
  return $ C.DoSomething 0    
  -- whatever incoming command `c` from the client, answer DoSomething 0

main :: IO ()
main = PNT.serve (PNT.Host "127.0.0.1") "23456" $
  \(connectionSocket, remoteAddress) -> do
                 putStrLn $ "Remote connection from ip = " ++ (show remoteAddress)
                 _ <- runEffect $ do
                   let bytesReceiver = PNT.fromSocket connectionSocket pageSize
                   let commandDecoder = PP.parsed PipesBinary.decode bytesReceiver
                   commandDecoder >-> PipesPrelude.mapM sideffectHandler >-> for cat PipesBinary.encode >-> PNT.toSocket connectionSocket
                   -- if we want to use the pureHandler
                   --commandDecoder >-> PipesPrelude.map pureHandler >-> for cat PipesBinary.Encode >-> PNT.toSocket connectionSocket
                 return ()

Klient łączy się w ten sposób:

module Client where

import Pipes
import qualified Pipes.Binary as PipesBinary
import qualified Pipes.Network.TCP as PNT
import qualified Pipes.Prelude as PipesPrelude
import qualified Pipes.Parse as PP
import qualified Command as C

pageSize :: Int
pageSize = 4096

-- pure handler, to be used with PipesPrelude.amp
pureHandler :: C.Command -> C.Command 
pureHandler c = c  -- answer the same command received from the server

-- inpure handler, to be used with PipesPremude.mapM
sideffectHandler :: MonadIO m => C.Command -> m C.Command
sideffectHandler c = do
  liftIO $ putStrLn $ "Received: " ++ (show c)
  return C.DoNothing  -- whatever is received from server, answer DoNothing

main :: IO ()
main = PNT.connect ("127.0.0.1") "23456" $
  \(connectionSocket, remoteAddress) -> do
    putStrLn $ "Connected to distant server ip = " ++ (show remoteAddress)
    sendFirstMessage connectionSocket
    _ <- runEffect $ do
      let bytesReceiver = PNT.fromSocket connectionSocket pageSize
      let commandDecoder = PP.parsed PipesBinary.decode bytesReceiver
      commandDecoder >-> PipesPrelude.mapM sideffectHandler >-> for cat PipesBinary.encode >-> PNT.toSocket connectionSocket
    return ()

sendFirstMessage :: PNT.Socket -> IO ()
sendFirstMessage s = do
  _ <- runEffect $ do
    let encodedProducer = PipesBinary.encode C.FirstMessage 
    encodedProducer >-> PNT.toSocket s  
  return ()