ActionScript 3
वीडियो के साथ काम करना

बाहरी वीडियो फ़ाइल लोड और चलाएं

संदर्भ : NetConnection , NetStream , Video

संबंधित विषय : साउंड के साथ काम करना

बाहरी वीडियो फ़ाइल (FLV, MP4, F4V) चलाने का मूल उदाहरण। कोड M4A ऑडियो फ़ाइलों को भी चलाएगा।

var nc:NetConnection = new NetConnection();
nc.connect(null);

var ns:NetStream = new NetStream(nc);

var myVideo:Video = new Video();
addChild(myVideo);

myVideo.attachNetStream(ns);

ns.play("http://www.yourwebsite.com/somefile.mp4");

एक nc.connect.null इस्तेमाल किए गए कोड को नोटिस करें? ऐसा इसलिए है, क्योंकि इस मामले में, हमें एक संग्रहीत फ़ाइल चलाने के लिए दो-तरफा सहकर्मी से सहकर्मी कनेक्शन (जैसे: वीडियो चैट ऐप में अपेक्षित) बनाने की कोई आवश्यकता नहीं है।

एक nc.connect.null सेट करके यह एक फ़ाइल के लिए एक लिंक प्रदान करने के लिए आवश्यक है जो या तो एक वेब सर्वर पर है या एक जो चल रहे SWF के लिए स्थानीय (समान स्थान / फ़ोल्डर) है।

• एक वेब फ़ाइल उपयोग के लिए: ns.play("http://www.yourwebsite.com/somefile.mp4");
• एक स्थानीय फ़ाइल उपयोग के लिए: ns.play("somefile.mp4");

NetStatusEvent के साथ

package {
    import flash.events.NetStatusEvent;
    import flash.net.NetStream;
    import flash.net.NetConnection;
    import flash.events.Event;
    import flash.media.Video;
    import flash.display.Sprite;
    public class VideoWithNetStatus extends Sprite {
        private var video:Video = new Video();
        private var nc:NetConnection;
        private var ns:NetStream;
        
        public function VideoWithNetStatus() {
            nc = new NetConnection();
            nc.addEventListener(NetStatusEvent.NET_STATUS, onStatus);
            nc.connect(null);//or media server url
        }
 
         private function onStatus(e:NetStatusEvent):void{
             switch(e.info.code){
                 case 'NetConnection.Connect.Success':
                     connectStream();
                 break;
                 default:
                     trace(e.info.code);//to see any unhadled events   
             }
         }
         private function connectStream():void{
             ns = new NetStream(nc);
             ns.addEventListener(NetStatusEvent.NET_STATUS, onStatus);
             addChild(video);
             video.attachNetStream(ns);
             ns.play('url/to/video.flv');
         }
    }
}