Microsoft SQL Server
data

Syntaxis

• EOMONTH ( startdatum [, month_to_add])

Opmerkingen

Datum- en tijdnotatie met CONVERT

U kunt de CONVERT-functie gebruiken om een datetime-gegevenstype naar een opgemaakte tekenreeks te casten.

SELECT GETDATE() AS [Result] -- 2016-07-21 07:56:10.927

U kunt ook enkele ingebouwde codes gebruiken om te converteren naar een specifiek formaat. Hier zijn de opties ingebouwd in SQL Server:

DECLARE @convert_code INT = 100 -- See Table Below
SELECT CONVERT(VARCHAR(30), GETDATE(), @convert_code) AS [Result]

SELECT GETDATE() AS [Result]                                -- 2016-07-21 07:56:10.927
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),100) AS [Result] -- Jul 21 2016  7:56AM
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),101) AS [Result] -- 07/21/2016
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),102) AS [Result] -- 2016.07.21
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),103) AS [Result] -- 21/07/2016
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),104) AS [Result] -- 21.07.2016
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),105) AS [Result] -- 21-07-2016
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),106) AS [Result] -- 21 Jul 2016
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),107) AS [Result] -- Jul 21, 2016
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),108) AS [Result] -- 07:57:05
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),109) AS [Result] -- Jul 21 2016  7:57:45:707AM
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),110) AS [Result] -- 07-21-2016
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),111) AS [Result] -- 2016/07/21
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),112) AS [Result] -- 20160721
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),113) AS [Result] -- 21 Jul 2016 07:57:59:553
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),114) AS [Result] -- 07:57:59:553
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),120) AS [Result] -- 2016-07-21 07:57:59
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),121) AS [Result] -- 2016-07-21 07:57:59.553
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),126) AS [Result] -- 2016-07-21T07:58:34.340
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),127) AS [Result] -- 2016-07-21T07:58:34.340
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),130) AS [Result] -- 16 ???? 1437  7:58:34:340AM
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),131) AS [Result] -- 16/10/1437  7:58:34:340AM

Datum- en tijdnotatie met FORMAT

DECLARE @Date DATETIME = '2016-09-05 00:01:02.333'

SELECT FORMAT(@Date, N'dddd, MMMM dd, yyyy hh:mm:ss tt')

DECLARE @Date DATETIME = '2016-09-05 00:01:02.333'

SELECT FORMAT(@Date, N'U')

DECLARE @Date DATETIME = '2016-09-05 00:01:02.333'

SELECT FORMAT(@Date, N'U', 'zh-cn')

Download de huidige DateTime

De ingebouwde functies GETDATE en GETUTCDATE elk de huidige datum en tijd zonder tijdzone-offset.

De retourwaarde van beide functies is gebaseerd op het besturingssysteem van de computer waarop het exemplaar van SQL Server wordt uitgevoerd.

De retourwaarde van GETDATE vertegenwoordigt de huidige tijd in dezelfde tijdzone als het besturingssysteem. De retourwaarde van GETUTCDATE vertegenwoordigt de huidige UTC-tijd.

Beide functies kunnen worden opgenomen in de SELECT component van een query of als onderdeel van de Booleaanse expressie in de WHERE component.

Voorbeelden:

-- example query that selects the current time in both the server time zone and UTC
SELECT GETDATE() as SystemDateTime, GETUTCDATE() as UTCDateTime

-- example query records with EventDate in the past.
SELECT * FROM MyEvents WHERE EventDate < GETDATE() 

Er zijn een paar andere ingebouwde functies die verschillende variaties van de huidige datum-tijd teruggeven:

SELECT 
    GETDATE(),          --2016-07-21 14:27:37.447
    GETUTCDATE(),       --2016-07-21 18:27:37.447
    CURRENT_TIMESTAMP,  --2016-07-21 14:27:37.447
    SYSDATETIME(),      --2016-07-21 14:27:37.4485768
    SYSDATETIMEOFFSET(),--2016-07-21 14:27:37.4485768 -04:00
    SYSUTCDATETIME()    --2016-07-21 18:27:37.4485768

DATEADD voor het optellen en aftrekken van tijdsperioden

Algemene syntaxis:

DATEADD (datepart , number , datetime_expr)  

Om een tijdmaat toe te voegen, moet het number positief zijn. Om een tijdmaat af te trekken, moet het number negatief zijn.

Voorbeelden

DECLARE @now DATETIME2 = GETDATE();
SELECT @now;                        --2016-07-21 14:39:46.4170000
SELECT DATEADD(YEAR, 1, @now)       --2017-07-21 14:39:46.4170000
SELECT DATEADD(QUARTER, 1, @now)    --2016-10-21 14:39:46.4170000
SELECT DATEADD(WEEK, 1, @now)       --2016-07-28 14:39:46.4170000
SELECT DATEADD(DAY, 1, @now)        --2016-07-22 14:39:46.4170000
SELECT DATEADD(HOUR, 1, @now)       --2016-07-21 15:39:46.4170000
SELECT DATEADD(MINUTE, 1, @now)     --2016-07-21 14:40:46.4170000
SELECT DATEADD(SECOND, 1, @now)     --2016-07-21 14:39:47.4170000
SELECT DATEADD(MILLISECOND, 1, @now)--2016-07-21 14:39:46.4180000

OPMERKING: DATEADD accepteert ook afkortingen in de parameter datepart . Het gebruik van deze afkortingen wordt over het algemeen afgeraden omdat ze verwarrend kunnen zijn ( m vs mi , ww vs w , etc.).

Datum onderdelen referentie

Dit zijn de waarden van het datepart die beschikbaar zijn voor datum- en tijdfuncties:

OPMERKING : het gebruik van afkortingen wordt over het algemeen afgeraden omdat ze verwarrend kunnen zijn ( m vs mi , ww vs w , etc.). De lange versie van de weergave van datepart bevordert de duidelijkheid en leesbaarheid en moet waar mogelijk worden gebruikt ( month , minute , week , weekday , enz.).

DATEDIFF voor het berekenen van verschillen in tijdsperiode

Algemene syntaxis:

DATEDIFF (datepart, datetime_expr1, datetime_expr2)

Het retourneert een positief getal als datetime_expr in het verleden is ten opzichte van datetime_expr2 , en anders een negatief getal.

Voorbeelden

DECLARE @now DATETIME2 = GETDATE();
DECLARE @oneYearAgo DATETIME2 = DATEADD(YEAR, -1, @now);
SELECT @now                                    --2016-07-21 14:49:50.9800000
SELECT @oneYearAgo                             --2015-07-21 14:49:50.9800000
SELECT DATEDIFF(YEAR, @oneYearAgo, @now)       --1
SELECT DATEDIFF(QUARTER, @oneYearAgo, @now)    --4
SELECT DATEDIFF(WEEK, @oneYearAgo, @now)       --52
SELECT DATEDIFF(DAY, @oneYearAgo, @now)        --366
SELECT DATEDIFF(HOUR, @oneYearAgo, @now)       --8784
SELECT DATEDIFF(MINUTE, @oneYearAgo, @now)     --527040
SELECT DATEDIFF(SECOND, @oneYearAgo, @now)     --31622400

OPMERKING: DATEDIFF accepteert ook afkortingen in de parameter datepart . Het gebruik van deze afkortingen wordt over het algemeen afgeraden omdat ze verwarrend kunnen zijn ( m vs mi , ww vs w , etc.).

DATEDIFF kan ook worden gebruikt om de offset tussen UTC en de lokale tijd van de SQL Server te bepalen. De volgende instructie kan worden gebruikt om de offset tussen UTC en lokale tijd (inclusief tijdzone) te berekenen.

select  DATEDIFF(hh, getutcdate(), getdate()) as 'CentralTimeOffset'

DATEPART & DATENAME

DATEPART retourneert het opgegeven datepart van de opgegeven datetime-expressie als een numerieke waarde.

DATENAME retourneert een tekenreeks die het opgegeven datepart van de opgegeven datum vertegenwoordigt. In de praktijk is DATENAME vooral handig om de naam van de maand of de dag van de week te DATENAME .

Er zijn ook enkele steno-functies om het jaar, de maand of de dag van een datetime-expressie te krijgen, die zich gedragen als DATEPART met hun respectieve datepart eenheden.

Syntaxis:

DATEPART ( datepart , datetime_expr )
DATENAME ( datepart , datetime_expr )
DAY ( datetime_expr )
MONTH ( datetime_expr )
YEAR ( datetime_expr )

Voorbeelden:

DECLARE @now DATETIME2 = GETDATE();
SELECT @now                       --2016-07-21 15:05:33.8370000
SELECT DATEPART(YEAR, @now)       --2016
SELECT DATEPART(QUARTER, @now)    --3
SELECT DATEPART(WEEK, @now)       --30
SELECT DATEPART(HOUR, @now)       --15
SELECT DATEPART(MINUTE, @now)     --5
SELECT DATEPART(SECOND, @now)     --33
-- Differences between DATEPART and DATENAME:
SELECT DATEPART(MONTH, @now)      --7
SELECT DATENAME(MONTH, @now)      --July
SELECT DATEPART(WEEKDAY, @now)    --5
SELECT DATENAME(WEEKDAY, @now)    --Thursday
--shorthand functions
SELECT DAY(@now)    --21
SELECT MONTH(@now)  --7
SELECT YEAR(@now)   --2016

OPMERKING: DATEPART en DATENAME accepteren ook afkortingen in de parameter datepart . Het gebruik van deze afkortingen wordt over het algemeen afgeraden omdat ze verwarrend kunnen zijn ( m vs mi , ww vs w , etc.).

De laatste dag van een maand krijgen

Met de functies DATEADD en DATEDIFF is het mogelijk om de laatste datum van een maand te retourneren.

SELECT DATEADD(d, -1, DATEADD(m, DATEDIFF(m, 0, '2016-09-23') + 1, 0))
-- 2016-09-30 00:00:00.000

SELECT EOMONTH('2016-07-21')        --2016-07-31
SELECT EOMONTH('2016-07-21', 4)     --2016-11-30
SELECT EOMONTH('2016-07-21', -5)    --2016-02-29

Retourneer alleen Datum van een datum / tijd

Er zijn veel manieren om een datum uit een DateTime-object te retourneren

1. SELECT CONVERT(Date, GETDATE())
2. SELECT DATEADD(dd, 0, DATEDIFF(dd, 0, GETDATE())) retourneert 2016-07-21 00: 00: 00.000
3. SELECT CAST(GETDATE() AS DATE)
4. SELECT CONVERT(CHAR(10),GETDATE(),111)
5. SELECT FORMAT(GETDATE(), 'yyyy-MM-dd')

Merk op dat opties 4 en 5 een tekenreeks retourneren, geen datum.

Maak een functie om de leeftijd van een persoon op een specifieke datum te berekenen

Voor deze functie zijn 2 datetime-parameters, de DOB en een datum nodig om de leeftijd te controleren

  CREATE FUNCTION [dbo].[Calc_Age]
    (
    @DOB datetime , @calcDate datetime 
    )
    RETURNS int
    AS
   BEGIN
declare @age int

IF (@calcDate < @DOB  )
RETURN -1

-- If a DOB is supplied after the comparison date, then return -1
SELECT @age = YEAR(@calcDate) - YEAR(@DOB) +
  CASE WHEN DATEADD(year,YEAR(@calcDate) - YEAR(@DOB)
  ,@DOB) > @calcDate THEN -1 ELSE 0 END
    

RETURN @age
    

END

bijv. om vandaag de leeftijd te controleren van iemand geboren op 1/1/2000

SELECT  dbo.Calc_Age('2000-01-01',Getdate())

DATUMOVERZICHT VAN CROSS-PLATFORM

 DECLARE @myDate DATE=DATEFROMPARTS(1988,11,28) 
 DECLARE @someMoment DATETIME=DATEFROMPARTS(1988,11,28,10,30,50,123)

Datumnotatie verlengd