ActionScript 3
Travailler avec la vidéo

Charger et lire un fichier vidéo externe

référence : NetConnection , NetStream , Video

sujets connexes : Travailler avec le son

Exemple de base de lecture d'un fichier vidéo externe (FLV, MP4, F4V). Le code lit également les fichiers audio M4A.

var nc:NetConnection = new NetConnection();
nc.connect(null);

var ns:NetStream = new NetStream(nc);

var myVideo:Video = new Video();
addChild(myVideo);

myVideo.attachNetStream(ns);

ns.play("http://www.yourwebsite.com/somefile.mp4");

Notez que le code a utilisé un nc.connect.null ? En effet, dans ce cas, il n'est pas nécessaire de créer une connexion pair à pair (par exemple: comme prévu dans une application de chat vidéo), car nous lisons un fichier stocké.

En définissant un nc.connect.null il est nécessaire de fournir un lien vers un fichier qui se trouve sur un serveur Web ou local (même emplacement / dossier) vers le fichier SWF en cours d'exécution.

• Pour un fichier Web , utilisez: ns.play("http://www.yourwebsite.com/somefile.mp4");
• Pour un fichier local , utilisez: ns.play("somefile.mp4");

Avec NetStatusEvent

package {
    import flash.events.NetStatusEvent;
    import flash.net.NetStream;
    import flash.net.NetConnection;
    import flash.events.Event;
    import flash.media.Video;
    import flash.display.Sprite;
    public class VideoWithNetStatus extends Sprite {
        private var video:Video = new Video();
        private var nc:NetConnection;
        private var ns:NetStream;
        
        public function VideoWithNetStatus() {
            nc = new NetConnection();
            nc.addEventListener(NetStatusEvent.NET_STATUS, onStatus);
            nc.connect(null);//or media server url
        }
 
         private function onStatus(e:NetStatusEvent):void{
             switch(e.info.code){
                 case 'NetConnection.Connect.Success':
                     connectStream();
                 break;
                 default:
                     trace(e.info.code);//to see any unhadled events   
             }
         }
         private function connectStream():void{
             ns = new NetStream(nc);
             ns.addEventListener(NetStatusEvent.NET_STATUS, onStatus);
             addChild(video);
             video.attachNetStream(ns);
             ns.play('url/to/video.flv');
         }
    }
}