Erlang Language
comportamento di gen_server

Osservazioni

Servizio di accoglienza

Ecco un esempio di un servizio che saluta le persone con il nome specificato e tiene traccia del numero di utenti che ha incontrato. Vedi l'utilizzo di seguito.

%% greeter.erl
%% Greets people and counts number of times it did so.
-module(greeter).
-behaviour(gen_server).
%% Export API Functions
-export([start_link/0, greet/1, get_count/0]).
%% Required gen server callbacks
-export([init/1, handle_call/3, handle_cast/2, handle_info/2, terminate/2, code_change/3]).

-record(state, {count::integer()}).

%% Public API
start_link() ->
    gen_server:start_link({local, ?MODULE}, ?MODULE, {}, []).

greet(Name) ->
    gen_server:cast(?MODULE, {greet, Name}).

get_count() ->
    gen_server:call(?MODULE, {get_count}).

%% Private
init({}) ->
    {ok, #state{count=0}}.

handle_cast({greet, Name}, #state{count = Count} = State) ->
    io:format("Greetings ~s!~n", [Name]),
    {noreply, State#state{count = Count + 1}};

handle_cast(Msg, State) ->
    error_logger:warning_msg("Bad message: ~p~n", [Msg]),
    {noreply, State}.

handle_call({get_count}, _From, State) ->
    {reply, {ok, State#state.count}, State};

handle_call(Request, _From, State) ->
    error_logger:warning_msg("Bad message: ~p~n", [Request]),
    {reply, {error, unknown_call}, State}.

%% Other gen_server callbacks
handle_info(Info, State) ->
    error_logger:warning_msg("Bad message: ~p~n", [Info]),
    {noreply, State}.

terminate(_Reason, _State) ->
    ok.

code_change(_OldVsn, State, _Extra) ->
    {ok, State}.

Ecco un esempio di utilizzo di questo servizio nella shell di erlang:

1> c(greeter).
{ok,greeter}
2> greeter:start_link().
{ok,<0.62.0>}
3> greeter:greet("Andriy").
Greetings Andriy!
ok
4> greeter:greet("Mike").
Greetings Mike!
ok
5> greeter:get_count().
{ok,2}

Utilizzando il comportamento di gen_server

Un gen_server è una macchina a stati finiti specifica che funziona come un server. gen_server può gestire diversi tipi di eventi:

• richiesta sincrona con handle_call
• richiesta asincrona con handle_cast
• altro messaggio (non definito nelle specifiche OTP) con handle_info

I messaggi sincroni e asincroni sono specificati in OTP e sono tuple con tag semplici con qualsiasi tipo di dati su di esso.

Un semplice gen_server è definito in questo modo:

-module(simple_gen_server).
-behaviour(gen_server).
-export([start_link/0]).
-export([init/1, handle_call/3, handle_cast/2, handle_info/2,
         terminate/2, code_change/3]).

start_link() ->
    Return = gen_server:start_link({local, ?MODULE}, ?MODULE, [], []),
    io:format("start_link: ~p~n", [Return]),
    Return.

init([]) ->
    State = [],
    Return = {ok, State},
    io:format("init: ~p~n", [State]),
    Return.

handle_call(_Request, _From, State) ->
    Reply = ok,
    Return = {reply, Reply, State},
    io:format("handle_call: ~p~n", [Return]),
    Return.

handle_cast(_Msg, State) ->
    Return = {noreply, State},
    io:format("handle_cast: ~p~n", [Return]),
    Return.

handle_info(_Info, State) ->
    Return = {noreply, State},
    io:format("handle_info: ~p~n", [Return]),
    Return.

terminate(_Reason, _State) ->
    Return = ok,
    io:format("terminate: ~p~n", [Return]),
    ok.

code_change(_OldVsn, State, _Extra) ->
    Return = {ok, State},
    io:format("code_change: ~p~n", [Return]),
    Return.

Questo codice è semplice: ogni messaggio ricevuto viene stampato sullo standard output.

comportamento di gen_server

Per definire un gen_server , è necessario dichiararlo esplicitamente nel codice sorgente con -behaviour(gen_server) . Nota, il behaviour può essere scritto negli USA (comportamento) o nel Regno Unito (comportamento).

start_link / 0

Questa funzione è una semplice scorciatoia per chiamare un'altra funzione: gen_server:start_link/3,4 .

start_link / 3,4

start_link() ->
    gen_server:start_link({local, ?MODULE}, ?MODULE, [], []).

Questa funzione viene chiamata quando si desidera avviare il server collegato a un supervisor oa un altro processo. start_link/3,4 può registrare automaticamente il tuo processo (se ritieni che il tuo processo debba essere unico) o può semplicemente generare come un semplice processo. Quando chiamato, questa funzione esegue init/1 .

Questa funzione può restituire questi valori di definizione:

• {ok,Pid}
• ignore
• {error,Error}

init / 1

init([]) ->
    State = [],
    {ok, State}.

init/1 è la prima funzione eseguita all'avvio del server. Questo inizializza tutti i prerequisiti dell'applicazione e restituisce lo stato al processo appena creato.

Questa funzione può restituire solo questi valori definiti:

• {ok,State}
• {ok,State,Timeout}
• {ok,State,hibernate}
• {stop,Reason}
• ignore

State variabile di State può essere tutto (ad es. Lista, tupla, proplists, map, record) e rimanere accessibile a tutte le funzioni all'interno del processo generato.

handle_call / 3

handle_call(_Request, _From, State) ->
    Reply = ok,
    {reply, Reply, State}.

gen_server:call/2 esegue questo callback. Il primo argomento è il tuo messaggio ( _Request ), il secondo è l'origine della richiesta ( _From ) e l'ultimo è lo stato corrente ( State ) del tuo comportamento in esecuzione gen_server.

Se vuoi una risposta al chiamante, handle_call/3 deve restituire una di queste strutture dati:

• {reply,Reply,NewState}
• {reply,Reply,NewState,Timeout}
• {reply,Reply,NewState,hibernate}

Se non si desidera rispondere al chiamante, handle_call/3 deve restituire una di queste strutture dati:

• {noreply,NewState}
• {noreply,NewState,Timeout}
• {noreply,NewState,hibernate}

Se vuoi interrompere l'attuale esecuzione del tuo attuale gen_server, handle_call/3 deve restituire una di queste strutture dati:

• {stop,Reason,Reply,NewState}
• {stop,Reason,NewState}

handle_cast / 2

handle_cast(_Msg, State) ->
    {noreply, State}.

gen_server:cast/2 esegue questo callback. Il primo argomento è il tuo messaggio ( _Msg ), e il secondo lo stato corrente del tuo comportamento in esecuzione gen_server.

Per impostazione predefinita, questa funzione non può fornire dati al chiamante, quindi, hai solo due scelte, continua l'esecuzione corrente:

• {noreply,NewState}
• {noreply,NewState,Timeout}
• {noreply,NewState,hibernate}

Oppure interrompi la tua attuale procedura gen_server :

• {stop,Reason,NewState}

handle_info / 2

handle_info(_Info, State) ->
    {noreply, State}.

handle_info/2 viene eseguito quando il messaggio OTP non standard proviene da un mondo esterno. Questo non può rispondere e, come handle_cast/2 può fare solo 2 azioni, continuando l'esecuzione corrente:

• {noreply,NewState}
• {noreply,NewState,Timeout}
• {noreply,NewState,hibernate}

Oppure interrompi il processo gen_server corrente:

• {stop,Reason,NewState}

interrompere / 2

terminate(_Reason, _State) ->
    ok.

terminate/2 viene chiamato quando si verifica un errore o quando si desidera gen_server processo gen_server .

code_change / 3

code_change(_OldVsn, State, _Extra) ->
    {ok, State}.

code_change/3 funzione code_change/3 viene chiamata quando si desidera aggiornare il codice in esecuzione.

Questa funzione può restituire solo questi valori definiti:

• {ok, NewState}
• {error, Reason}

Avvio di questo processo

Puoi compilare il tuo codice e avviare simple_gen_server :

simple_gen_server:start_link().

Se si desidera inviare un messaggio al server, è possibile utilizzare queste funzioni:

% will use handle_call as callback and print:
%   handle_call: mymessage
gen_server:call(simple_gen_server, mymessage).

% will use handle_cast as callback and print:
%   handle_cast: mymessage
gen_server:cast(simple_gen_server, mymessage).

% will use handle_info as callback and print:
%   handle_info: mymessage
erlang:send(whereis(simple_gen_server), mymessage).

Semplice database di chiavi / valori

Questo codice sorgente crea un semplice servizio di archiviazione chiavi / valore basato sulla struttura di dati di Erlang della map . In primo luogo, dobbiamo definire tutte le informazioni riguardanti il ​​nostro gen_server :

-module(cache).
-behaviour(gen_server).

% our API
-export([start_link/0]).
-export([get/1, put/2, state/0, delete/1, stop/0]).

% our handlers
-export([init/1, handle_call/3, handle_cast/2, handle_info/2,
         terminate/2, code_change/3]).

% Defining our function to start `cache` process:

start_link() ->
    gen_server:start_link({local, ?MODULE}, ?MODULE, [], []).

%%%%%%%%%%%%%%
% API

% Key/Value database is a simple store, value indexed by an unique key. 
% This implementation is based on map, this datastructure is like hash 
# in Perl or dictionaries in Python. 

% put/2
% put a value indexed by a key. We assume the link is stable 
% and the data will be written, so, we use an asynchronous call with 
% gen_server:cast/2.

put(Key, Value) ->
    gen_server:cast(?MODULE, {put, {Key, Value}}).

% get/1
% take one argument, a key and will a return the value indexed 
% by this same key. We use a synchronous call with gen_server:call/2.

get(Key) ->
    gen_server:call(?MODULE, {get, Key}).

% delete/1 
% like `put/1`, we assume the data will be removed. So, we use an 
% asynchronous call with gen_server:cast/2.

delete(Key) ->
    gen_server:cast(?MODULE, {delete, Key}).

% state/0 
% This function will return the current state (here the map who contain all 
% indexed values), we need a synchronous call.

state() ->
    gen_server:call(?MODULE, {get_state}).

% stop/0
% This function stop cache server process.

stop() ->
    gen_server:stop(?MODULE).

%%%%%%%%%%%%%%%
% Handlers

% init/1
% Here init/1 will initialize state with simple empty map datastructure.

init([]) ->
    {ok, #{}}.

% handle_call/3
% Now, we need to define our handle. In a cache server we need to get our 
% value from a key, this feature need to be synchronous, so, using 
% handle_call seems a good choice:

handle_call({get, Key}, From, State) ->
    Response = maps:get(Key, State, undefined),
    {reply, Response, State};

% We need to check our current state, like get_fea

handle_call({get_state}, From, State) ->
    Response = {current_state, State},
    {reply, Response, State};

% All other messages will be dropped here.

handle_call(_Request, _From, State) ->
    Reply = ok,
    {reply, Reply, State}.

% handle_cast/2
% put/2 will execute this function.

handle_cast({put, {Key, Value}}, State) ->
    NewState = maps:put(Key, Value, State),
    {noreply, NewState};

% delete/1 will execute this function.

handle_cast({delete, Key}, State) ->
    NewState = maps:remove(Key, State),
    {noreply, NewState};

% All other messages are dropped here.

handle_cast(_Msg, State) ->
    {noreply, State}.

%%%%%%%%%%%%%%%%
% other handlers

% We don't need other features, other handlers do nothing.

handle_info(_Info, State) ->
    {noreply, State}.

terminate(_Reason, _State) ->
    ok.

code_change(_OldVsn, State, _Extra) ->
    {ok, State}.

Usando il nostro server cache

Ora possiamo compilare il nostro codice e iniziare a usarlo con erl .

% compile cache
c(cache).

% starting cache server
cache:start_link().

% get current store
% will return:
%   #{}
cache:state().

% put some data
cache:put(1, one).
cache:put(hello, bonjour).
cache:put(list, []).

% get current store
% will return:
%   #{1 => one,hello => bonjour,list => []}
cache:state().

% delete a value
cache:delete(1).
cache:state().
%   #{1 => one,hello => bonjour,list => []}

% stopping cache server
cache:stop().