Microsoft SQL Server
日付

構文

• EOMONTH（ 開始日 [、month_to_add]）

備考

CONVERTを使用した日付と時刻の書式設定

CONVERT関数を使用して、日時データ型を書式設定された文字列にキャストできます。

SELECT GETDATE() AS [Result] -- 2016-07-21 07:56:10.927

組み込みのコードを使用して、特定の形式に変換することもできます。 SQL Serverに組み込まれているオプションは次のとおりです。

DECLARE @convert_code INT = 100 -- See Table Below
SELECT CONVERT(VARCHAR(30), GETDATE(), @convert_code) AS [Result]

SELECT GETDATE() AS [Result]                                -- 2016-07-21 07:56:10.927
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),100) AS [Result] -- Jul 21 2016  7:56AM
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),101) AS [Result] -- 07/21/2016
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),102) AS [Result] -- 2016.07.21
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),103) AS [Result] -- 21/07/2016
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),104) AS [Result] -- 21.07.2016
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),105) AS [Result] -- 21-07-2016
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),106) AS [Result] -- 21 Jul 2016
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),107) AS [Result] -- Jul 21, 2016
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),108) AS [Result] -- 07:57:05
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),109) AS [Result] -- Jul 21 2016  7:57:45:707AM
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),110) AS [Result] -- 07-21-2016
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),111) AS [Result] -- 2016/07/21
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),112) AS [Result] -- 20160721
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),113) AS [Result] -- 21 Jul 2016 07:57:59:553
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),114) AS [Result] -- 07:57:59:553
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),120) AS [Result] -- 2016-07-21 07:57:59
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),121) AS [Result] -- 2016-07-21 07:57:59.553
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),126) AS [Result] -- 2016-07-21T07:58:34.340
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),127) AS [Result] -- 2016-07-21T07:58:34.340
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),130) AS [Result] -- 16 ???? 1437  7:58:34:340AM
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),131) AS [Result] -- 16/10/1437  7:58:34:340AM

FORMATを使用した日付と時刻の書式設定

DECLARE @Date DATETIME = '2016-09-05 00:01:02.333'

SELECT FORMAT(@Date, N'dddd, MMMM dd, yyyy hh:mm:ss tt')

DECLARE @Date DATETIME = '2016-09-05 00:01:02.333'

SELECT FORMAT(@Date, N'U')

DECLARE @Date DATETIME = '2016-09-05 00:01:02.333'

SELECT FORMAT(@Date, N'U', 'zh-cn')

現在のDateTimeを取得する

組み込み関数GETDATEとGETUTCDATEそれぞれ、現在の日付と時刻をタイムゾーンオフセットなしで返します。

両方の関数の戻り値は、SQL Serverのインスタンスが実行されているコンピュータのオペレーティングシステムに基づいています。

GETDATEの戻り値は、オペレーティングシステムと同じタイムゾーン内の現在の時刻を表します。 GETUTCDATEの戻り値は、現在のUTC時間を表します。

いずれの関数も、問合せのSELECT句またはWHERE句のブール式の一部として含めることができます。

例：

-- example query that selects the current time in both the server time zone and UTC
SELECT GETDATE() as SystemDateTime, GETUTCDATE() as UTCDateTime

-- example query records with EventDate in the past.
SELECT * FROM MyEvents WHERE EventDate < GETDATE() 

現在の日時のさまざまなバリエーションを返す組み込み関数がいくつかあります：

SELECT 
    GETDATE(),          --2016-07-21 14:27:37.447
    GETUTCDATE(),       --2016-07-21 18:27:37.447
    CURRENT_TIMESTAMP,  --2016-07-21 14:27:37.447
    SYSDATETIME(),      --2016-07-21 14:27:37.4485768
    SYSDATETIMEOFFSET(),--2016-07-21 14:27:37.4485768 -04:00
    SYSUTCDATETIME()    --2016-07-21 18:27:37.4485768

期間の加算と減算のためのDATEADD

一般的な構文：

DATEADD (datepart , number , datetime_expr)  

時間尺度を追加するには、 numberが正でなければなりません。時間尺度を減算するには、 numberが負でなければなりません。

例

DECLARE @now DATETIME2 = GETDATE();
SELECT @now;                        --2016-07-21 14:39:46.4170000
SELECT DATEADD(YEAR, 1, @now)       --2017-07-21 14:39:46.4170000
SELECT DATEADD(QUARTER, 1, @now)    --2016-10-21 14:39:46.4170000
SELECT DATEADD(WEEK, 1, @now)       --2016-07-28 14:39:46.4170000
SELECT DATEADD(DAY, 1, @now)        --2016-07-22 14:39:46.4170000
SELECT DATEADD(HOUR, 1, @now)       --2016-07-21 15:39:46.4170000
SELECT DATEADD(MINUTE, 1, @now)     --2016-07-21 14:40:46.4170000
SELECT DATEADD(SECOND, 1, @now)     --2016-07-21 14:39:47.4170000
SELECT DATEADD(MILLISECOND, 1, @now)--2016-07-21 14:39:46.4180000

注： DATEADDはdatepartパラメータに略語も受け入れます。これらの略語の使用は、混乱する可能性があるため一般的には推奨されません（ m対mi 、 ww対wなど）。

日付パーツ参照

日付と時刻関数で使用できるdatepart値は次のとおりdatepart 。

注記 ：略語の使用は、混乱する可能性があるため一般的には使用しないでください（ m対mi 、 ww対wなど）。可能であれば（ month 、 minute 、 week 、 weekdayなど）、 datepart表現の長いバージョンは明快さと可読性を促進します。

時間差を計算するためのDATEDIFF

一般的な構文：

DATEDIFF (datepart, datetime_expr1, datetime_expr2)

datetime_exprがdatetime_expr2基準として過去にある場合は正の数を返し、そうでない場合は負の数を返します。

例

DECLARE @now DATETIME2 = GETDATE();
DECLARE @oneYearAgo DATETIME2 = DATEADD(YEAR, -1, @now);
SELECT @now                                    --2016-07-21 14:49:50.9800000
SELECT @oneYearAgo                             --2015-07-21 14:49:50.9800000
SELECT DATEDIFF(YEAR, @oneYearAgo, @now)       --1
SELECT DATEDIFF(QUARTER, @oneYearAgo, @now)    --4
SELECT DATEDIFF(WEEK, @oneYearAgo, @now)       --52
SELECT DATEDIFF(DAY, @oneYearAgo, @now)        --366
SELECT DATEDIFF(HOUR, @oneYearAgo, @now)       --8784
SELECT DATEDIFF(MINUTE, @oneYearAgo, @now)     --527040
SELECT DATEDIFF(SECOND, @oneYearAgo, @now)     --31622400

注： DATEDIFFでは、 datepartパラメータに略語も使用できます。これらの略語の使用は、混乱する可能性があるため一般的には推奨されません（ m対mi 、 ww対wなど）。

DATEDIFFを使用して、UTCとSQL Serverのローカル時刻との間のオフセットを特定することもできます。次のステートメントは、UTCと現地時間（タイムゾーンを含む）間のオフセットを計算するために使用できます。

select  DATEDIFF(hh, getutcdate(), getdate()) as 'CentralTimeOffset'

DATEPART＆DATENAME

DATEPARTは、指定されたdatetime式の指定されたdatepartを数値として返します。

DATENAMEは、指定された日付の指定されたdatepartを表す文字列を戻します。実際には、 DATENAMEは月または曜日の名前を取得するのに最も便利です。

日時式の年、月、または日を取得するための短縮形関数もいくつかあります。これはそれぞれのdatepart単位でDATEPARTように動作します。

構文：

DATEPART ( datepart , datetime_expr )
DATENAME ( datepart , datetime_expr )
DAY ( datetime_expr )
MONTH ( datetime_expr )
YEAR ( datetime_expr )

例：

DECLARE @now DATETIME2 = GETDATE();
SELECT @now                       --2016-07-21 15:05:33.8370000
SELECT DATEPART(YEAR, @now)       --2016
SELECT DATEPART(QUARTER, @now)    --3
SELECT DATEPART(WEEK, @now)       --30
SELECT DATEPART(HOUR, @now)       --15
SELECT DATEPART(MINUTE, @now)     --5
SELECT DATEPART(SECOND, @now)     --33
-- Differences between DATEPART and DATENAME:
SELECT DATEPART(MONTH, @now)      --7
SELECT DATENAME(MONTH, @now)      --July
SELECT DATEPART(WEEKDAY, @now)    --5
SELECT DATENAME(WEEKDAY, @now)    --Thursday
--shorthand functions
SELECT DAY(@now)    --21
SELECT MONTH(@now)  --7
SELECT YEAR(@now)   --2016

注： DATEPARTとDATENAMEは、 datepartパラメータに略語も受け入れます。これらの略語の使用は、混乱する可能性があるため一般的には推奨されません（ m対mi 、 ww対wなど）。

一ヶ月の最後の日を取得する

DATEADDとDATEDIFF関数を使用すると、月の最後の日付を返すことができます。

SELECT DATEADD(d, -1, DATEADD(m, DATEDIFF(m, 0, '2016-09-23') + 1, 0))
-- 2016-09-30 00:00:00.000

SELECT EOMONTH('2016-07-21')        --2016-07-31
SELECT EOMONTH('2016-07-21', 4)     --2016-11-30
SELECT EOMONTH('2016-07-21', -5)    --2016-02-29

DateTimeからDateを返す

DateTimeオブジェクトからDateを返す方法はたくさんあります

1. SELECT CONVERT(Date, GETDATE())
2. SELECT DATEADD(dd, 0, DATEDIFF(dd, 0, GETDATE()))は、2016-07-21 00：00：00.000を返します。
3. SELECT CAST(GETDATE() AS DATE)
4. SELECT CONVERT(CHAR(10),GETDATE(),111)
5. SELECT FORMAT(GETDATE(), 'yyyy-MM-dd')

オプション4と5は日付ではなく文字列を返します。

特定の日付に人の年齢を計算する関数を作成する

この関数は、2つの日時パラメータ、DOB、および年齢を確認する日付を取る

  CREATE FUNCTION [dbo].[Calc_Age]
    (
    @DOB datetime , @calcDate datetime 
    )
    RETURNS int
    AS
   BEGIN
declare @age int

IF (@calcDate < @DOB  )
RETURN -1

-- If a DOB is supplied after the comparison date, then return -1
SELECT @age = YEAR(@calcDate) - YEAR(@DOB) +
  CASE WHEN DATEADD(year,YEAR(@calcDate) - YEAR(@DOB)
  ,@DOB) > @calcDate THEN -1 ELSE 0 END
    

RETURN @age
    

END

2000年1月1日に生まれた人の今日の年齢を確認する

SELECT  dbo.Calc_Age('2000-01-01',Getdate())

CROSS PLATFORM DATE OBJECT

 DECLARE @myDate DATE=DATEFROMPARTS(1988,11,28) 
 DECLARE @someMoment DATETIME=DATEFROMPARTS(1988,11,28,10,30,50,123)

日付形式の拡張