Microsoft SQL Server
fechas

Sintaxis

• EOMONTH (fecha_inicial [, month_to_add])

Observaciones

Formato de fecha y hora utilizando CONVERT

Puede usar la función CONVERTIR para convertir un tipo de datos de fecha y hora en una cadena con formato.

SELECT GETDATE() AS [Result] -- 2016-07-21 07:56:10.927

También puede usar algunos códigos incorporados para convertirlos en un formato específico. Aquí están las opciones integradas en SQL Server:

DECLARE @convert_code INT = 100 -- See Table Below
SELECT CONVERT(VARCHAR(30), GETDATE(), @convert_code) AS [Result]

SELECT GETDATE() AS [Result]                                -- 2016-07-21 07:56:10.927
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),100) AS [Result] -- Jul 21 2016  7:56AM
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),101) AS [Result] -- 07/21/2016
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),102) AS [Result] -- 2016.07.21
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),103) AS [Result] -- 21/07/2016
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),104) AS [Result] -- 21.07.2016
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),105) AS [Result] -- 21-07-2016
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),106) AS [Result] -- 21 Jul 2016
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),107) AS [Result] -- Jul 21, 2016
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),108) AS [Result] -- 07:57:05
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),109) AS [Result] -- Jul 21 2016  7:57:45:707AM
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),110) AS [Result] -- 07-21-2016
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),111) AS [Result] -- 2016/07/21
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),112) AS [Result] -- 20160721
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),113) AS [Result] -- 21 Jul 2016 07:57:59:553
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),114) AS [Result] -- 07:57:59:553
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),120) AS [Result] -- 2016-07-21 07:57:59
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),121) AS [Result] -- 2016-07-21 07:57:59.553
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),126) AS [Result] -- 2016-07-21T07:58:34.340
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),127) AS [Result] -- 2016-07-21T07:58:34.340
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),130) AS [Result] -- 16 ???? 1437  7:58:34:340AM
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),131) AS [Result] -- 16/10/1437  7:58:34:340AM

Formato de fecha y hora usando FORMATO

DECLARE @Date DATETIME = '2016-09-05 00:01:02.333'

SELECT FORMAT(@Date, N'dddd, MMMM dd, yyyy hh:mm:ss tt')

DECLARE @Date DATETIME = '2016-09-05 00:01:02.333'

SELECT FORMAT(@Date, N'U')

DECLARE @Date DATETIME = '2016-09-05 00:01:02.333'

SELECT FORMAT(@Date, N'U', 'zh-cn')

Obtener el DateTime actual

Las funciones integradas GETDATE y GETUTCDATE devuelven la fecha y la hora actuales sin un desplazamiento de zona horaria.

El valor de retorno de ambas funciones se basa en el sistema operativo del equipo en el que se ejecuta la instancia de SQL Server.

El valor de retorno de GETDATE representa la hora actual en la misma zona horaria que el sistema operativo. El valor de retorno de GETUTCDATE representa la hora UTC actual.

Cualquiera de las funciones puede incluirse en la cláusula SELECT de una consulta o como parte de una expresión booleana en la cláusula WHERE .

Ejemplos:

-- example query that selects the current time in both the server time zone and UTC
SELECT GETDATE() as SystemDateTime, GETUTCDATE() as UTCDateTime

-- example query records with EventDate in the past.
SELECT * FROM MyEvents WHERE EventDate < GETDATE() 

Hay algunas otras funciones integradas que devuelven diferentes variaciones de la fecha y hora actual:

SELECT 
    GETDATE(),          --2016-07-21 14:27:37.447
    GETUTCDATE(),       --2016-07-21 18:27:37.447
    CURRENT_TIMESTAMP,  --2016-07-21 14:27:37.447
    SYSDATETIME(),      --2016-07-21 14:27:37.4485768
    SYSDATETIMEOFFSET(),--2016-07-21 14:27:37.4485768 -04:00
    SYSUTCDATETIME()    --2016-07-21 18:27:37.4485768

DATEADD para sumar y restar períodos de tiempo

Sintaxis general:

DATEADD (datepart , number , datetime_expr)  

Para agregar una medida de tiempo, el number debe ser positivo. Para restar una medida de tiempo, el number debe ser negativo.

Ejemplos

DECLARE @now DATETIME2 = GETDATE();
SELECT @now;                        --2016-07-21 14:39:46.4170000
SELECT DATEADD(YEAR, 1, @now)       --2017-07-21 14:39:46.4170000
SELECT DATEADD(QUARTER, 1, @now)    --2016-10-21 14:39:46.4170000
SELECT DATEADD(WEEK, 1, @now)       --2016-07-28 14:39:46.4170000
SELECT DATEADD(DAY, 1, @now)        --2016-07-22 14:39:46.4170000
SELECT DATEADD(HOUR, 1, @now)       --2016-07-21 15:39:46.4170000
SELECT DATEADD(MINUTE, 1, @now)     --2016-07-21 14:40:46.4170000
SELECT DATEADD(SECOND, 1, @now)     --2016-07-21 14:39:47.4170000
SELECT DATEADD(MILLISECOND, 1, @now)--2016-07-21 14:39:46.4180000

NOTA: DATEADD también acepta abreviaturas en el parámetro datepart . El uso de estas abreviaturas generalmente se desaconseja ya que pueden ser confusos ( m vs mi , ww vs w , etc.).

Referencia de piezas de fecha

Estos son los datepart valores disponibles para las funciones de fecha y hora:

NOTA : El uso de abreviaturas generalmente se desaconseja ya que pueden ser confusos ( m vs mi , ww vs w , etc.). La versión larga de la representación de la fecha datepart promueve la claridad y la legibilidad, y debe usarse siempre que sea posible ( month , minute , week , weekday , etc.).

DATEDIFF para calcular las diferencias de período de tiempo

Sintaxis general:

DATEDIFF (datepart, datetime_expr1, datetime_expr2)

Devolverá un número positivo si datetime_expr está en el pasado en relación con datetime_expr2 , y un número negativo de lo contrario.

Ejemplos

DECLARE @now DATETIME2 = GETDATE();
DECLARE @oneYearAgo DATETIME2 = DATEADD(YEAR, -1, @now);
SELECT @now                                    --2016-07-21 14:49:50.9800000
SELECT @oneYearAgo                             --2015-07-21 14:49:50.9800000
SELECT DATEDIFF(YEAR, @oneYearAgo, @now)       --1
SELECT DATEDIFF(QUARTER, @oneYearAgo, @now)    --4
SELECT DATEDIFF(WEEK, @oneYearAgo, @now)       --52
SELECT DATEDIFF(DAY, @oneYearAgo, @now)        --366
SELECT DATEDIFF(HOUR, @oneYearAgo, @now)       --8784
SELECT DATEDIFF(MINUTE, @oneYearAgo, @now)     --527040
SELECT DATEDIFF(SECOND, @oneYearAgo, @now)     --31622400

NOTA: DATEDIFF también acepta abreviaturas en el parámetro datepart . El uso de estas abreviaturas generalmente se desaconseja ya que pueden ser confusos ( m vs mi , ww vs w , etc.).

DATEDIFF también se puede usar para determinar el desplazamiento entre UTC y la hora local del servidor SQL. La siguiente declaración se puede usar para calcular el desplazamiento entre UTC y la hora local (incluida la zona horaria).

select  DATEDIFF(hh, getutcdate(), getdate()) as 'CentralTimeOffset'

DATEPART & DATENAME

DATEPART devuelve la datepart de fecha especificada de la expresión datetime especificada como un valor numérico.

DATENAME devuelve una cadena de caracteres que representa la datepart de la fecha especificada de la fecha especificada. En la práctica, DATENAME es útil para obtener el nombre del mes o el día de la semana.

También hay algunas funciones de la taquigrafía para conseguir el año, mes o día de una expresión de fecha y hora, que se comportan como DATEPART con sus respectivos datepart unidades.

Sintaxis:

DATEPART ( datepart , datetime_expr )
DATENAME ( datepart , datetime_expr )
DAY ( datetime_expr )
MONTH ( datetime_expr )
YEAR ( datetime_expr )

Ejemplos:

DECLARE @now DATETIME2 = GETDATE();
SELECT @now                       --2016-07-21 15:05:33.8370000
SELECT DATEPART(YEAR, @now)       --2016
SELECT DATEPART(QUARTER, @now)    --3
SELECT DATEPART(WEEK, @now)       --30
SELECT DATEPART(HOUR, @now)       --15
SELECT DATEPART(MINUTE, @now)     --5
SELECT DATEPART(SECOND, @now)     --33
-- Differences between DATEPART and DATENAME:
SELECT DATEPART(MONTH, @now)      --7
SELECT DATENAME(MONTH, @now)      --July
SELECT DATEPART(WEEKDAY, @now)    --5
SELECT DATENAME(WEEKDAY, @now)    --Thursday
--shorthand functions
SELECT DAY(@now)    --21
SELECT MONTH(@now)  --7
SELECT YEAR(@now)   --2016

NOTA: DATEPART y DATENAME también aceptan abreviaturas en el parámetro datepart . El uso de estas abreviaturas generalmente se desaconseja ya que pueden ser confusos ( m vs mi , ww vs w , etc.).

Consiguiendo el último día de un mes.

Usando las funciones DATEADD y DATEDIFF , es posible devolver la última fecha de un mes.

SELECT DATEADD(d, -1, DATEADD(m, DATEDIFF(m, 0, '2016-09-23') + 1, 0))
-- 2016-09-30 00:00:00.000

SELECT EOMONTH('2016-07-21')        --2016-07-31
SELECT EOMONTH('2016-07-21', 4)     --2016-11-30
SELECT EOMONTH('2016-07-21', -5)    --2016-02-29

Devuelve solo la fecha de un DateTime

Hay muchas formas de devolver una fecha desde un objeto DateTime

1. SELECT CONVERT(Date, GETDATE())
2. SELECT DATEADD(dd, 0, DATEDIFF(dd, 0, GETDATE())) devuelve 2016-07-21 00: 00: 00.000
3. SELECT CAST(GETDATE() AS DATE)
4. SELECT CONVERT(CHAR(10),GETDATE(),111)
5. SELECT FORMAT(GETDATE(), 'yyyy-MM-dd')

Tenga en cuenta que las opciones 4 y 5 devuelven una cadena, no una fecha.

Crear una función para calcular la edad de una persona en una fecha específica

Esta función tomará 2 parámetros de fecha y hora, el DOB y una fecha para verificar la edad en

  CREATE FUNCTION [dbo].[Calc_Age]
    (
    @DOB datetime , @calcDate datetime 
    )
    RETURNS int
    AS
   BEGIN
declare @age int

IF (@calcDate < @DOB  )
RETURN -1

-- If a DOB is supplied after the comparison date, then return -1
SELECT @age = YEAR(@calcDate) - YEAR(@DOB) +
  CASE WHEN DATEADD(year,YEAR(@calcDate) - YEAR(@DOB)
  ,@DOB) > @calcDate THEN -1 ELSE 0 END
    

RETURN @age
    

END

por ejemplo, para comprobar la edad actual de alguien nacido el 1/1/2000

SELECT  dbo.Calc_Age('2000-01-01',Getdate())

PLATAFORMA TRANSVERSAL FECHA OBJETO

 DECLARE @myDate DATE=DATEFROMPARTS(1988,11,28) 
 DECLARE @someMoment DATETIME=DATEFROMPARTS(1988,11,28,10,30,50,123)

Formato de fecha extendido