Microsoft SQL Server
datum

Syntax

• EOMONTH ( startdatum [, månad_till_add])

Anmärkningar

Datum och tid formatering med CONVERT

Du kan använda CONVERT-funktionen för att kasta en datatyp i en formaterad sträng.

SELECT GETDATE() AS [Result] -- 2016-07-21 07:56:10.927

Du kan också använda några inbyggda koder för att konvertera till ett specifikt format. Här är alternativen inbyggda i SQL Server:

DECLARE @convert_code INT = 100 -- See Table Below
SELECT CONVERT(VARCHAR(30), GETDATE(), @convert_code) AS [Result]

SELECT GETDATE() AS [Result]                                -- 2016-07-21 07:56:10.927
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),100) AS [Result] -- Jul 21 2016  7:56AM
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),101) AS [Result] -- 07/21/2016
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),102) AS [Result] -- 2016.07.21
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),103) AS [Result] -- 21/07/2016
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),104) AS [Result] -- 21.07.2016
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),105) AS [Result] -- 21-07-2016
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),106) AS [Result] -- 21 Jul 2016
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),107) AS [Result] -- Jul 21, 2016
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),108) AS [Result] -- 07:57:05
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),109) AS [Result] -- Jul 21 2016  7:57:45:707AM
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),110) AS [Result] -- 07-21-2016
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),111) AS [Result] -- 2016/07/21
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),112) AS [Result] -- 20160721
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),113) AS [Result] -- 21 Jul 2016 07:57:59:553
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),114) AS [Result] -- 07:57:59:553
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),120) AS [Result] -- 2016-07-21 07:57:59
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),121) AS [Result] -- 2016-07-21 07:57:59.553
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),126) AS [Result] -- 2016-07-21T07:58:34.340
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),127) AS [Result] -- 2016-07-21T07:58:34.340
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),130) AS [Result] -- 16 ???? 1437  7:58:34:340AM
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),131) AS [Result] -- 16/10/1437  7:58:34:340AM

Datum och tidformatering med FORMAT

DECLARE @Date DATETIME = '2016-09-05 00:01:02.333'

SELECT FORMAT(@Date, N'dddd, MMMM dd, yyyy hh:mm:ss tt')

DECLARE @Date DATETIME = '2016-09-05 00:01:02.333'

SELECT FORMAT(@Date, N'U')

DECLARE @Date DATETIME = '2016-09-05 00:01:02.333'

SELECT FORMAT(@Date, N'U', 'zh-cn')

Hämta den aktuella DateTime

De inbyggda funktionerna GETDATE och GETUTCDATE returnerar var och en aktuellt datum och tid utan en tidszonförskjutning.

Returvärdet för båda funktionerna är baserat på operativsystemet på den dator som förekomsten av SQL Server körs på.

Returvärdet för GETDATE representerar den aktuella tiden i samma tidszon som operativsystemet. Returvärdet för GETUTCDATE representerar aktuell UTC-tid.

Endera funktionen kan inkluderas i SELECT klausulen i en fråga eller som del av booleskt uttryck i WHERE klausulen.

Exempel:

-- example query that selects the current time in both the server time zone and UTC
SELECT GETDATE() as SystemDateTime, GETUTCDATE() as UTCDateTime

-- example query records with EventDate in the past.
SELECT * FROM MyEvents WHERE EventDate < GETDATE() 

Det finns några andra inbyggda funktioner som returnerar olika variationer av det aktuella datumet:

SELECT 
    GETDATE(),          --2016-07-21 14:27:37.447
    GETUTCDATE(),       --2016-07-21 18:27:37.447
    CURRENT_TIMESTAMP,  --2016-07-21 14:27:37.447
    SYSDATETIME(),      --2016-07-21 14:27:37.4485768
    SYSDATETIMEOFFSET(),--2016-07-21 14:27:37.4485768 -04:00
    SYSUTCDATETIME()    --2016-07-21 18:27:37.4485768

DATEADD för att lägga till och subtrahera tidsperioder

Allmän syntax:

DATEADD (datepart , number , datetime_expr)  

För att lägga till en tidsmätning måste number vara positivt. För att subtrahera en tidsmätning måste number vara negativt.

exempel

DECLARE @now DATETIME2 = GETDATE();
SELECT @now;                        --2016-07-21 14:39:46.4170000
SELECT DATEADD(YEAR, 1, @now)       --2017-07-21 14:39:46.4170000
SELECT DATEADD(QUARTER, 1, @now)    --2016-10-21 14:39:46.4170000
SELECT DATEADD(WEEK, 1, @now)       --2016-07-28 14:39:46.4170000
SELECT DATEADD(DAY, 1, @now)        --2016-07-22 14:39:46.4170000
SELECT DATEADD(HOUR, 1, @now)       --2016-07-21 15:39:46.4170000
SELECT DATEADD(MINUTE, 1, @now)     --2016-07-21 14:40:46.4170000
SELECT DATEADD(SECOND, 1, @now)     --2016-07-21 14:39:47.4170000
SELECT DATEADD(MILLISECOND, 1, @now)--2016-07-21 14:39:46.4180000

OBS: DATEADD accepterar också förkortningar i parametern datepart . Användning av dessa förkortningar avlägsnas generellt eftersom de kan vara förvirrande ( m vs mi , ww vs w , etc.).

Datum för referens

Dessa är datepart tillgängliga för datepart och tidsfunktioner:

OBS! Användning av förkortningar avlägsnas vanligtvis eftersom de kan vara förvirrande ( m vs mi , ww vs w , etc.). Den långa versionen av datepart främjar tydlighet och läsbarhet och bör användas när det är möjligt ( month , minute , week , weekday etc.).

DATEDIFF för att beräkna skillnader i tidsperiod

Allmän syntax:

DATEDIFF (datepart, datetime_expr1, datetime_expr2)

Det kommer att returnera ett positivt nummer om datetime_expr är tidigare i förhållande till datetime_expr2 , och ett negativt nummer annars.

exempel

DECLARE @now DATETIME2 = GETDATE();
DECLARE @oneYearAgo DATETIME2 = DATEADD(YEAR, -1, @now);
SELECT @now                                    --2016-07-21 14:49:50.9800000
SELECT @oneYearAgo                             --2015-07-21 14:49:50.9800000
SELECT DATEDIFF(YEAR, @oneYearAgo, @now)       --1
SELECT DATEDIFF(QUARTER, @oneYearAgo, @now)    --4
SELECT DATEDIFF(WEEK, @oneYearAgo, @now)       --52
SELECT DATEDIFF(DAY, @oneYearAgo, @now)        --366
SELECT DATEDIFF(HOUR, @oneYearAgo, @now)       --8784
SELECT DATEDIFF(MINUTE, @oneYearAgo, @now)     --527040
SELECT DATEDIFF(SECOND, @oneYearAgo, @now)     --31622400

OBS: DATEDIFF accepterar också förkortningar i parametern datepart . Användning av dessa förkortningar avlägsnas generellt eftersom de kan vara förvirrande ( m vs mi , ww vs w , etc.).

DATEDIFF kan också användas för att bestämma förskjutningen mellan UTC och den lokala tiden för SQL Server. Följande uttalande kan användas för att beräkna offset mellan UTC och lokal tid (inklusive tidszon).

select  DATEDIFF(hh, getutcdate(), getdate()) as 'CentralTimeOffset'

DATEPART & DATENAME

DATEPART returnerar det angivna datepart för det angivna datumet uttrycket som ett numeriskt värde.

DATENAME returnerar en teckensträng som representerar den angivna datepart för det angivna datumet. I praktiken är DATENAME mest användbar för att få DATENAME namn eller veckodag.

Det finns också några korta funktioner för att få året, månaden eller dagen för ett datetime-uttryck, som uppträder som DATEPART med sina respektive datepart enheter.

Syntax:

DATEPART ( datepart , datetime_expr )
DATENAME ( datepart , datetime_expr )
DAY ( datetime_expr )
MONTH ( datetime_expr )
YEAR ( datetime_expr )

Exempel:

DECLARE @now DATETIME2 = GETDATE();
SELECT @now                       --2016-07-21 15:05:33.8370000
SELECT DATEPART(YEAR, @now)       --2016
SELECT DATEPART(QUARTER, @now)    --3
SELECT DATEPART(WEEK, @now)       --30
SELECT DATEPART(HOUR, @now)       --15
SELECT DATEPART(MINUTE, @now)     --5
SELECT DATEPART(SECOND, @now)     --33
-- Differences between DATEPART and DATENAME:
SELECT DATEPART(MONTH, @now)      --7
SELECT DATENAME(MONTH, @now)      --July
SELECT DATEPART(WEEKDAY, @now)    --5
SELECT DATENAME(WEEKDAY, @now)    --Thursday
--shorthand functions
SELECT DAY(@now)    --21
SELECT MONTH(@now)  --7
SELECT YEAR(@now)   --2016

OBS: DATEPART och DATENAME accepterar också förkortningar i parametern datepart . Användning av dessa förkortningar avlägsnas generellt eftersom de kan vara förvirrande ( m vs mi , ww vs w , etc.).

Få den sista dagen i en månad

Med DATEADD och DATEDIFF är det möjligt att returnera det sista datumet i en månad.

SELECT DATEADD(d, -1, DATEADD(m, DATEDIFF(m, 0, '2016-09-23') + 1, 0))
-- 2016-09-30 00:00:00.000

SELECT EOMONTH('2016-07-21')        --2016-07-31
SELECT EOMONTH('2016-07-21', 4)     --2016-11-30
SELECT EOMONTH('2016-07-21', -5)    --2016-02-29

Returnera bara datum från en DateTime

Det finns många sätt att returnera ett datum från ett DateTime-objekt

1. SELECT CONVERT(Date, GETDATE())
2. SELECT DATEADD(dd, 0, DATEDIFF(dd, 0, GETDATE())) returnerar 2016-07-21 00: 00: 00.000
3. SELECT CAST(GETDATE() AS DATE)
4. SELECT CONVERT(CHAR(10),GETDATE(),111)
5. SELECT FORMAT(GETDATE(), 'yyyy-MM-dd')

Observera att alternativ 4 och 5 returnerar en sträng, inte ett datum.

Skapa funktion för att beräkna en persons ålder på ett specifikt datum

Denna funktion tar två datetime-parametrar, DOB och ett datum för att kontrollera åldern kl

  CREATE FUNCTION [dbo].[Calc_Age]
    (
    @DOB datetime , @calcDate datetime 
    )
    RETURNS int
    AS
   BEGIN
declare @age int

IF (@calcDate < @DOB  )
RETURN -1

-- If a DOB is supplied after the comparison date, then return -1
SELECT @age = YEAR(@calcDate) - YEAR(@DOB) +
  CASE WHEN DATEADD(year,YEAR(@calcDate) - YEAR(@DOB)
  ,@DOB) > @calcDate THEN -1 ELSE 0 END
    

RETURN @age
    

END

t.ex. för att kontrollera åldern i dag för någon som är född 1/1/2000

SELECT  dbo.Calc_Age('2000-01-01',Getdate())

KROSSPLATFORM DATUMMÅL

 DECLARE @myDate DATE=DATEFROMPARTS(1988,11,28) 
 DECLARE @someMoment DATETIME=DATEFROMPARTS(1988,11,28,10,30,50,123)

Datumformat Utökad