ActionScript 3
Lavorare con i video

Carica e riproduci file video esterni

riferimento : NetConnection , NetStream , Video

argomenti correlati : Lavorare con il suono

Esempio base di riproduzione di un file video esterno (FLV, MP4, F4V). Il codice riprodurrà anche i file audio M4A.

var nc:NetConnection = new NetConnection();
nc.connect(null);

var ns:NetStream = new NetStream(nc);

var myVideo:Video = new Video();
addChild(myVideo);

myVideo.attachNetStream(ns);

ns.play("http://www.yourwebsite.com/somefile.mp4");

Si noti il ​​codice utilizzato un nc.connect.null ? Questo perché, in questo caso, non è necessario creare una connessione bidirezionale peer-to-peer (ad esempio: come previsto in un'app di chat video) poiché stiamo riproducendo un file memorizzato.

Impostando nc.connect.null è necessario fornire un collegamento a un file che si trova su un server Web o locale (stessa posizione / cartella) al file SWF in esecuzione.

• Per un file web utilizzare: ns.play("http://www.yourwebsite.com/somefile.mp4");
• Per un file locale utilizzare: ns.play("somefile.mp4");

Con NetStatusEvent

package {
    import flash.events.NetStatusEvent;
    import flash.net.NetStream;
    import flash.net.NetConnection;
    import flash.events.Event;
    import flash.media.Video;
    import flash.display.Sprite;
    public class VideoWithNetStatus extends Sprite {
        private var video:Video = new Video();
        private var nc:NetConnection;
        private var ns:NetStream;
        
        public function VideoWithNetStatus() {
            nc = new NetConnection();
            nc.addEventListener(NetStatusEvent.NET_STATUS, onStatus);
            nc.connect(null);//or media server url
        }
 
         private function onStatus(e:NetStatusEvent):void{
             switch(e.info.code){
                 case 'NetConnection.Connect.Success':
                     connectStream();
                 break;
                 default:
                     trace(e.info.code);//to see any unhadled events   
             }
         }
         private function connectStream():void{
             ns = new NetStream(nc);
             ns.addEventListener(NetStatusEvent.NET_STATUS, onStatus);
             addChild(video);
             video.attachNetStream(ns);
             ns.play('url/to/video.flv');
         }
    }
}