Microsoft SQL Server
Termine

Syntax

• EOMONTH ( start_date [, month_to_add])

Bemerkungen

Datums- und Uhrzeitformatierung mit CONVERT

Sie können die CONVERT-Funktion verwenden, um einen Datetime-Datentyp in eine formatierte Zeichenfolge umzuwandeln.

SELECT GETDATE() AS [Result] -- 2016-07-21 07:56:10.927

Sie können auch einige integrierte Codes verwenden, um in ein bestimmtes Format zu konvertieren. Hier sind die in SQL Server integrierten Optionen:

DECLARE @convert_code INT = 100 -- See Table Below
SELECT CONVERT(VARCHAR(30), GETDATE(), @convert_code) AS [Result]

SELECT GETDATE() AS [Result]                                -- 2016-07-21 07:56:10.927
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),100) AS [Result] -- Jul 21 2016  7:56AM
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),101) AS [Result] -- 07/21/2016
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),102) AS [Result] -- 2016.07.21
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),103) AS [Result] -- 21/07/2016
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),104) AS [Result] -- 21.07.2016
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),105) AS [Result] -- 21-07-2016
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),106) AS [Result] -- 21 Jul 2016
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),107) AS [Result] -- Jul 21, 2016
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),108) AS [Result] -- 07:57:05
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),109) AS [Result] -- Jul 21 2016  7:57:45:707AM
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),110) AS [Result] -- 07-21-2016
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),111) AS [Result] -- 2016/07/21
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),112) AS [Result] -- 20160721
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),113) AS [Result] -- 21 Jul 2016 07:57:59:553
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),114) AS [Result] -- 07:57:59:553
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),120) AS [Result] -- 2016-07-21 07:57:59
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),121) AS [Result] -- 2016-07-21 07:57:59.553
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),126) AS [Result] -- 2016-07-21T07:58:34.340
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),127) AS [Result] -- 2016-07-21T07:58:34.340
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),130) AS [Result] -- 16 ???? 1437  7:58:34:340AM
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),131) AS [Result] -- 16/10/1437  7:58:34:340AM

Datums- und Zeitformatierung mit FORMAT

DECLARE @Date DATETIME = '2016-09-05 00:01:02.333'

SELECT FORMAT(@Date, N'dddd, MMMM dd, yyyy hh:mm:ss tt')

DECLARE @Date DATETIME = '2016-09-05 00:01:02.333'

SELECT FORMAT(@Date, N'U')

DECLARE @Date DATETIME = '2016-09-05 00:01:02.333'

SELECT FORMAT(@Date, N'U', 'zh-cn')

Holen Sie sich die aktuelle DateTime

Die eingebauten Funktionen GETDATE und GETUTCDATE jeweils das aktuelle Datum und die aktuelle Uhrzeit ohne Zeitzonenversatz zurück.

Der Rückgabewert beider Funktionen basiert auf dem Betriebssystem des Computers, auf dem die Instanz von SQL Server ausgeführt wird.

Der Rückgabewert von GETDATE repräsentiert die aktuelle Uhrzeit in derselben Zeitzone wie das Betriebssystem. Der Rückgabewert von GETUTCDATE repräsentiert die aktuelle UTC-Zeit.

Jede Funktion kann in der SELECT Klausel einer Abfrage oder als Teil eines booleschen Ausdrucks in der WHERE Klausel enthalten sein.

Beispiele:

-- example query that selects the current time in both the server time zone and UTC
SELECT GETDATE() as SystemDateTime, GETUTCDATE() as UTCDateTime

-- example query records with EventDate in the past.
SELECT * FROM MyEvents WHERE EventDate < GETDATE() 

Es gibt ein paar andere integrierte Funktionen, die verschiedene Variationen des aktuellen Datums und der Uhrzeit anzeigen:

SELECT 
    GETDATE(),          --2016-07-21 14:27:37.447
    GETUTCDATE(),       --2016-07-21 18:27:37.447
    CURRENT_TIMESTAMP,  --2016-07-21 14:27:37.447
    SYSDATETIME(),      --2016-07-21 14:27:37.4485768
    SYSDATETIMEOFFSET(),--2016-07-21 14:27:37.4485768 -04:00
    SYSUTCDATETIME()    --2016-07-21 18:27:37.4485768

DATEADD zum Hinzufügen und Entfernen von Zeiträumen

Allgemeine Syntax:

DATEADD (datepart , number , datetime_expr)  

Um ein Zeitmaß hinzuzufügen, muss die number positiv sein. Um ein Zeitmaß abzuziehen, muss die number negativ sein.

Beispiele

DECLARE @now DATETIME2 = GETDATE();
SELECT @now;                        --2016-07-21 14:39:46.4170000
SELECT DATEADD(YEAR, 1, @now)       --2017-07-21 14:39:46.4170000
SELECT DATEADD(QUARTER, 1, @now)    --2016-10-21 14:39:46.4170000
SELECT DATEADD(WEEK, 1, @now)       --2016-07-28 14:39:46.4170000
SELECT DATEADD(DAY, 1, @now)        --2016-07-22 14:39:46.4170000
SELECT DATEADD(HOUR, 1, @now)       --2016-07-21 15:39:46.4170000
SELECT DATEADD(MINUTE, 1, @now)     --2016-07-21 14:40:46.4170000
SELECT DATEADD(SECOND, 1, @now)     --2016-07-21 14:39:47.4170000
SELECT DATEADD(MILLISECOND, 1, @now)--2016-07-21 14:39:46.4180000

DATEADD : DATEADD akzeptiert auch Abkürzungen im Parameter datepart . Die Verwendung dieser Abkürzungen wird im Allgemeinen nicht empfohlen, da sie verwirrend sein können ( m vs mi , ww vs w usw.).

Datum Teile Referenz

Dies sind die datepart , die für Datums- und datepart verfügbar sind:

HINWEIS : Die Verwendung von Abkürzungen wird im Allgemeinen nicht empfohlen, da sie verwirrend sein können ( m vs mi , ww vs w usw.). Die Langversion der datepart Darstellung datepart für Klarheit und Lesbarkeit und sollte nach Möglichkeit verwendet werden ( month , minute , week , weekday usw.).

DATEDIFF zur Berechnung von Zeitdifferenzen

Allgemeine Syntax:

DATEDIFF (datepart, datetime_expr1, datetime_expr2)

Es wird eine positive Zahl zurückgegeben, wenn datetime_expr relativ zu datetime_expr2 in der Vergangenheit datetime_expr2 , ansonsten eine negative Zahl.

Beispiele

DECLARE @now DATETIME2 = GETDATE();
DECLARE @oneYearAgo DATETIME2 = DATEADD(YEAR, -1, @now);
SELECT @now                                    --2016-07-21 14:49:50.9800000
SELECT @oneYearAgo                             --2015-07-21 14:49:50.9800000
SELECT DATEDIFF(YEAR, @oneYearAgo, @now)       --1
SELECT DATEDIFF(QUARTER, @oneYearAgo, @now)    --4
SELECT DATEDIFF(WEEK, @oneYearAgo, @now)       --52
SELECT DATEDIFF(DAY, @oneYearAgo, @now)        --366
SELECT DATEDIFF(HOUR, @oneYearAgo, @now)       --8784
SELECT DATEDIFF(MINUTE, @oneYearAgo, @now)     --527040
SELECT DATEDIFF(SECOND, @oneYearAgo, @now)     --31622400

DATEDIFF : DATEDIFF akzeptiert auch Abkürzungen im Parameter datepart . Die Verwendung dieser Abkürzungen wird im Allgemeinen nicht empfohlen, da sie verwirrend sein können ( m vs mi , ww vs w usw.).

DATEDIFF kann auch verwendet werden, um den Versatz zwischen UTC und der lokalen Zeit des SQL-Servers zu bestimmen. Mit der folgenden Anweisung kann der Versatz zwischen UTC und lokaler Zeit (einschließlich Zeitzone) berechnet werden.

select  DATEDIFF(hh, getutcdate(), getdate()) as 'CentralTimeOffset'

DATEPART & DATENAME

DATEPART gibt den angegebenen datepart des angegebenen Datetime-Ausdrucks als numerischen Wert zurück.

DATENAME gibt eine Zeichenfolge zurück, die den angegebenen datepart des angegebenen Datums darstellt. In der Praxis ist DATENAME meistens nützlich, um den Namen des Monats oder des Wochentags DATENAME .

Es gibt auch einige Abkürzungsfunktionen, um das Jahr, den Monat oder den Tag eines datetime-Ausdrucks abzurufen, die sich wie DATEPART mit ihren jeweiligen datepart Einheiten verhalten.

Syntax:

DATEPART ( datepart , datetime_expr )
DATENAME ( datepart , datetime_expr )
DAY ( datetime_expr )
MONTH ( datetime_expr )
YEAR ( datetime_expr )

Beispiele:

DECLARE @now DATETIME2 = GETDATE();
SELECT @now                       --2016-07-21 15:05:33.8370000
SELECT DATEPART(YEAR, @now)       --2016
SELECT DATEPART(QUARTER, @now)    --3
SELECT DATEPART(WEEK, @now)       --30
SELECT DATEPART(HOUR, @now)       --15
SELECT DATEPART(MINUTE, @now)     --5
SELECT DATEPART(SECOND, @now)     --33
-- Differences between DATEPART and DATENAME:
SELECT DATEPART(MONTH, @now)      --7
SELECT DATENAME(MONTH, @now)      --July
SELECT DATEPART(WEEKDAY, @now)    --5
SELECT DATENAME(WEEKDAY, @now)    --Thursday
--shorthand functions
SELECT DAY(@now)    --21
SELECT MONTH(@now)  --7
SELECT YEAR(@now)   --2016

DATEPART : DATEPART und DATENAME akzeptieren auch Abkürzungen im Parameter datepart . Die Verwendung dieser Abkürzungen wird im Allgemeinen nicht empfohlen, da sie verwirrend sein können ( m vs mi , ww vs w usw.).

Den letzten Tag eines Monats bekommen

Mit den Funktionen DATEADD und DATEDIFF kann das letzte Datum eines Monats zurückgegeben werden.

SELECT DATEADD(d, -1, DATEADD(m, DATEDIFF(m, 0, '2016-09-23') + 1, 0))
-- 2016-09-30 00:00:00.000

SELECT EOMONTH('2016-07-21')        --2016-07-31
SELECT EOMONTH('2016-07-21', 4)     --2016-11-30
SELECT EOMONTH('2016-07-21', -5)    --2016-02-29

Nur Datum aus einer DateTime zurückgeben

Es gibt viele Möglichkeiten, ein Date aus einem DateTime-Objekt zurückzugeben

1. SELECT CONVERT(Date, GETDATE())
2. SELECT DATEADD(dd, 0, DATEDIFF(dd, 0, GETDATE())) gibt 2016-07-21 00: 00: 00.000 zurück
3. SELECT CAST(GETDATE() AS DATE)
4. SELECT CONVERT(CHAR(10),GETDATE(),111)
5. SELECT FORMAT(GETDATE(), 'yyyy-MM-dd')

Beachten Sie, dass die Optionen 4 und 5 eine Zeichenfolge und kein Datum zurückgeben.

Funktion erstellen, um das Alter einer Person an einem bestimmten Datum zu berechnen

Diese Funktion benötigt zwei datetime-Parameter, das DOB und ein Datum, um das Alter bei zu überprüfen

  CREATE FUNCTION [dbo].[Calc_Age]
    (
    @DOB datetime , @calcDate datetime 
    )
    RETURNS int
    AS
   BEGIN
declare @age int

IF (@calcDate < @DOB  )
RETURN -1

-- If a DOB is supplied after the comparison date, then return -1
SELECT @age = YEAR(@calcDate) - YEAR(@DOB) +
  CASE WHEN DATEADD(year,YEAR(@calcDate) - YEAR(@DOB)
  ,@DOB) > @calcDate THEN -1 ELSE 0 END
    

RETURN @age
    

END

B. um das Alter einer am 01.01.2000 geborenen Person zu überprüfen

SELECT  dbo.Calc_Age('2000-01-01',Getdate())

CROSS PLATFORM DATE OBJECT

 DECLARE @myDate DATE=DATEFROMPARTS(1988,11,28) 
 DECLARE @someMoment DATETIME=DATEFROMPARTS(1988,11,28,10,30,50,123)

Datumsformat erweitert