ActionScript 3
비디오 작업

외부 비디오 파일로드 및 재생

참조 : NetConnection , NetStream , Video

관련 항목 : 사운드를 사용한 작업

외부 비디오 파일 (FLV, MP4, F4V) 재생의 기본 예제. 코드는 또한 M4A 오디오 파일을 재생합니다.

var nc:NetConnection = new NetConnection();
nc.connect(null);

var ns:NetStream = new NetStream(nc);

var myVideo:Video = new Video();
addChild(myVideo);

myVideo.attachNetStream(ns);

ns.play("http://www.yourwebsite.com/somefile.mp4");

코드에서 nc.connect.null 사용 nc.connect.null . 이 경우 저장된 파일을 재생 중이므로 양방향 피어 투 피어 연결 (예 : 화상 채팅 앱에서 예상 한 것처럼)을 만들 필요가 없기 때문입니다.

nc.connect.null 을 설정하면 웹 서버에있는 파일이나 실행중인 SWF에 대해 로컬 (동일한 위치 / 폴더)에있는 파일에 대한 링크를 제공해야합니다.

• 웹 파일의 경우 : ns.play("http://www.yourwebsite.com/somefile.mp4");
• 로컬 파일 사용 : ns.play("somefile.mp4");

NetStatusEvent 사용

package {
    import flash.events.NetStatusEvent;
    import flash.net.NetStream;
    import flash.net.NetConnection;
    import flash.events.Event;
    import flash.media.Video;
    import flash.display.Sprite;
    public class VideoWithNetStatus extends Sprite {
        private var video:Video = new Video();
        private var nc:NetConnection;
        private var ns:NetStream;
        
        public function VideoWithNetStatus() {
            nc = new NetConnection();
            nc.addEventListener(NetStatusEvent.NET_STATUS, onStatus);
            nc.connect(null);//or media server url
        }
 
         private function onStatus(e:NetStatusEvent):void{
             switch(e.info.code){
                 case 'NetConnection.Connect.Success':
                     connectStream();
                 break;
                 default:
                     trace(e.info.code);//to see any unhadled events   
             }
         }
         private function connectStream():void{
             ns = new NetStream(nc);
             ns.addEventListener(NetStatusEvent.NET_STATUS, onStatus);
             addChild(video);
             video.attachNetStream(ns);
             ns.play('url/to/video.flv');
         }
    }
}