ActionScript 3
Работа с датой и временем

Ante meridiem (AM) или Post meridiem (PM) для 12-часовых часов

function meridiem(d:Date):String {
    return (d.hours > 11) ? "pm" : "am";
}

Количество дней в указанном месяце

/**
 * @param year   Full year as int (ex: 2000).
 * @param month  Month as int, zero-based (ex: 0=January, 11=December).
 */
function daysInMonth(year:int, month:int):int {
    return (new Date(year, ++month, 0)).date;
}

Является ли указанный год високосным годом

function isLeapYear(year:int):Boolean {
    return daysInMonth(year, 1) == 29;
}

Независимо от того, соблюдается ли сейчас летнее время

function isDaylightSavings(d:Date):Boolean {
    var months:uint = 12;
    var offset:uint = d.timezoneOffset;
    var offsetCheck:Number;

    while (months--) {
        offsetCheck = (new Date(d.getFullYear(), months, 1)).timezoneOffset;

        if (offsetCheck != offset)
            return (offsetCheck > offset);
    }

    return false;
}

Сегодняшняя дата начала, в полночь

function today(date:Date = null):Date {
    if (date == null)
        date = new Date();

    return new Date(date.fullYear, date.month, date.date, 0, 0, 0, 0);
}