ActionScript 3
Praca z wideo

Załaduj i odtwórz zewnętrzny plik wideo

odniesienie : NetConnection , NetStream , Video

powiązane tematy : Praca z dźwiękiem

Podstawowy przykład odtwarzania zewnętrznego pliku wideo (FLV, MP4, F4V). Kod będzie także odtwarzał pliki audio M4A.

var nc:NetConnection = new NetConnection();
nc.connect(null);

var ns:NetStream = new NetStream(nc);

var myVideo:Video = new Video();
addChild(myVideo);

myVideo.attachNetStream(ns);

ns.play("http://www.yourwebsite.com/somefile.mp4");

Zauważ, że kod używał nc.connect.null ? Wynika to z faktu, że w tym przypadku nie ma potrzeby tworzenia dwukierunkowego połączenia peer-to-peer (np. Zgodnie z oczekiwaniami w aplikacji do czatów wideo), ponieważ odtwarzamy zapisany plik.

Po ustawieniu nc.connect.null wymagane jest podanie łącza do pliku znajdującego się na serwerze WWW lub pliku lokalnego (ta sama lokalizacja / folder) do działającego pliku SWF.

• W przypadku pliku internetowego użyj: ns.play("http://www.yourwebsite.com/somefile.mp4");
• Do pliku lokalnego użyj: ns.play("somefile.mp4");

Z NetStatusEvent

package {
    import flash.events.NetStatusEvent;
    import flash.net.NetStream;
    import flash.net.NetConnection;
    import flash.events.Event;
    import flash.media.Video;
    import flash.display.Sprite;
    public class VideoWithNetStatus extends Sprite {
        private var video:Video = new Video();
        private var nc:NetConnection;
        private var ns:NetStream;
        
        public function VideoWithNetStatus() {
            nc = new NetConnection();
            nc.addEventListener(NetStatusEvent.NET_STATUS, onStatus);
            nc.connect(null);//or media server url
        }
 
         private function onStatus(e:NetStatusEvent):void{
             switch(e.info.code){
                 case 'NetConnection.Connect.Success':
                     connectStream();
                 break;
                 default:
                     trace(e.info.code);//to see any unhadled events   
             }
         }
         private function connectStream():void{
             ns = new NetStream(nc);
             ns.addEventListener(NetStatusEvent.NET_STATUS, onStatus);
             addChild(video);
             video.attachNetStream(ns);
             ns.play('url/to/video.flv');
         }
    }
}