Microsoft SQL Server
Rendez-vous

Syntaxe

• EOMONTH ( start_date [, month_to_add])

Remarques

Formatage de la date et de l'heure avec CONVERT

Vous pouvez utiliser la fonction CONVERT pour convertir un type de données datetime en une chaîne formatée.

SELECT GETDATE() AS [Result] -- 2016-07-21 07:56:10.927

Vous pouvez également utiliser des codes intégrés pour convertir dans un format spécifique. Voici les options intégrées à SQL Server:

DECLARE @convert_code INT = 100 -- See Table Below
SELECT CONVERT(VARCHAR(30), GETDATE(), @convert_code) AS [Result]

SELECT GETDATE() AS [Result]                                -- 2016-07-21 07:56:10.927
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),100) AS [Result] -- Jul 21 2016  7:56AM
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),101) AS [Result] -- 07/21/2016
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),102) AS [Result] -- 2016.07.21
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),103) AS [Result] -- 21/07/2016
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),104) AS [Result] -- 21.07.2016
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),105) AS [Result] -- 21-07-2016
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),106) AS [Result] -- 21 Jul 2016
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),107) AS [Result] -- Jul 21, 2016
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),108) AS [Result] -- 07:57:05
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),109) AS [Result] -- Jul 21 2016  7:57:45:707AM
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),110) AS [Result] -- 07-21-2016
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),111) AS [Result] -- 2016/07/21
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),112) AS [Result] -- 20160721
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),113) AS [Result] -- 21 Jul 2016 07:57:59:553
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),114) AS [Result] -- 07:57:59:553
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),120) AS [Result] -- 2016-07-21 07:57:59
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),121) AS [Result] -- 2016-07-21 07:57:59.553
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),126) AS [Result] -- 2016-07-21T07:58:34.340
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),127) AS [Result] -- 2016-07-21T07:58:34.340
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),130) AS [Result] -- 16 ???? 1437  7:58:34:340AM
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),131) AS [Result] -- 16/10/1437  7:58:34:340AM

Formatage de la date et de l'heure à l'aide de FORMAT

DECLARE @Date DATETIME = '2016-09-05 00:01:02.333'

SELECT FORMAT(@Date, N'dddd, MMMM dd, yyyy hh:mm:ss tt')

DECLARE @Date DATETIME = '2016-09-05 00:01:02.333'

SELECT FORMAT(@Date, N'U')

DECLARE @Date DATETIME = '2016-09-05 00:01:02.333'

SELECT FORMAT(@Date, N'U', 'zh-cn')

Récupère le DateTime actuel

Les fonctions GETDATE et GETUTCDATE chacune la date et l'heure actuelles sans décalage de fuseau horaire.

La valeur de retour des deux fonctions est basée sur le système d'exploitation de l'ordinateur sur lequel l'instance de SQL Server est exécutée.

La valeur de retour de GETDATE représente l'heure actuelle dans le même fuseau horaire que le système d'exploitation. La valeur de retour de GETUTCDATE représente l'heure UTC actuelle.

L'une ou l'autre fonction peut être incluse dans la clause SELECT d'une requête ou dans le cadre d'une expression booléenne dans la clause WHERE .

Exemples:

-- example query that selects the current time in both the server time zone and UTC
SELECT GETDATE() as SystemDateTime, GETUTCDATE() as UTCDateTime

-- example query records with EventDate in the past.
SELECT * FROM MyEvents WHERE EventDate < GETDATE() 

Il existe quelques autres fonctions intégrées qui renvoient des variations différentes de la date et heure actuelle:

SELECT 
    GETDATE(),          --2016-07-21 14:27:37.447
    GETUTCDATE(),       --2016-07-21 18:27:37.447
    CURRENT_TIMESTAMP,  --2016-07-21 14:27:37.447
    SYSDATETIME(),      --2016-07-21 14:27:37.4485768
    SYSDATETIMEOFFSET(),--2016-07-21 14:27:37.4485768 -04:00
    SYSUTCDATETIME()    --2016-07-21 18:27:37.4485768

DATEADD pour l'ajout et la soustraction de périodes

Syntaxe générale:

DATEADD (datepart , number , datetime_expr)  

Pour ajouter une mesure de temps, le number doit être positif. Pour soustraire une mesure de temps, le number doit être négatif.

Exemples

DECLARE @now DATETIME2 = GETDATE();
SELECT @now;                        --2016-07-21 14:39:46.4170000
SELECT DATEADD(YEAR, 1, @now)       --2017-07-21 14:39:46.4170000
SELECT DATEADD(QUARTER, 1, @now)    --2016-10-21 14:39:46.4170000
SELECT DATEADD(WEEK, 1, @now)       --2016-07-28 14:39:46.4170000
SELECT DATEADD(DAY, 1, @now)        --2016-07-22 14:39:46.4170000
SELECT DATEADD(HOUR, 1, @now)       --2016-07-21 15:39:46.4170000
SELECT DATEADD(MINUTE, 1, @now)     --2016-07-21 14:40:46.4170000
SELECT DATEADD(SECOND, 1, @now)     --2016-07-21 14:39:47.4170000
SELECT DATEADD(MILLISECOND, 1, @now)--2016-07-21 14:39:46.4180000

REMARQUE: DATEADD accepte également les abréviations dans le paramètre datepart . L'utilisation de ces abréviations est généralement déconseillée car elles peuvent être source de confusion ( m vs mi , ww vs w , etc.).

Date de référence des pièces

Ce sont les datepart valeurs disponibles pour les fonctions de date et heure:

NOTE : L'utilisation des abréviations est généralement déconseillée car elles peuvent être source de confusion ( m vs mi , ww vs w , etc.). La version longue de la datepart représentation favorise la clarté et la lisibilité, et doit être utilisé chaque fois que possible ( month , minute , week , weekday de la weekday , etc.).

DATEDIFF pour calculer les différences de période

Syntaxe générale:

DATEDIFF (datepart, datetime_expr1, datetime_expr2)

Il retournera un nombre positif si datetime_expr est dans le passé relatif à datetime_expr2 , et un nombre négatif sinon.

Exemples

DECLARE @now DATETIME2 = GETDATE();
DECLARE @oneYearAgo DATETIME2 = DATEADD(YEAR, -1, @now);
SELECT @now                                    --2016-07-21 14:49:50.9800000
SELECT @oneYearAgo                             --2015-07-21 14:49:50.9800000
SELECT DATEDIFF(YEAR, @oneYearAgo, @now)       --1
SELECT DATEDIFF(QUARTER, @oneYearAgo, @now)    --4
SELECT DATEDIFF(WEEK, @oneYearAgo, @now)       --52
SELECT DATEDIFF(DAY, @oneYearAgo, @now)        --366
SELECT DATEDIFF(HOUR, @oneYearAgo, @now)       --8784
SELECT DATEDIFF(MINUTE, @oneYearAgo, @now)     --527040
SELECT DATEDIFF(SECOND, @oneYearAgo, @now)     --31622400

REMARQUE: DATEDIFF accepte également les abréviations dans le paramètre datepart . L'utilisation de ces abréviations est généralement déconseillée car elles peuvent être source de confusion ( m vs mi , ww vs w , etc.).

DATEDIFF peut également être utilisé pour déterminer le décalage entre l'heure UTC et l'heure locale du serveur SQL. L'instruction suivante peut être utilisée pour calculer le décalage entre l'heure UTC et l'heure locale (y compris le fuseau horaire).

select  DATEDIFF(hh, getutcdate(), getdate()) as 'CentralTimeOffset'

DATEPART & DATENAME

DATEPART renvoie la datepart spécifiée de l'expression datetime spécifiée en tant que valeur numérique.

DATENAME renvoie une chaîne de caractères qui représente la datepart l'heure spécifiées pour la date spécifiée. En pratique, DATENAME est surtout utile pour obtenir le nom du mois ou du jour de la semaine.

Il y a aussi quelques fonctions raccourcies pour obtenir l'année, le mois ou le jour d'une expression_dateheure, qui se comportent comme DATEPART avec leurs respectives datepart unités.

Syntaxe:

DATEPART ( datepart , datetime_expr )
DATENAME ( datepart , datetime_expr )
DAY ( datetime_expr )
MONTH ( datetime_expr )
YEAR ( datetime_expr )

Exemples:

DECLARE @now DATETIME2 = GETDATE();
SELECT @now                       --2016-07-21 15:05:33.8370000
SELECT DATEPART(YEAR, @now)       --2016
SELECT DATEPART(QUARTER, @now)    --3
SELECT DATEPART(WEEK, @now)       --30
SELECT DATEPART(HOUR, @now)       --15
SELECT DATEPART(MINUTE, @now)     --5
SELECT DATEPART(SECOND, @now)     --33
-- Differences between DATEPART and DATENAME:
SELECT DATEPART(MONTH, @now)      --7
SELECT DATENAME(MONTH, @now)      --July
SELECT DATEPART(WEEKDAY, @now)    --5
SELECT DATENAME(WEEKDAY, @now)    --Thursday
--shorthand functions
SELECT DAY(@now)    --21
SELECT MONTH(@now)  --7
SELECT YEAR(@now)   --2016

REMARQUE: DATEPART et DATENAME acceptent également les abréviations dans le paramètre datepart . L'utilisation de ces abréviations est généralement déconseillée car elles peuvent être source de confusion ( m vs mi , ww vs w , etc.).

Obtenir le dernier jour d'un mois

En utilisant les fonctions DATEADD et DATEDIFF , il est possible de renvoyer la dernière date d'un mois.

SELECT DATEADD(d, -1, DATEADD(m, DATEDIFF(m, 0, '2016-09-23') + 1, 0))
-- 2016-09-30 00:00:00.000

SELECT EOMONTH('2016-07-21')        --2016-07-31
SELECT EOMONTH('2016-07-21', 4)     --2016-11-30
SELECT EOMONTH('2016-07-21', -5)    --2016-02-29

Retourner la date juste d'un DateTime

Il existe plusieurs façons de renvoyer une date à partir d'un objet DateTime

1. SELECT CONVERT(Date, GETDATE())
2. SELECT DATEADD(dd, 0, DATEDIFF(dd, 0, GETDATE())) renvoie 2016-07-21 00: 00: 00.000
3. SELECT CAST(GETDATE() AS DATE)
4. SELECT CONVERT(CHAR(10),GETDATE(),111)
5. SELECT FORMAT(GETDATE(), 'yyyy-MM-dd')

Notez que les options 4 et 5 retournent une chaîne, pas une date.

Fonction de création pour calculer l'âge d'une personne à une date précise

Cette fonction prendra 2 paramètres datetime, le DOB et une date pour vérifier l’âge à

  CREATE FUNCTION [dbo].[Calc_Age]
    (
    @DOB datetime , @calcDate datetime 
    )
    RETURNS int
    AS
   BEGIN
declare @age int

IF (@calcDate < @DOB  )
RETURN -1

-- If a DOB is supplied after the comparison date, then return -1
SELECT @age = YEAR(@calcDate) - YEAR(@DOB) +
  CASE WHEN DATEADD(year,YEAR(@calcDate) - YEAR(@DOB)
  ,@DOB) > @calcDate THEN -1 ELSE 0 END
    

RETURN @age
    

END

par exemple pour vérifier l'âge d'une personne née le 1/1/2000

SELECT  dbo.Calc_Age('2000-01-01',Getdate())

OBJET DE DATE CROSS PLATFORM

 DECLARE @myDate DATE=DATEFROMPARTS(1988,11,28) 
 DECLARE @someMoment DATETIME=DATEFROMPARTS(1988,11,28,10,30,50,123)

Format de date étendu