ActionScript 3
Travailler avec la date et l'heure

Ante meridiem (AM) ou Post meridiem (PM) pour une horloge de 12 heures

function meridiem(d:Date):String {
    return (d.hours > 11) ? "pm" : "am";
}

Nombre de jours dans le mois spécifié

/**
 * @param year   Full year as int (ex: 2000).
 * @param month  Month as int, zero-based (ex: 0=January, 11=December).
 */
function daysInMonth(year:int, month:int):int {
    return (new Date(year, ++month, 0)).date;
}

Si l'année spécifiée est l'année bissextile

function isLeapYear(year:int):Boolean {
    return daysInMonth(year, 1) == 29;
}

Si l'heure d'été est actuellement observée

function isDaylightSavings(d:Date):Boolean {
    var months:uint = 12;
    var offset:uint = d.timezoneOffset;
    var offsetCheck:Number;

    while (months--) {
        offsetCheck = (new Date(d.getFullYear(), months, 1)).timezoneOffset;

        if (offsetCheck != offset)
            return (offsetCheck > offset);
    }

    return false;
}

Date de début du jour à minuit

function today(date:Date = null):Date {
    if (date == null)
        date = new Date();

    return new Date(date.fullYear, date.month, date.date, 0, 0, 0, 0);
}