Sök…


Naturligt sammanställt lagrat förfarande

I en procedur med naturlig kompilering kompileras T-SQL-kod till dll och körs som inbyggd C-kod. För att skapa en infödd lagrad procedur måste du:

  • Använd syntax för CREATE PROCEDURE
  • Ställ in alternativet NATIVE_COMPILATION i lagrad procedurdefinition
  • Använd SCHEMABINDING-alternativet i lagrad procedurdefinition
  • Definiera EXECUTE AS OWNER-alternativet i lagrad procedurdefinition

Istället för standard BEGIN END-block måste du använda BEGIN ATOMIC-block:

BEGIN ATOMIC
   WITH (TRANSACTION ISOLATION LEVEL=SNAPSHOT, LANGUAGE='us_english')
   -- T-Sql code goes here
END

Exempel:

CREATE PROCEDURE usp_LoadMemOptTable (@maxRows INT, @FullName NVARCHAR(200))
WITH
    NATIVE_COMPILATION, 
    SCHEMABINDING, 
    EXECUTE AS OWNER
AS
BEGIN ATOMIC
WITH (TRANSACTION ISOLATION LEVEL=SNAPSHOT, LANGUAGE='us_english')
    DECLARE @i INT = 1
    WHILE @i <= @maxRows
    BEGIN
        INSERT INTO dbo.MemOptTable3 VALUES(@i, @FullName, GETDATE())
        SET @i = @i+1
    END
END
GO

Nativt kompilerad skalfunktion

Kod i nativt kompilerad funktion omvandlas till C-kod och kompileras som dll. För att skapa en Native Compiled skalfunktion måste du:

  • Använd standard CREATE FUNCTION-syntax
  • Ställ in alternativet NATIVE_COMPILATION i funktionsdefinition
  • Använd SCHEMABINDING-alternativet i funktionsdefinition

Istället för standard BEGIN END-block måste du använda BEGIN ATOMIC-block:

BEGIN ATOMIC
   WITH (TRANSACTION ISOLATION LEVEL=SNAPSHOT, LANGUAGE='us_english')
   -- T-Sql code goes here
END

Exempel:

CREATE FUNCTION [dbo].[udfMultiply]( @v1 int, @v2 int )   
RETURNS bigint 
WITH NATIVE_COMPILATION, SCHEMABINDING  
AS   
BEGIN ATOMIC WITH (TRANSACTION ISOLATION LEVEL = SNAPSHOT, LANGUAGE = N'English')  
  
    DECLARE @ReturnValue bigint;  
    SET @ReturnValue = @v1 * @v2;         
  
    RETURN (@ReturnValue);    
END 

-- usage sample:
SELECT dbo.udfMultiply(10, 12)

Native inline tabellvärde funktion

Native compiled tabellvärdesfunktion returnerar tabellen som resultat. Kod i nativt kompilerad funktion omvandlas till C-kod och kompileras som dll. Endast inline-tabellvärderade funktioner stöds i version 2016. För att skapa en inbyggd tabellvärdesfunktion måste du:

  • Använd standard CREATE FUNCTION-syntax
  • Ställ in alternativet NATIVE_COMPILATION i funktionsdefinition
  • Använd SCHEMABINDING-alternativet i funktionsdefinition

Istället för standard BEGIN END-block måste du använda BEGIN ATOMIC-block:

BEGIN ATOMIC
   WITH (TRANSACTION ISOLATION LEVEL=SNAPSHOT, LANGUAGE='us_english')
   -- T-Sql code goes here
END

Exempel:

CREATE FUNCTION [dbo].[udft_NativeGetBusinessDoc]
(
   @RunDate VARCHAR(25)
)
RETURNS TABLE
WITH SCHEMABINDING,
     NATIVE_COMPILATION
AS
     RETURN
(
    SELECT BusinessDocNo,
           ProductCode,
           UnitID,               
           ReasonID,
           PriceID,
           RunDate,
           ReturnPercent,
           Qty,
           RewardAmount,
           ModifyDate,
           UserID
    FROM dbo.[BusinessDocDetail_11]
    WHERE RunDate >= @RunDate
);


Modified text is an extract of the original Stack Overflow Documentation
Licensierat under CC BY-SA 3.0
Inte anslutet till Stack Overflow