Microsoft SQL Server
날짜

통사론

• EOMONTH ( 시작일 [, month_to_add])

비고

CONVERT를 사용한 날짜 및 시간 형식 지정

CONVERT 함수를 사용하여 datetime 데이터 유형을 형식화 된 문자열로 변환 할 수 있습니다.

SELECT GETDATE() AS [Result] -- 2016-07-21 07:56:10.927

내장 코드를 사용하여 특정 형식으로 변환 할 수도 있습니다. SQL Server에 내장 된 옵션은 다음과 같습니다.

DECLARE @convert_code INT = 100 -- See Table Below
SELECT CONVERT(VARCHAR(30), GETDATE(), @convert_code) AS [Result]

SELECT GETDATE() AS [Result]                                -- 2016-07-21 07:56:10.927
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),100) AS [Result] -- Jul 21 2016  7:56AM
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),101) AS [Result] -- 07/21/2016
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),102) AS [Result] -- 2016.07.21
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),103) AS [Result] -- 21/07/2016
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),104) AS [Result] -- 21.07.2016
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),105) AS [Result] -- 21-07-2016
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),106) AS [Result] -- 21 Jul 2016
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),107) AS [Result] -- Jul 21, 2016
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),108) AS [Result] -- 07:57:05
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),109) AS [Result] -- Jul 21 2016  7:57:45:707AM
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),110) AS [Result] -- 07-21-2016
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),111) AS [Result] -- 2016/07/21
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),112) AS [Result] -- 20160721
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),113) AS [Result] -- 21 Jul 2016 07:57:59:553
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),114) AS [Result] -- 07:57:59:553
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),120) AS [Result] -- 2016-07-21 07:57:59
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),121) AS [Result] -- 2016-07-21 07:57:59.553
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),126) AS [Result] -- 2016-07-21T07:58:34.340
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),127) AS [Result] -- 2016-07-21T07:58:34.340
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),130) AS [Result] -- 16 ???? 1437  7:58:34:340AM
UNION SELECT CONVERT(VARCHAR(30),GETDATE(),131) AS [Result] -- 16/10/1437  7:58:34:340AM

FORMAT을 사용한 날짜 및 시간 형식 지정

DECLARE @Date DATETIME = '2016-09-05 00:01:02.333'

SELECT FORMAT(@Date, N'dddd, MMMM dd, yyyy hh:mm:ss tt')

DECLARE @Date DATETIME = '2016-09-05 00:01:02.333'

SELECT FORMAT(@Date, N'U')

DECLARE @Date DATETIME = '2016-09-05 00:01:02.333'

SELECT FORMAT(@Date, N'U', 'zh-cn')

현재 DateTime 가져 오기

기본 제공 함수 GETDATE 및 GETUTCDATE 각각 시간대 오프셋없이 현재 날짜 및 시간을 반환합니다.

두 함수의 반환 값은 SQL Server 인스턴스가 실행되는 컴퓨터의 운영 체제를 기반으로합니다.

GETDATE의 반환 값은 운영 체제와 동일한 시간대의 현재 시간을 나타냅니다. GETUTCDATE의 리턴 값은 현재 UTC 시간을 나타냅니다.

두 함수 모두 WHERE 절의 부울 식 또는 쿼리의 SELECT 절에 포함될 수 있습니다.

예 :

-- example query that selects the current time in both the server time zone and UTC
SELECT GETDATE() as SystemDateTime, GETUTCDATE() as UTCDateTime

-- example query records with EventDate in the past.
SELECT * FROM MyEvents WHERE EventDate < GETDATE() 

현재 날짜 - 시간의 다양한 변형을 반환하는 몇 가지 기본 제공 함수가 있습니다.

SELECT 
    GETDATE(),          --2016-07-21 14:27:37.447
    GETUTCDATE(),       --2016-07-21 18:27:37.447
    CURRENT_TIMESTAMP,  --2016-07-21 14:27:37.447
    SYSDATETIME(),      --2016-07-21 14:27:37.4485768
    SYSDATETIMEOFFSET(),--2016-07-21 14:27:37.4485768 -04:00
    SYSUTCDATETIME()    --2016-07-21 18:27:37.4485768

기간 추가 및 삭제를위한 DATEADD

일반 구문 :

DATEADD (datepart , number , datetime_expr)  

시간 측정 값을 추가하려면 number 가 양수 여야합니다. 시간 측정 값을 빼려면 number 가 음수 여야합니다.

예제들

DECLARE @now DATETIME2 = GETDATE();
SELECT @now;                        --2016-07-21 14:39:46.4170000
SELECT DATEADD(YEAR, 1, @now)       --2017-07-21 14:39:46.4170000
SELECT DATEADD(QUARTER, 1, @now)    --2016-10-21 14:39:46.4170000
SELECT DATEADD(WEEK, 1, @now)       --2016-07-28 14:39:46.4170000
SELECT DATEADD(DAY, 1, @now)        --2016-07-22 14:39:46.4170000
SELECT DATEADD(HOUR, 1, @now)       --2016-07-21 15:39:46.4170000
SELECT DATEADD(MINUTE, 1, @now)     --2016-07-21 14:40:46.4170000
SELECT DATEADD(SECOND, 1, @now)     --2016-07-21 14:39:47.4170000
SELECT DATEADD(MILLISECOND, 1, @now)--2016-07-21 14:39:46.4180000

참고 : DATEADD 는 datepart 매개 변수에도 약어를 사용할 datepart 있습니다. 이러한 약어의 사용은 일반적으로 혼란 스러울 수 있으므로 권장하지 않습니다 ( m vs mi , ww vs w 등).

날짜 부분 참조

날짜 및 시간 함수에서 사용할 수있는 datepart 값은 다음과 같습니다.

참고 : 약어의 사용은 일반적으로 혼란 스러울 수 있으므로 권장하지 않습니다 ( m vs mi , ww vs w 등). datepart 표현의 긴 버전은 명확성과 가독성을 datepart 가능할 때마다 사용되어야합니다 ( month , minute , week , weekday 등).

시간차 계산을위한 DATEDIFF

일반 구문 :

DATEDIFF (datepart, datetime_expr1, datetime_expr2)

경우는 양수를 반환합니다 datetime_expr 에 과거 상대에 datetime_expr2 , 그렇지 않으면 음수.

예제들

DECLARE @now DATETIME2 = GETDATE();
DECLARE @oneYearAgo DATETIME2 = DATEADD(YEAR, -1, @now);
SELECT @now                                    --2016-07-21 14:49:50.9800000
SELECT @oneYearAgo                             --2015-07-21 14:49:50.9800000
SELECT DATEDIFF(YEAR, @oneYearAgo, @now)       --1
SELECT DATEDIFF(QUARTER, @oneYearAgo, @now)    --4
SELECT DATEDIFF(WEEK, @oneYearAgo, @now)       --52
SELECT DATEDIFF(DAY, @oneYearAgo, @now)        --366
SELECT DATEDIFF(HOUR, @oneYearAgo, @now)       --8784
SELECT DATEDIFF(MINUTE, @oneYearAgo, @now)     --527040
SELECT DATEDIFF(SECOND, @oneYearAgo, @now)     --31622400

참고 : DATEDIFF 는 datepart 매개 변수에도 약어를 허용합니다. 이러한 약어의 사용은 일반적으로 혼란 스러울 수 있으므로 권장하지 않습니다 ( m vs mi , ww vs w 등).

DATEDIFF 는 또한 UTC와 SQL Server의 로컬 시간 사이의 오프셋을 결정하는 데 사용할 수 있습니다. 다음 문은 UTC와 로컬 시간 (시간대 포함) 사이의 오프셋을 계산하는 데 사용할 수 있습니다.

select  DATEDIFF(hh, getutcdate(), getdate()) as 'CentralTimeOffset'

데이터 시트 및 데이터베이스

DATEPART 는 지정된 datetime 표현식의 지정된 datepart 를 숫자 값으로 리턴합니다.

DATENAME 은 지정된 날짜의 지정된 datepart 를 나타내는 문자열을 리턴합니다. 실제로 DATENAME 은 주로 달이나 요일의 이름을 알아 DATENAME 유용합니다.

또한 datetime 표현식의 연, 월 또는 일을 얻기위한 몇 가지 단축 함수가 있는데, 이는 각각의 datepart 단위로 DATEPART 처럼 작동합니다.

통사론:

DATEPART ( datepart , datetime_expr )
DATENAME ( datepart , datetime_expr )
DAY ( datetime_expr )
MONTH ( datetime_expr )
YEAR ( datetime_expr )

예 :

DECLARE @now DATETIME2 = GETDATE();
SELECT @now                       --2016-07-21 15:05:33.8370000
SELECT DATEPART(YEAR, @now)       --2016
SELECT DATEPART(QUARTER, @now)    --3
SELECT DATEPART(WEEK, @now)       --30
SELECT DATEPART(HOUR, @now)       --15
SELECT DATEPART(MINUTE, @now)     --5
SELECT DATEPART(SECOND, @now)     --33
-- Differences between DATEPART and DATENAME:
SELECT DATEPART(MONTH, @now)      --7
SELECT DATENAME(MONTH, @now)      --July
SELECT DATEPART(WEEKDAY, @now)    --5
SELECT DATENAME(WEEKDAY, @now)    --Thursday
--shorthand functions
SELECT DAY(@now)    --21
SELECT MONTH(@now)  --7
SELECT YEAR(@now)   --2016

참고 : DATEPART 및 DATENAME 은 datepart 매개 변수에서도 약어를 허용합니다. 이러한 약어의 사용은 일반적으로 혼란 스러울 수 있으므로 권장하지 않습니다 ( m vs mi , ww vs w 등).

한 달의 마지막 날 구하기

DATEADD 및 DATEDIFF 함수를 사용하면 한 달의 마지막 날짜를 반환 할 수 있습니다.

SELECT DATEADD(d, -1, DATEADD(m, DATEDIFF(m, 0, '2016-09-23') + 1, 0))
-- 2016-09-30 00:00:00.000

SELECT EOMONTH('2016-07-21')        --2016-07-31
SELECT EOMONTH('2016-07-21', 4)     --2016-11-30
SELECT EOMONTH('2016-07-21', -5)    --2016-02-29

DateTime에서 날짜 만 반환

DateTime 객체에서 Date를 반환하는 방법은 여러 가지가 있습니다.

1. SELECT CONVERT(Date, GETDATE())
2. SELECT DATEADD(dd, 0, DATEDIFF(dd, 0, GETDATE())) 는 2016-07-21 00 : 00 : 00.000을 반환합니다.
3. SELECT CAST(GETDATE() AS DATE)
4. SELECT CONVERT(CHAR(10),GETDATE(),111)
5. SELECT FORMAT(GETDATE(), 'yyyy-MM-dd')

옵션 4와 5는 날짜가 아닌 문자열을 반환합니다.

특정 날짜에 사람의 나이를 계산하는 함수 만들기

이 함수는 2 개의 datetime 매개 변수 인 DOB와 날짜를 확인하는 날짜를 취합니다.

  CREATE FUNCTION [dbo].[Calc_Age]
    (
    @DOB datetime , @calcDate datetime 
    )
    RETURNS int
    AS
   BEGIN
declare @age int

IF (@calcDate < @DOB  )
RETURN -1

-- If a DOB is supplied after the comparison date, then return -1
SELECT @age = YEAR(@calcDate) - YEAR(@DOB) +
  CASE WHEN DATEADD(year,YEAR(@calcDate) - YEAR(@DOB)
  ,@DOB) > @calcDate THEN -1 ELSE 0 END
    

RETURN @age
    

END

예 : 오늘 1/1/2000에 태어난 사람의 나이를 확인하십시오.

SELECT  dbo.Calc_Age('2000-01-01',Getdate())

CROSS 플랫폼 날짜 객체

 DECLARE @myDate DATE=DATEFROMPARTS(1988,11,28) 
 DECLARE @someMoment DATETIME=DATEFROMPARTS(1988,11,28,10,30,50,123)

날짜 형식 확장