Erlang Language
comportamiento gen_server

Observaciones

Servicio de Greeter

Aquí hay un ejemplo de un servicio que saluda a las personas por el nombre dado, y hace un seguimiento de cuántos usuarios se encontraron. Ver uso a continuación.

%% greeter.erl
%% Greets people and counts number of times it did so.
-module(greeter).
-behaviour(gen_server).
%% Export API Functions
-export([start_link/0, greet/1, get_count/0]).
%% Required gen server callbacks
-export([init/1, handle_call/3, handle_cast/2, handle_info/2, terminate/2, code_change/3]).

-record(state, {count::integer()}).

%% Public API
start_link() ->
    gen_server:start_link({local, ?MODULE}, ?MODULE, {}, []).

greet(Name) ->
    gen_server:cast(?MODULE, {greet, Name}).

get_count() ->
    gen_server:call(?MODULE, {get_count}).

%% Private
init({}) ->
    {ok, #state{count=0}}.

handle_cast({greet, Name}, #state{count = Count} = State) ->
    io:format("Greetings ~s!~n", [Name]),
    {noreply, State#state{count = Count + 1}};

handle_cast(Msg, State) ->
    error_logger:warning_msg("Bad message: ~p~n", [Msg]),
    {noreply, State}.

handle_call({get_count}, _From, State) ->
    {reply, {ok, State#state.count}, State};

handle_call(Request, _From, State) ->
    error_logger:warning_msg("Bad message: ~p~n", [Request]),
    {reply, {error, unknown_call}, State}.

%% Other gen_server callbacks
handle_info(Info, State) ->
    error_logger:warning_msg("Bad message: ~p~n", [Info]),
    {noreply, State}.

terminate(_Reason, _State) ->
    ok.

code_change(_OldVsn, State, _Extra) ->
    {ok, State}.

Aquí hay una muestra de uso de este servicio en el shell erlang:

1> c(greeter).
{ok,greeter}
2> greeter:start_link().
{ok,<0.62.0>}
3> greeter:greet("Andriy").
Greetings Andriy!
ok
4> greeter:greet("Mike").
Greetings Mike!
ok
5> greeter:get_count().
{ok,2}

Usando el comportamiento gen_server

Un gen_server es una máquina de estados finitos específica que funciona como un servidor. gen_server puede manejar diferentes tipos de eventos:

• solicitud síncrona con handle_call
• Solicitud asincrona con handle_cast
• otro mensaje (no definido en la especificación OTP) con handle_info

Los mensajes síncronos y asíncronos se especifican en OTP y son simples tuplas etiquetadas con cualquier tipo de datos.

Un gen_server simple se define así:

-module(simple_gen_server).
-behaviour(gen_server).
-export([start_link/0]).
-export([init/1, handle_call/3, handle_cast/2, handle_info/2,
         terminate/2, code_change/3]).

start_link() ->
    Return = gen_server:start_link({local, ?MODULE}, ?MODULE, [], []),
    io:format("start_link: ~p~n", [Return]),
    Return.

init([]) ->
    State = [],
    Return = {ok, State},
    io:format("init: ~p~n", [State]),
    Return.

handle_call(_Request, _From, State) ->
    Reply = ok,
    Return = {reply, Reply, State},
    io:format("handle_call: ~p~n", [Return]),
    Return.

handle_cast(_Msg, State) ->
    Return = {noreply, State},
    io:format("handle_cast: ~p~n", [Return]),
    Return.

handle_info(_Info, State) ->
    Return = {noreply, State},
    io:format("handle_info: ~p~n", [Return]),
    Return.

terminate(_Reason, _State) ->
    Return = ok,
    io:format("terminate: ~p~n", [Return]),
    ok.

code_change(_OldVsn, State, _Extra) ->
    Return = {ok, State},
    io:format("code_change: ~p~n", [Return]),
    Return.

Este código es simple: cada mensaje recibido se imprime en una salida estándar.

comportamiento gen_server

Para definir un gen_server , debe declararlo explícitamente en su código fuente con -behaviour(gen_server) . Tenga en cuenta que el behaviour puede escribirse en EE. UU. (Comportamiento) o Reino Unido (comportamiento).

start_link / 0

Esta función es un atajo simple para llamar a otra función: gen_server:start_link/3,4 .

start_link / 3,4

start_link() ->
    gen_server:start_link({local, ?MODULE}, ?MODULE, [], []).

Se llama a esta función cuando desea iniciar su servidor vinculado a un supervisor u otro proceso. start_link/3,4 puede registrar automáticamente su proceso (si cree que su proceso debe ser único) o simplemente puede generarlo como un proceso simple. Cuando se llama, esta función ejecuta init/1 .

Esta función puede devolver estos valores definidos:

• {ok,Pid}
• ignore
• {error,Error}

init / 1

init([]) ->
    State = [],
    {ok, State}.

init/1 es la primera función ejecutada cuando se iniciará su servidor. Este inicializa todos los requisitos previos de su aplicación y devuelve el estado al proceso recién creado.

Esta función puede devolver solo estos valores definidos:

• {ok,State}
• {ok,State,Timeout}
• {ok,State,hibernate}
• {stop,Reason}
• ignore

State variable de State puede ser todo (p. Ej., Lista, tupla, listas de distribución, mapa, registro) y permanecer accesible para todas las funciones dentro del proceso generado.

handle_call / 3

handle_call(_Request, _From, State) ->
    Reply = ok,
    {reply, Reply, State}.

gen_server:call/2 ejecuta esta devolución de llamada. El primer argumento es su mensaje ( _Request ), el segundo es el origen de la solicitud ( _From ) y el último es el estado actual ( State ) de su comportamiento gen_server en ejecución.

Si desea una respuesta a la persona que llama, handle_call/3 necesita devolver una de estas estructuras de datos:

• {reply,Reply,NewState}
• {reply,Reply,NewState,Timeout}
• {reply,Reply,NewState,hibernate}

Si no desea responder al llamante, handle_call/3 necesita devolver una de estas estructuras de datos:

• {noreply,NewState}
• {noreply,NewState,Timeout}
• {noreply,NewState,hibernate}

Si desea detener la ejecución actual de su gen_server actual, handle_call/3 necesita devolver una de estas estructuras de datos:

• {stop,Reason,Reply,NewState}
• {stop,Reason,NewState}

handle_cast / 2

handle_cast(_Msg, State) ->
    {noreply, State}.

gen_server:cast/2 ejecuta esta devolución de llamada. El primer argumento es su mensaje ( _Msg ), y el segundo es el estado actual de su comportamiento gen_server en ejecución.

De forma predeterminada, esta función no puede proporcionar datos a la persona que llama, por lo tanto, solo tiene dos opciones, continuar la ejecución actual:

• {noreply,NewState}
• {noreply,NewState,Timeout}
• {noreply,NewState,hibernate}

O gen_server proceso gen_server actual:

• {stop,Reason,NewState}

handle_info / 2

handle_info(_Info, State) ->
    {noreply, State}.

handle_info/2 se ejecuta cuando un mensaje OTP no estándar proviene del mundo exterior. Este no puede responder y, al igual que handle_cast/2 , solo puede realizar 2 acciones, continuando con la ejecución actual:

• {noreply,NewState}
• {noreply,NewState,Timeout}
• {noreply,NewState,hibernate}

O detenga el proceso gen_server ejecución actual:

• {stop,Reason,NewState}

terminar / 2

terminate(_Reason, _State) ->
    ok.

terminate/2 se llama cuando ocurre un error o cuando quiere cerrar su proceso gen_server .

code_change / 3

code_change(_OldVsn, State, _Extra) ->
    {ok, State}.

code_change/3 función code_change/3 cuando desea actualizar su código de ejecución.

Esta función puede devolver solo estos valores definidos:

• {ok, NewState}
• {error, Reason}

Iniciando este proceso

Puedes compilar tu código e iniciar simple_gen_server :

simple_gen_server:start_link().

Si desea enviar un mensaje a su servidor, puede usar estas funciones:

% will use handle_call as callback and print:
%   handle_call: mymessage
gen_server:call(simple_gen_server, mymessage).

% will use handle_cast as callback and print:
%   handle_cast: mymessage
gen_server:cast(simple_gen_server, mymessage).

% will use handle_info as callback and print:
%   handle_info: mymessage
erlang:send(whereis(simple_gen_server), mymessage).

Base de datos clave / valor simple

Este código fuente crea un servicio simple de almacenamiento de clave / valor basado en la estructura de datos de Erlang del map . En primer lugar, necesitamos definir toda la información relativa a nuestro gen_server :

-module(cache).
-behaviour(gen_server).

% our API
-export([start_link/0]).
-export([get/1, put/2, state/0, delete/1, stop/0]).

% our handlers
-export([init/1, handle_call/3, handle_cast/2, handle_info/2,
         terminate/2, code_change/3]).

% Defining our function to start `cache` process:

start_link() ->
    gen_server:start_link({local, ?MODULE}, ?MODULE, [], []).

%%%%%%%%%%%%%%
% API

% Key/Value database is a simple store, value indexed by an unique key. 
% This implementation is based on map, this datastructure is like hash 
# in Perl or dictionaries in Python. 

% put/2
% put a value indexed by a key. We assume the link is stable 
% and the data will be written, so, we use an asynchronous call with 
% gen_server:cast/2.

put(Key, Value) ->
    gen_server:cast(?MODULE, {put, {Key, Value}}).

% get/1
% take one argument, a key and will a return the value indexed 
% by this same key. We use a synchronous call with gen_server:call/2.

get(Key) ->
    gen_server:call(?MODULE, {get, Key}).

% delete/1 
% like `put/1`, we assume the data will be removed. So, we use an 
% asynchronous call with gen_server:cast/2.

delete(Key) ->
    gen_server:cast(?MODULE, {delete, Key}).

% state/0 
% This function will return the current state (here the map who contain all 
% indexed values), we need a synchronous call.

state() ->
    gen_server:call(?MODULE, {get_state}).

% stop/0
% This function stop cache server process.

stop() ->
    gen_server:stop(?MODULE).

%%%%%%%%%%%%%%%
% Handlers

% init/1
% Here init/1 will initialize state with simple empty map datastructure.

init([]) ->
    {ok, #{}}.

% handle_call/3
% Now, we need to define our handle. In a cache server we need to get our 
% value from a key, this feature need to be synchronous, so, using 
% handle_call seems a good choice:

handle_call({get, Key}, From, State) ->
    Response = maps:get(Key, State, undefined),
    {reply, Response, State};

% We need to check our current state, like get_fea

handle_call({get_state}, From, State) ->
    Response = {current_state, State},
    {reply, Response, State};

% All other messages will be dropped here.

handle_call(_Request, _From, State) ->
    Reply = ok,
    {reply, Reply, State}.

% handle_cast/2
% put/2 will execute this function.

handle_cast({put, {Key, Value}}, State) ->
    NewState = maps:put(Key, Value, State),
    {noreply, NewState};

% delete/1 will execute this function.

handle_cast({delete, Key}, State) ->
    NewState = maps:remove(Key, State),
    {noreply, NewState};

% All other messages are dropped here.

handle_cast(_Msg, State) ->
    {noreply, State}.

%%%%%%%%%%%%%%%%
% other handlers

% We don't need other features, other handlers do nothing.

handle_info(_Info, State) ->
    {noreply, State}.

terminate(_Reason, _State) ->
    ok.

code_change(_OldVsn, State, _Extra) ->
    {ok, State}.

Usando nuestro servidor de caché

Ahora podemos compilar nuestro código y comenzar a usarlo con erl .

% compile cache
c(cache).

% starting cache server
cache:start_link().

% get current store
% will return:
%   #{}
cache:state().

% put some data
cache:put(1, one).
cache:put(hello, bonjour).
cache:put(list, []).

% get current store
% will return:
%   #{1 => one,hello => bonjour,list => []}
cache:state().

% delete a value
cache:delete(1).
cache:state().
%   #{1 => one,hello => bonjour,list => []}

% stopping cache server
cache:stop().