ActionScript 3
Trabajando con video

Cargar y reproducir archivo de video externo

referencia : NetConnection , NetStream , Video

temas relacionados : trabajando con sonido

Ejemplo básico de reproducción de un archivo de video externo (FLV, MP4, F4V). El código también reproducirá archivos de audio M4A.

var nc:NetConnection = new NetConnection();
nc.connect(null);

var ns:NetStream = new NetStream(nc);

var myVideo:Video = new Video();
addChild(myVideo);

myVideo.attachNetStream(ns);

ns.play("http://www.yourwebsite.com/somefile.mp4");

Observe el código utilizado en nc.connect.null ? Esto se debe a que, en este caso, no es necesario crear una conexión de igual a igual (p. Ej., Como se espera en una aplicación de video chat) ya que estamos reproduciendo un archivo almacenado.

Al configurar nc.connect.null , es necesario proporcionar un enlace a un archivo que esté en un servidor web o que sea local (misma ubicación / carpeta) al SWF en ejecución.

• Para usar un archivo web : ns.play("http://www.yourwebsite.com/somefile.mp4");
• Para un uso de archivo local : ns.play("somefile.mp4");

Con NetStatusEvent

package {
    import flash.events.NetStatusEvent;
    import flash.net.NetStream;
    import flash.net.NetConnection;
    import flash.events.Event;
    import flash.media.Video;
    import flash.display.Sprite;
    public class VideoWithNetStatus extends Sprite {
        private var video:Video = new Video();
        private var nc:NetConnection;
        private var ns:NetStream;
        
        public function VideoWithNetStatus() {
            nc = new NetConnection();
            nc.addEventListener(NetStatusEvent.NET_STATUS, onStatus);
            nc.connect(null);//or media server url
        }
 
         private function onStatus(e:NetStatusEvent):void{
             switch(e.info.code){
                 case 'NetConnection.Connect.Success':
                     connectStream();
                 break;
                 default:
                     trace(e.info.code);//to see any unhadled events   
             }
         }
         private function connectStream():void{
             ns = new NetStream(nc);
             ns.addEventListener(NetStatusEvent.NET_STATUS, onStatus);
             addChild(video);
             video.attachNetStream(ns);
             ns.play('url/to/video.flv');
         }
    }
}