ActionScript 3
Mit Datum und Uhrzeit arbeiten

Ante Meridiem (AM) oder Post Meridiem (PM) für 12-Stunden-Uhr

function meridiem(d:Date):String {
    return (d.hours > 11) ? "pm" : "am";
}

Anzahl der Tage im angegebenen Monat

/**
 * @param year   Full year as int (ex: 2000).
 * @param month  Month as int, zero-based (ex: 0=January, 11=December).
 */
function daysInMonth(year:int, month:int):int {
    return (new Date(year, ++month, 0)).date;
}

Gibt an, ob das angegebene Jahr Schaltjahr ist

function isLeapYear(year:int):Boolean {
    return daysInMonth(year, 1) == 29;
}

Ob aktuell Sommerzeit eingehalten wird

function isDaylightSavings(d:Date):Boolean {
    var months:uint = 12;
    var offset:uint = d.timezoneOffset;
    var offsetCheck:Number;

    while (months--) {
        offsetCheck = (new Date(d.getFullYear(), months, 1)).timezoneOffset;

        if (offsetCheck != offset)
            return (offsetCheck > offset);
    }

    return false;
}

Der heutige Start ist um Mitternacht

function today(date:Date = null):Date {
    if (date == null)
        date = new Date();

    return new Date(date.fullYear, date.month, date.date, 0, 0, 0, 0);
}