ActionScript 3
ज्यामिति के साथ काम करना

दो बिंदुओं के बीच का कोण प्राप्त करना

वेनिला गणित का उपयोग करना:

var from:Point = new Point(100, 50);
var to:Point = new Point(80, 95);

var angle:Number = Math.atan2(to.y - from.y, to.x - from.x);

पहले दो के बीच अंतर का प्रतिनिधित्व करने वाले एक नए वेक्टर का उपयोग करना:

var difference:Point = to.subtract(from);

var angle:Number = Math.atan2(difference.y, difference.x);

नोट: atan2() रिटर्न रेडियंस, डिग्री नहीं।

दो बिंदुओं के बीच की दूरी प्राप्त करना

वेनिला गणित का उपयोग करना:

var from:Point = new Point(300, 10);
var to:Point = new Point(75, 40);

var a:Number = to.x - from.x;
var b:Number = to.y - from.y;

var distance:Number = Math.sqrt(a * a + b * b);

Point की इनबिल्ट कार्यक्षमता का उपयोग करना:

var distance:Number = to.subtract(from).length; // or
var distance:Number = Point.distance(to, from);

रेडियन को डिग्री में परिवर्तित करना

var degrees:Number = radians * 180 / Math.PI;

रेडियन को डिग्री परिवर्तित करना

var radians:Number = degrees / 180 * Math.PI;

डिग्री और रेडियन में एक सर्कल का मूल्य

• एक संपूर्ण सर्कल 360 डिग्री या Math.PI * 2 रेडियन।
• उन मानों का आधा भाग 180 डिग्री या Math.PI पी। आई। रेडियन का है।
• एक चौथाई तो 90 डिग्री या Math.PI / 2 रेडियन है।

रेडियन में एक पूरे वृत्त के प्रतिशत के रूप में एक खंड प्राप्त करने के लिए:

function getSegment(percent:Number):Number {
    return Math.PI * 2 * percent;
}

var tenth:Number = getSegment(0.1); // One tenth of a circle in radians.

एक बिंदु को एक कोण पर ले जाना

मान लें कि आपके पास वह कोण है जिसे आप स्थानांतरित करना चाहते हैं और x और y मानों के साथ एक ऑब्जेक्ट जिसे आप स्थानांतरित करना चाहते हैं:

var position:Point = new Point(10, 10);
var angle:Number = 1.25;

आप Math.cos साथ x अक्ष के साथ जा सकते हैं:

position.x += Math.cos(angle);

और Math.sin साथ y अक्ष।

position.y += Math.sin(angle);

आप निश्चित रूप से Math.cos और Math.sin के परिणाम को उस दूरी से गुणा कर सकते हैं जो आप यात्रा करना चाहते हैं:

var distance:int = 20;

position.x += Math.cos(angle) * distance;
position.y += Math.sin(angle) * distance;

नोट: इनपुट कोण रेडियन में होना चाहिए।

निर्धारित करें कि एक बिंदु एक आयत क्षेत्र के अंदर है

आप यह जांच सकते हैं कि क्या आयत Rectangle.containsPoint() का उपयोग कर एक आयत के अंदर है:

var point:Point = new Point(5, 5);
var rectangle:Rectangle = new Rectangle(0, 0, 10, 10);

var contains:Boolean = rectangle.containsPoint(point); // true