ActionScript 3
Trabajando con fecha y hora

Ante meridiem (AM) o Post meridiem (PM) para un reloj de 12 horas

function meridiem(d:Date):String {
    return (d.hours > 11) ? "pm" : "am";
}

Número de días en el mes especificado.

/**
 * @param year   Full year as int (ex: 2000).
 * @param month  Month as int, zero-based (ex: 0=January, 11=December).
 */
function daysInMonth(year:int, month:int):int {
    return (new Date(year, ++month, 0)).date;
}

Si el año especificado es año bisiesto

function isLeapYear(year:int):Boolean {
    return daysInMonth(year, 1) == 29;
}

Si se observa el horario de verano.

function isDaylightSavings(d:Date):Boolean {
    var months:uint = 12;
    var offset:uint = d.timezoneOffset;
    var offsetCheck:Number;

    while (months--) {
        offsetCheck = (new Date(d.getFullYear(), months, 1)).timezoneOffset;

        if (offsetCheck != offset)
            return (offsetCheck > offset);
    }

    return false;
}

Fecha de inicio de hoy, a medianoche.

function today(date:Date = null):Date {
    if (date == null)
        date = new Date();

    return new Date(date.fullYear, date.month, date.date, 0, 0, 0, 0);
}