Microsoft SQL Server
खजूर

वाक्य - विन्यास

• EOMONTH ( start_date [, month_to_add])

टिप्पणियों

CONVERT का उपयोग करके दिनांक और समय स्वरूपण

आप एक प्रारूपित स्ट्रिंग के लिए एक डेटाइम डेटटाइप कास्ट करने के लिए CONVERT फ़ंक्शन का उपयोग कर सकते हैं।

SELECT GETDATE() AS [Result] -- 2016-07-21 07:56:10.927

आप किसी विशिष्ट प्रारूप में परिवर्तित करने के लिए कुछ अंतर्निहित कोड का भी उपयोग कर सकते हैं। यहाँ SQL सर्वर में निर्मित विकल्प हैं:

DECLARE @convert_code INT = 100 -- See Table Below
SELECT CONVERT(VARCHAR(30), GETDATE(), @convert_code) AS [Result]

SELECT GETDATE() AS [Result]                                -- 2016-07-21 07:56:10.927
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),100) AS [Result] -- Jul 21 2016  7:56AM
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),101) AS [Result] -- 07/21/2016
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),102) AS [Result] -- 2016.07.21
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),103) AS [Result] -- 21/07/2016
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),104) AS [Result] -- 21.07.2016
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),105) AS [Result] -- 21-07-2016
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),106) AS [Result] -- 21 Jul 2016
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),107) AS [Result] -- Jul 21, 2016
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),108) AS [Result] -- 07:57:05
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),109) AS [Result] -- Jul 21 2016  7:57:45:707AM
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),110) AS [Result] -- 07-21-2016
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),111) AS [Result] -- 2016/07/21
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),112) AS [Result] -- 20160721
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),113) AS [Result] -- 21 Jul 2016 07:57:59:553
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),114) AS [Result] -- 07:57:59:553
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),120) AS [Result] -- 2016-07-21 07:57:59
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),121) AS [Result] -- 2016-07-21 07:57:59.553
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),126) AS [Result] -- 2016-07-21T07:58:34.340
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),127) AS [Result] -- 2016-07-21T07:58:34.340
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),130) AS [Result] -- 16 ???? 1437  7:58:34:340AM
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),131) AS [Result] -- 16/10/1437  7:58:34:340AM

FORMAT का उपयोग करके दिनांक और समय स्वरूपण

DECLARE @Date DATETIME = '2016-09-05 00:01:02.333'

SELECT FORMAT(@Date, N'dddd, MMMM dd, yyyy hh:mm:ss tt')

DECLARE @Date DATETIME = '2016-09-05 00:01:02.333'

SELECT FORMAT(@Date, N'U')

DECLARE @Date DATETIME = '2016-09-05 00:01:02.333'

SELECT FORMAT(@Date, N'U', 'zh-cn')

वर्तमान दिनांक समय प्राप्त करें

बिल्ट-इन फ़ंक्शन GETDATE और GETUTCDATE प्रत्येक को एक समय क्षेत्र ऑफ़सेट के बिना वर्तमान दिनांक और समय लौटाता है।

दोनों फ़ंक्शन का रिटर्न मान उस कंप्यूटर के ऑपरेटिंग सिस्टम पर आधारित है जिस पर SQL सर्वर का उदाहरण चल रहा है।

GETDATE का रिटर्न मान ऑपरेटिंग सिस्टम के समान टाइमज़ोन में वर्तमान समय का प्रतिनिधित्व करता है। GETUTCDATE का रिटर्न मान वर्तमान UTC समय का प्रतिनिधित्व करता है।

किसी भी फ़ंक्शन को क्वेरी के SELECT क्लॉज़ में या WHERE क्लॉज़ में बूलियन अभिव्यक्ति के भाग के रूप में शामिल किया जा सकता है।

उदाहरण:

-- example query that selects the current time in both the server time zone and UTC
SELECT GETDATE() as SystemDateTime, GETUTCDATE() as UTCDateTime

-- example query records with EventDate in the past.
SELECT * FROM MyEvents WHERE EventDate < GETDATE() 

कुछ अन्य अंतर्निहित कार्य हैं जो वर्तमान तिथि-समय के विभिन्न रूपों को लौटाते हैं:

SELECT 
    GETDATE(),          --2016-07-21 14:27:37.447
    GETUTCDATE(),       --2016-07-21 18:27:37.447
    CURRENT_TIMESTAMP,  --2016-07-21 14:27:37.447
    SYSDATETIME(),      --2016-07-21 14:27:37.4485768
    SYSDATETIMEOFFSET(),--2016-07-21 14:27:37.4485768 -04:00
    SYSUTCDATETIME()    --2016-07-21 18:27:37.4485768

समय अवधि को जोड़ने और घटाने के लिए DATEADD

सामान्य सिंटैक्स:

DATEADD (datepart , number , datetime_expr)  

एक समय उपाय जोड़ने के लिए, number सकारात्मक होनी चाहिए। समय मापने के लिए, number को नकारात्मक होना चाहिए।

उदाहरण

DECLARE @now DATETIME2 = GETDATE();
SELECT @now;                        --2016-07-21 14:39:46.4170000
SELECT DATEADD(YEAR, 1, @now)       --2017-07-21 14:39:46.4170000
SELECT DATEADD(QUARTER, 1, @now)    --2016-10-21 14:39:46.4170000
SELECT DATEADD(WEEK, 1, @now)       --2016-07-28 14:39:46.4170000
SELECT DATEADD(DAY, 1, @now)        --2016-07-22 14:39:46.4170000
SELECT DATEADD(HOUR, 1, @now)       --2016-07-21 15:39:46.4170000
SELECT DATEADD(MINUTE, 1, @now)     --2016-07-21 14:40:46.4170000
SELECT DATEADD(SECOND, 1, @now)     --2016-07-21 14:39:47.4170000
SELECT DATEADD(MILLISECOND, 1, @now)--2016-07-21 14:39:46.4180000

नोट: DATEADD भी datepart पैरामीटर में संक्षिप्ताक्षर स्वीकार करता है। इन संक्षिप्तीकरणों का उपयोग आमतौर पर हतोत्साहित किया जाता है क्योंकि वे भ्रमित हो सकते हैं ( m vs mi , ww vs w , आदि)।

दिनांक भागों संदर्भ

ये हैं datepart दिनांक और समय कार्यों के लिए उपलब्ध मान:

नोट : संक्षिप्तीकरण का उपयोग आमतौर पर हतोत्साहित किया जाता है क्योंकि वे भ्रमित हो सकते हैं ( m vs mi , ww vs w , आदि)। datepart प्रतिनिधित्व का लंबा संस्करण स्पष्टता और पठनीयता को बढ़ावा देता है, और जब भी संभव हो ( month , minute , week , weekday , आदि) का उपयोग किया जाना चाहिए।

समय अवधि के अंतर की गणना के लिए दिनांकित

सामान्य सिंटैक्स:

DATEDIFF (datepart, datetime_expr1, datetime_expr2)

यह एक सकारात्मक संख्या वापस आ जाएगी अगर datetime_expr पिछले सापेक्ष में है datetime_expr2 , और नहीं तो एक ऋणात्मक संख्या।

उदाहरण

DECLARE @now DATETIME2 = GETDATE();
DECLARE @oneYearAgo DATETIME2 = DATEADD(YEAR, -1, @now);
SELECT @now                                    --2016-07-21 14:49:50.9800000
SELECT @oneYearAgo                             --2015-07-21 14:49:50.9800000
SELECT DATEDIFF(YEAR, @oneYearAgo, @now)       --1
SELECT DATEDIFF(QUARTER, @oneYearAgo, @now)    --4
SELECT DATEDIFF(WEEK, @oneYearAgo, @now)       --52
SELECT DATEDIFF(DAY, @oneYearAgo, @now)        --366
SELECT DATEDIFF(HOUR, @oneYearAgo, @now)       --8784
SELECT DATEDIFF(MINUTE, @oneYearAgo, @now)     --527040
SELECT DATEDIFF(SECOND, @oneYearAgo, @now)     --31622400

नोट: DATEDIFF भी संक्षिप्त रूपों को स्वीकार करता है datepart पैरामीटर। इन संक्षिप्तीकरणों का उपयोग आमतौर पर हतोत्साहित किया जाता है क्योंकि वे भ्रमित हो सकते हैं ( m vs mi , ww vs w , आदि)।

DATEDIFF उपयोग UTC और SQL सर्वर के स्थानीय समय के बीच ऑफसेट को निर्धारित करने के लिए भी किया जा सकता है। यूटीसी और स्थानीय समय (टाइमज़ोन सहित) के बीच ऑफसेट की गणना करने के लिए निम्नलिखित कथन का उपयोग किया जा सकता है।

select  DATEDIFF(hh, getutcdate(), getdate()) as 'CentralTimeOffset'

DATEPART और DATENAME

DATEPART एक संख्यात्मक मान के रूप में निर्दिष्ट datepart अभिव्यक्ति के निर्दिष्ट दिनांक को लौटाता है।

DATENAME एक चरित्र स्ट्रिंग कि निर्दिष्ट प्रतिनिधित्व रिटर्न datepart निर्धारित तिथि के। व्यवहार में DATENAME ज्यादातर महीने या सप्ताह के दिन का नाम प्राप्त करने के लिए उपयोगी है।

DATEPART एक्सप्रेशन के वर्ष, महीने या दिन प्राप्त करने के लिए कुछ शॉर्टहैंड फ़ंक्शन भी होते हैं, जो अपनी संबंधित datepart इकाइयों के साथ DATEPART तरह व्यवहार करते हैं।

वाक्य - विन्यास:

DATEPART ( datepart , datetime_expr )
DATENAME ( datepart , datetime_expr )
DAY ( datetime_expr )
MONTH ( datetime_expr )
YEAR ( datetime_expr )

उदाहरण:

DECLARE @now DATETIME2 = GETDATE();
SELECT @now                       --2016-07-21 15:05:33.8370000
SELECT DATEPART(YEAR, @now)       --2016
SELECT DATEPART(QUARTER, @now)    --3
SELECT DATEPART(WEEK, @now)       --30
SELECT DATEPART(HOUR, @now)       --15
SELECT DATEPART(MINUTE, @now)     --5
SELECT DATEPART(SECOND, @now)     --33
-- Differences between DATEPART and DATENAME:
SELECT DATEPART(MONTH, @now)      --7
SELECT DATENAME(MONTH, @now)      --July
SELECT DATEPART(WEEKDAY, @now)    --5
SELECT DATENAME(WEEKDAY, @now)    --Thursday
--shorthand functions
SELECT DAY(@now)    --21
SELECT MONTH(@now)  --7
SELECT YEAR(@now)   --2016

नोट: DATEPART और DATENAME भी datepart पैरामीटर में संक्षिप्त रूप स्वीकार करते हैं। इन संक्षिप्तीकरणों का उपयोग आमतौर पर हतोत्साहित किया जाता है क्योंकि वे भ्रमित हो सकते हैं ( m vs mi , ww vs w , आदि)।

महीने का आखिरी दिन हो रहा है

का उपयोग करते हुए DATEADD और DATEDIFF काम करता है, यह एक महीने की अंतिम तारीख वापस जाने के लिए संभव है।

SELECT DATEADD(d, -1, DATEADD(m, DATEDIFF(m, 0, '2016-09-23') + 1, 0))
-- 2016-09-30 00:00:00.000

SELECT EOMONTH('2016-07-21')        --2016-07-31
SELECT EOMONTH('2016-07-21', 4)     --2016-11-30
SELECT EOMONTH('2016-07-21', -5)    --2016-02-29

किसी DateTime से बस दिनांक लौटाएँ

DateTime ऑब्जेक्ट से किसी दिनांक को वापस करने के कई तरीके हैं

1. SELECT CONVERT(Date, GETDATE())
2. SELECT DATEADD(dd, 0, DATEDIFF(dd, 0, GETDATE())) 2016-07-21 00: 00: 00.000
3. SELECT CAST(GETDATE() AS DATE)
4. SELECT CONVERT(CHAR(10),GETDATE(),111)
5. SELECT FORMAT(GETDATE(), 'yyyy-MM-dd')

ध्यान दें कि विकल्प 4 और 5 एक स्ट्रिंग देता है, तारीख नहीं।

किसी विशिष्ट तिथि पर किसी व्यक्ति की आयु की गणना करने के लिए फ़ंक्शन बनाएं

यह फ़ंक्शन 2 डेटाइम पैरामीटर, DOB और आयु की जांच करने की तारीख लेगा

  CREATE FUNCTION [dbo].[Calc_Age]
    (
    @DOB datetime , @calcDate datetime 
    )
    RETURNS int
    AS
   BEGIN
declare @age int

IF (@calcDate < @DOB  )
RETURN -1

-- If a DOB is supplied after the comparison date, then return -1
SELECT @age = YEAR(@calcDate) - YEAR(@DOB) +
  CASE WHEN DATEADD(year,YEAR(@calcDate) - YEAR(@DOB)
  ,@DOB) > @calcDate THEN -1 ELSE 0 END
    

RETURN @age
    

END

जैसे 1/1/2000 को पैदा हुए किसी व्यक्ति की आयु की जांच करना

SELECT  dbo.Calc_Age('2000-01-01',Getdate())

क्रॉस प्लेटफ़ॉर्म दिनांक OBJECT

 DECLARE @myDate DATE=DATEFROMPARTS(1988,11,28) 
 DECLARE @someMoment DATETIME=DATEFROMPARTS(1988,11,28,10,30,50,123)

तिथि प्रारूप विस्तारित