ActionScript 3
दिनांक और समय के साथ काम करना

12 घंटे की घड़ी के लिए एंट मेरिडेम (एएम) या पोस्ट मेरिडिएम (पीएम)

function meridiem(d:Date):String {
    return (d.hours > 11) ? "pm" : "am";
}

निर्दिष्ट महीने में दिनों की संख्या

/**
 * @param year   Full year as int (ex: 2000).
 * @param month  Month as int, zero-based (ex: 0=January, 11=December).
 */
function daysInMonth(year:int, month:int):int {
    return (new Date(year, ++month, 0)).date;
}

चाहे निर्दिष्ट वर्ष लीप वर्ष हो

function isLeapYear(year:int):Boolean {
    return daysInMonth(year, 1) == 29;
}

वर्तमान में डेलाइट बचत का समय देखा गया है या नहीं

function isDaylightSavings(d:Date):Boolean {
    var months:uint = 12;
    var offset:uint = d.timezoneOffset;
    var offsetCheck:Number;

    while (months--) {
        offsetCheck = (new Date(d.getFullYear(), months, 1)).timezoneOffset;

        if (offsetCheck != offset)
            return (offsetCheck > offset);
    }

    return false;
}

आज की शुरुआत की तारीख, आधी रात को

function today(date:Date = null):Date {
    if (date == null)
        date = new Date();

    return new Date(date.fullYear, date.month, date.date, 0, 0, 0, 0);
}