Microsoft SQL Server
Date

Sintassi

• EOMONTH ( start_date [, month_to_add])

Osservazioni

Formattazione di data e ora tramite CONVERT

È possibile utilizzare la funzione CONVERT per eseguire il cast di un datatype datetime su una stringa formattata.

SELECT GETDATE() AS [Result] -- 2016-07-21 07:56:10.927

È inoltre possibile utilizzare alcuni codici incorporati per convertire in un formato specifico. Ecco le opzioni integrate in SQL Server:

DECLARE @convert_code INT = 100 -- See Table Below
SELECT CONVERT(VARCHAR(30), GETDATE(), @convert_code) AS [Result]

SELECT GETDATE() AS [Result]                                -- 2016-07-21 07:56:10.927
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),100) AS [Result] -- Jul 21 2016  7:56AM
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),101) AS [Result] -- 07/21/2016
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),102) AS [Result] -- 2016.07.21
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),103) AS [Result] -- 21/07/2016
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),104) AS [Result] -- 21.07.2016
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),105) AS [Result] -- 21-07-2016
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),106) AS [Result] -- 21 Jul 2016
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),107) AS [Result] -- Jul 21, 2016
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),108) AS [Result] -- 07:57:05
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),109) AS [Result] -- Jul 21 2016  7:57:45:707AM
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),110) AS [Result] -- 07-21-2016
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),111) AS [Result] -- 2016/07/21
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),112) AS [Result] -- 20160721
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),113) AS [Result] -- 21 Jul 2016 07:57:59:553
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),114) AS [Result] -- 07:57:59:553
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),120) AS [Result] -- 2016-07-21 07:57:59
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),121) AS [Result] -- 2016-07-21 07:57:59.553
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),126) AS [Result] -- 2016-07-21T07:58:34.340
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),127) AS [Result] -- 2016-07-21T07:58:34.340
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),130) AS [Result] -- 16 ???? 1437  7:58:34:340AM
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),131) AS [Result] -- 16/10/1437  7:58:34:340AM

Formattazione di data e ora tramite FORMAT

DECLARE @Date DATETIME = '2016-09-05 00:01:02.333'

SELECT FORMAT(@Date, N'dddd, MMMM dd, yyyy hh:mm:ss tt')

DECLARE @Date DATETIME = '2016-09-05 00:01:02.333'

SELECT FORMAT(@Date, N'U')

DECLARE @Date DATETIME = '2016-09-05 00:01:02.333'

SELECT FORMAT(@Date, N'U', 'zh-cn')

Ottieni l'ora corrente

Le funzioni incorporate GETDATE e GETUTCDATE restituiscono ciascuna la data e l'ora correnti senza un offset del fuso orario.

Il valore di ritorno di entrambe le funzioni è basato sul sistema operativo del computer su cui è in esecuzione l'istanza di SQL Server.

Il valore restituito di GETDATE rappresenta l'ora corrente nello stesso fuso orario del sistema operativo. Il valore di ritorno di GETUTCDATE rappresenta l'ora UTC corrente.

Entrambe le funzioni possono essere incluse nella clausola SELECT di una query o come parte dell'espressione booleana nella clausola WHERE .

Esempi:

-- example query that selects the current time in both the server time zone and UTC
SELECT GETDATE() as SystemDateTime, GETUTCDATE() as UTCDateTime

-- example query records with EventDate in the past.
SELECT * FROM MyEvents WHERE EventDate < GETDATE() 

Ci sono alcune altre funzioni incorporate che restituiscono diverse variazioni della data-ora corrente:

SELECT 
    GETDATE(),          --2016-07-21 14:27:37.447
    GETUTCDATE(),       --2016-07-21 18:27:37.447
    CURRENT_TIMESTAMP,  --2016-07-21 14:27:37.447
    SYSDATETIME(),      --2016-07-21 14:27:37.4485768
    SYSDATETIMEOFFSET(),--2016-07-21 14:27:37.4485768 -04:00
    SYSUTCDATETIME()    --2016-07-21 18:27:37.4485768

DATEADD per l'aggiunta e la sottrazione dei periodi di tempo

Sintassi generale:

DATEADD (datepart , number , datetime_expr)  

Per aggiungere una misura temporale, il number deve essere positivo. Per sottrarre una misura del tempo, il number deve essere negativo.

Esempi

DECLARE @now DATETIME2 = GETDATE();
SELECT @now;                        --2016-07-21 14:39:46.4170000
SELECT DATEADD(YEAR, 1, @now)       --2017-07-21 14:39:46.4170000
SELECT DATEADD(QUARTER, 1, @now)    --2016-10-21 14:39:46.4170000
SELECT DATEADD(WEEK, 1, @now)       --2016-07-28 14:39:46.4170000
SELECT DATEADD(DAY, 1, @now)        --2016-07-22 14:39:46.4170000
SELECT DATEADD(HOUR, 1, @now)       --2016-07-21 15:39:46.4170000
SELECT DATEADD(MINUTE, 1, @now)     --2016-07-21 14:40:46.4170000
SELECT DATEADD(SECOND, 1, @now)     --2016-07-21 14:39:47.4170000
SELECT DATEADD(MILLISECOND, 1, @now)--2016-07-21 14:39:46.4180000

NOTA: DATEADD accetta anche le abbreviazioni nel parametro datepart . L'uso di queste abbreviazioni è generalmente scoraggiato in quanto possono essere fonte di confusione ( m vs mi , ww vs w , ecc.).

Data di riferimento delle parti

Questi sono i valori di datepart disponibili per le funzioni di data e ora:

NOTA : l'uso delle abbreviazioni è generalmente scoraggiato in quanto possono essere fonte di confusione ( m vs mi , ww vs w , ecc.). La versione lunga della rappresentazione di datepart promuove la chiarezza e la leggibilità e dovrebbe essere utilizzata ogni qualvolta possibile ( month , minute , week , weekday , ecc.).

DATEDIFF per il calcolo delle differenze di periodo

Sintassi generale:

DATEDIFF (datepart, datetime_expr1, datetime_expr2)

Restituirà un numero positivo se datetime_expr è nel passato relativo a datetime_expr2 e un numero negativo in caso contrario.

Esempi

DECLARE @now DATETIME2 = GETDATE();
DECLARE @oneYearAgo DATETIME2 = DATEADD(YEAR, -1, @now);
SELECT @now                                    --2016-07-21 14:49:50.9800000
SELECT @oneYearAgo                             --2015-07-21 14:49:50.9800000
SELECT DATEDIFF(YEAR, @oneYearAgo, @now)       --1
SELECT DATEDIFF(QUARTER, @oneYearAgo, @now)    --4
SELECT DATEDIFF(WEEK, @oneYearAgo, @now)       --52
SELECT DATEDIFF(DAY, @oneYearAgo, @now)        --366
SELECT DATEDIFF(HOUR, @oneYearAgo, @now)       --8784
SELECT DATEDIFF(MINUTE, @oneYearAgo, @now)     --527040
SELECT DATEDIFF(SECOND, @oneYearAgo, @now)     --31622400

NOTA: DATEDIFF accetta anche le abbreviazioni nel parametro datepart . L'uso di queste abbreviazioni è generalmente scoraggiato in quanto possono essere fonte di confusione ( m vs mi , ww vs w , ecc.).

DATEDIFF può anche essere utilizzato per determinare l'offset tra UTC e l'ora locale di SQL Server. La seguente istruzione può essere utilizzata per calcolare l'offset tra UTC e l'ora locale (incluso il fuso orario).

select  DATEDIFF(hh, getutcdate(), getdate()) as 'CentralTimeOffset'

DATEPART & DATENAME

DATEPART restituisce la datepart specificata dell'espressione datetime specificata come valore numerico.

DATENAME restituisce una stringa di caratteri che rappresenta la datepart specificata della data specificata. In pratica, DATENAME è utile soprattutto per ottenere il nome del mese o il giorno della settimana.

Esistono anche alcune funzioni abbreviate per ottenere l'anno, il mese o il giorno di un'espressione datetime, che si comportano come DATEPART con le rispettive unità di datepart .

Sintassi:

DATEPART ( datepart , datetime_expr )
DATENAME ( datepart , datetime_expr )
DAY ( datetime_expr )
MONTH ( datetime_expr )
YEAR ( datetime_expr )

Esempi:

DECLARE @now DATETIME2 = GETDATE();
SELECT @now                       --2016-07-21 15:05:33.8370000
SELECT DATEPART(YEAR, @now)       --2016
SELECT DATEPART(QUARTER, @now)    --3
SELECT DATEPART(WEEK, @now)       --30
SELECT DATEPART(HOUR, @now)       --15
SELECT DATEPART(MINUTE, @now)     --5
SELECT DATEPART(SECOND, @now)     --33
-- Differences between DATEPART and DATENAME:
SELECT DATEPART(MONTH, @now)      --7
SELECT DATENAME(MONTH, @now)      --July
SELECT DATEPART(WEEKDAY, @now)    --5
SELECT DATENAME(WEEKDAY, @now)    --Thursday
--shorthand functions
SELECT DAY(@now)    --21
SELECT MONTH(@now)  --7
SELECT YEAR(@now)   --2016

NOTA: DATEPART e DATENAME accettano anche le abbreviazioni nel parametro datepart . L'uso di queste abbreviazioni è generalmente scoraggiato in quanto possono essere fonte di confusione ( m vs mi , ww vs w , ecc.).

Ottenere l'ultimo giorno di un mese

Utilizzando le funzioni DATEADD e DATEDIFF , è possibile restituire l'ultima data del mese.

SELECT DATEADD(d, -1, DATEADD(m, DATEDIFF(m, 0, '2016-09-23') + 1, 0))
-- 2016-09-30 00:00:00.000

SELECT EOMONTH('2016-07-21')        --2016-07-31
SELECT EOMONTH('2016-07-21', 4)     --2016-11-30
SELECT EOMONTH('2016-07-21', -5)    --2016-02-29

Restituisce solo la data da un DateTime

Esistono molti modi per restituire una data da un oggetto DateTime

1. SELECT CONVERT(Date, GETDATE())
2. SELECT DATEADD(dd, 0, DATEDIFF(dd, 0, GETDATE())) restituisce 2016-07-21 00: 00: 00.000
3. SELECT CAST(GETDATE() AS DATE)
4. SELECT CONVERT(CHAR(10),GETDATE(),111)
5. SELECT FORMAT(GETDATE(), 'yyyy-MM-dd')

Nota che le opzioni 4 e 5 restituiscono una stringa, non una data.

Crea una funzione per calcolare l'età di una persona in una data specifica

Questa funzione richiede 2 parametri datetime, il DOB e una data per verificare l'età in

  CREATE FUNCTION [dbo].[Calc_Age]
    (
    @DOB datetime , @calcDate datetime 
    )
    RETURNS int
    AS
   BEGIN
declare @age int

IF (@calcDate < @DOB  )
RETURN -1

-- If a DOB is supplied after the comparison date, then return -1
SELECT @age = YEAR(@calcDate) - YEAR(@DOB) +
  CASE WHEN DATEADD(year,YEAR(@calcDate) - YEAR(@DOB)
  ,@DOB) > @calcDate THEN -1 ELSE 0 END
    

RETURN @age
    

END

ad esempio per verificare l'età di oggi di qualcuno nato il 1 ° gennaio 2000

SELECT  dbo.Calc_Age('2000-01-01',Getdate())

OGGETTO DELLA DATA DELLA PIATTAFORMA CROSS

 DECLARE @myDate DATE=DATEFROMPARTS(1988,11,28) 
 DECLARE @someMoment DATETIME=DATEFROMPARTS(1988,11,28,10,30,50,123)

Formato data esteso