Microsoft SQL Server
Daktyle

Składnia

• EOMONTH ( data_początkowa [, miesiąc_do_add])

Uwagi

Formatowanie daty i godziny za pomocą CONVERT

Za pomocą funkcji CONVERT można rzutować typ danych datetime na sformatowany ciąg.

SELECT GETDATE() AS [Result] -- 2016-07-21 07:56:10.927

Możesz również użyć niektórych wbudowanych kodów do konwersji na określony format. Oto opcje wbudowane w SQL Server:

DECLARE @convert_code INT = 100 -- See Table Below
SELECT CONVERT(VARCHAR(30), GETDATE(), @convert_code) AS [Result]

SELECT GETDATE() AS [Result]                                -- 2016-07-21 07:56:10.927
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),100) AS [Result] -- Jul 21 2016  7:56AM
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),101) AS [Result] -- 07/21/2016
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),102) AS [Result] -- 2016.07.21
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),103) AS [Result] -- 21/07/2016
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),104) AS [Result] -- 21.07.2016
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),105) AS [Result] -- 21-07-2016
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),106) AS [Result] -- 21 Jul 2016
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),107) AS [Result] -- Jul 21, 2016
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),108) AS [Result] -- 07:57:05
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),109) AS [Result] -- Jul 21 2016  7:57:45:707AM
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),110) AS [Result] -- 07-21-2016
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),111) AS [Result] -- 2016/07/21
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),112) AS [Result] -- 20160721
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),113) AS [Result] -- 21 Jul 2016 07:57:59:553
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),114) AS [Result] -- 07:57:59:553
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),120) AS [Result] -- 2016-07-21 07:57:59
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),121) AS [Result] -- 2016-07-21 07:57:59.553
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),126) AS [Result] -- 2016-07-21T07:58:34.340
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),127) AS [Result] -- 2016-07-21T07:58:34.340
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),130) AS [Result] -- 16 ???? 1437  7:58:34:340AM
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),131) AS [Result] -- 16/10/1437  7:58:34:340AM

Formatowanie daty i godziny za pomocą FORMATU

DECLARE @Date DATETIME = '2016-09-05 00:01:02.333'

SELECT FORMAT(@Date, N'dddd, MMMM dd, yyyy hh:mm:ss tt')

DECLARE @Date DATETIME = '2016-09-05 00:01:02.333'

SELECT FORMAT(@Date, N'U')

DECLARE @Date DATETIME = '2016-09-05 00:01:02.333'

SELECT FORMAT(@Date, N'U', 'zh-cn')

Pobierz bieżącą datę i godzinę

Wbudowane funkcje GETDATE i GETUTCDATE zwracają bieżącą datę i godzinę bez przesunięcia strefy czasowej.

Zwracana wartość obu funkcji zależy od systemu operacyjnego komputera, na którym działa wystąpienie programu SQL Server.

Zwracana wartość GETDATE reprezentuje aktualny czas w tej samej strefie czasowej, co system operacyjny. Zwracana wartość GETUTCDATE reprezentuje aktualny czas UTC.

Każda funkcja może być zawarta w klauzuli SELECT zapytania lub jako część wyrażenia logicznego w klauzuli WHERE .

Przykłady:

-- example query that selects the current time in both the server time zone and UTC
SELECT GETDATE() as SystemDateTime, GETUTCDATE() as UTCDateTime

-- example query records with EventDate in the past.
SELECT * FROM MyEvents WHERE EventDate < GETDATE() 

Istnieje kilka innych wbudowanych funkcji, które zwracają różne warianty bieżącej daty i godziny:

SELECT 
    GETDATE(),          --2016-07-21 14:27:37.447
    GETUTCDATE(),       --2016-07-21 18:27:37.447
    CURRENT_TIMESTAMP,  --2016-07-21 14:27:37.447
    SYSDATETIME(),      --2016-07-21 14:27:37.4485768
    SYSDATETIMEOFFSET(),--2016-07-21 14:27:37.4485768 -04:00
    SYSUTCDATETIME()    --2016-07-21 18:27:37.4485768

DATEADD do dodawania i odejmowania okresów

Ogólna składnia:

DATEADD (datepart , number , datetime_expr)  

Aby dodać miarę czasu, number musi być dodatnia. Aby odjąć miarę czasu, number musi być ujemna.

Przykłady

DECLARE @now DATETIME2 = GETDATE();
SELECT @now;                        --2016-07-21 14:39:46.4170000
SELECT DATEADD(YEAR, 1, @now)       --2017-07-21 14:39:46.4170000
SELECT DATEADD(QUARTER, 1, @now)    --2016-10-21 14:39:46.4170000
SELECT DATEADD(WEEK, 1, @now)       --2016-07-28 14:39:46.4170000
SELECT DATEADD(DAY, 1, @now)        --2016-07-22 14:39:46.4170000
SELECT DATEADD(HOUR, 1, @now)       --2016-07-21 15:39:46.4170000
SELECT DATEADD(MINUTE, 1, @now)     --2016-07-21 14:40:46.4170000
SELECT DATEADD(SECOND, 1, @now)     --2016-07-21 14:39:47.4170000
SELECT DATEADD(MILLISECOND, 1, @now)--2016-07-21 14:39:46.4180000

UWAGA: DATEADD akceptuje również skróty w parametrze datepart . Stosowanie tych skrótów jest ogólnie odradzane, ponieważ mogą być mylące ( m vs mi , ww vs w itp.).

Data części odniesienia

Oto wartości datepart dostępne dla funkcji daty i godziny:

UWAGA : Stosowanie skrótów jest ogólnie odradzane, ponieważ mogą być mylące ( m vs mi , ww vs w itp.). Długa wersja reprezentacji datepart promuje jasność i czytelność i powinna być używana w miarę możliwości ( month , minute , week , weekday itp.).

DATEDIFF do obliczania różnic okresów

Ogólna składnia:

DATEDIFF (datepart, datetime_expr1, datetime_expr2)

Zwróci liczbę dodatnią, jeśli datetime_expr jest w przeszłości względem datetime_expr2 , a w przeciwnym razie liczbę ujemną.

Przykłady

DECLARE @now DATETIME2 = GETDATE();
DECLARE @oneYearAgo DATETIME2 = DATEADD(YEAR, -1, @now);
SELECT @now                                    --2016-07-21 14:49:50.9800000
SELECT @oneYearAgo                             --2015-07-21 14:49:50.9800000
SELECT DATEDIFF(YEAR, @oneYearAgo, @now)       --1
SELECT DATEDIFF(QUARTER, @oneYearAgo, @now)    --4
SELECT DATEDIFF(WEEK, @oneYearAgo, @now)       --52
SELECT DATEDIFF(DAY, @oneYearAgo, @now)        --366
SELECT DATEDIFF(HOUR, @oneYearAgo, @now)       --8784
SELECT DATEDIFF(MINUTE, @oneYearAgo, @now)     --527040
SELECT DATEDIFF(SECOND, @oneYearAgo, @now)     --31622400

UWAGA: DATEDIFF akceptuje również skróty w parametrze datepart . Stosowanie tych skrótów jest ogólnie odradzane, ponieważ mogą być mylące ( m vs mi , ww vs w itp.).

DATEDIFF może również służyć do określania przesunięcia między czasem UTC a czasem lokalnym programu SQL Server. Poniższej instrukcji można użyć do obliczenia przesunięcia między czasem UTC a czasem lokalnym (w tym strefą czasową).

select  DATEDIFF(hh, getutcdate(), getdate()) as 'CentralTimeOffset'

DATEPART & DATENAME

DATEPART zwraca podaną część daty określonego wyrażenia datepart i datepart jako wartość liczbową.

DATENAME zwraca ciąg znaków, który reprezentuje określony datepart daty określonej daty. W praktyce DATENAME jest najbardziej przydatny do uzyskiwania nazwy miesiąca lub dnia tygodnia.

Istnieje również kilka skrótowych funkcji, aby uzyskać rok, miesiąc lub dzień wyrażenia DATEPART i DATEPART , które zachowują się jak DATEPART z odpowiednimi jednostkami datepart .

Składnia:

DATEPART ( datepart , datetime_expr )
DATENAME ( datepart , datetime_expr )
DAY ( datetime_expr )
MONTH ( datetime_expr )
YEAR ( datetime_expr )

Przykłady:

DECLARE @now DATETIME2 = GETDATE();
SELECT @now                       --2016-07-21 15:05:33.8370000
SELECT DATEPART(YEAR, @now)       --2016
SELECT DATEPART(QUARTER, @now)    --3
SELECT DATEPART(WEEK, @now)       --30
SELECT DATEPART(HOUR, @now)       --15
SELECT DATEPART(MINUTE, @now)     --5
SELECT DATEPART(SECOND, @now)     --33
-- Differences between DATEPART and DATENAME:
SELECT DATEPART(MONTH, @now)      --7
SELECT DATENAME(MONTH, @now)      --July
SELECT DATEPART(WEEKDAY, @now)    --5
SELECT DATENAME(WEEKDAY, @now)    --Thursday
--shorthand functions
SELECT DAY(@now)    --21
SELECT MONTH(@now)  --7
SELECT YEAR(@now)   --2016

UWAGA: DATEPART i DATENAME akceptują również skróty w parametrze datepart . Stosowanie tych skrótów jest ogólnie odradzane, ponieważ mogą być mylące ( m vs mi , ww vs w itp.).

Uzyskiwanie ostatniego dnia miesiąca

Korzystając z funkcji DATEADD i DATEDIFF , można zwrócić ostatnią datę miesiąca.

SELECT DATEADD(d, -1, DATEADD(m, DATEDIFF(m, 0, '2016-09-23') + 1, 0))
-- 2016-09-30 00:00:00.000

SELECT EOMONTH('2016-07-21')        --2016-07-31
SELECT EOMONTH('2016-07-21', 4)     --2016-11-30
SELECT EOMONTH('2016-07-21', -5)    --2016-02-29

Zwróć tylko datę z DateTime

Istnieje wiele sposobów zwracania daty z obiektu DateTime

1. SELECT CONVERT(Date, GETDATE())
2. SELECT DATEADD(dd, 0, DATEDIFF(dd, 0, GETDATE())) zwraca 21.07.2016 00: 00: 00.000
3. SELECT CAST(GETDATE() AS DATE)
4. SELECT CONVERT(CHAR(10),GETDATE(),111)
5. SELECT FORMAT(GETDATE(), 'yyyy-MM-dd')

Pamiętaj, że opcje 4 i 5 zwracają ciąg, a nie datę.

Utwórz funkcję, aby obliczyć wiek osoby w określonym dniu

Ta funkcja zajmie 2 parametry daty i godziny, DOB i datę sprawdzenia wieku

  CREATE FUNCTION [dbo].[Calc_Age]
    (
    @DOB datetime , @calcDate datetime 
    )
    RETURNS int
    AS
   BEGIN
declare @age int

IF (@calcDate < @DOB  )
RETURN -1

-- If a DOB is supplied after the comparison date, then return -1
SELECT @age = YEAR(@calcDate) - YEAR(@DOB) +
  CASE WHEN DATEADD(year,YEAR(@calcDate) - YEAR(@DOB)
  ,@DOB) > @calcDate THEN -1 ELSE 0 END
    

RETURN @age
    

END

np. aby sprawdzić dzisiejszy wiek osoby urodzonej 1 stycznia 2000 r

SELECT  dbo.Calc_Age('2000-01-01',Getdate())

PRZEDMIOT DATY PLATFORMY

 DECLARE @myDate DATE=DATEFROMPARTS(1988,11,28) 
 DECLARE @someMoment DATETIME=DATEFROMPARTS(1988,11,28,10,30,50,123)

Rozszerzony format daty