Erlang Language
gen_server gedrag

Opmerkingen

Greeter-service

Hier is een voorbeeld van een service die mensen begroet met de opgegeven naam en bijhoudt hoeveel gebruikers deze zijn tegengekomen. Zie gebruik hieronder.

%% greeter.erl
%% Greets people and counts number of times it did so.
-module(greeter).
-behaviour(gen_server).
%% Export API Functions
-export([start_link/0, greet/1, get_count/0]).
%% Required gen server callbacks
-export([init/1, handle_call/3, handle_cast/2, handle_info/2, terminate/2, code_change/3]).

-record(state, {count::integer()}).

%% Public API
start_link() ->
    gen_server:start_link({local, ?MODULE}, ?MODULE, {}, []).

greet(Name) ->
    gen_server:cast(?MODULE, {greet, Name}).

get_count() ->
    gen_server:call(?MODULE, {get_count}).

%% Private
init({}) ->
    {ok, #state{count=0}}.

handle_cast({greet, Name}, #state{count = Count} = State) ->
    io:format("Greetings ~s!~n", [Name]),
    {noreply, State#state{count = Count + 1}};

handle_cast(Msg, State) ->
    error_logger:warning_msg("Bad message: ~p~n", [Msg]),
    {noreply, State}.

handle_call({get_count}, _From, State) ->
    {reply, {ok, State#state.count}, State};

handle_call(Request, _From, State) ->
    error_logger:warning_msg("Bad message: ~p~n", [Request]),
    {reply, {error, unknown_call}, State}.

%% Other gen_server callbacks
handle_info(Info, State) ->
    error_logger:warning_msg("Bad message: ~p~n", [Info]),
    {noreply, State}.

terminate(_Reason, _State) ->
    ok.

code_change(_OldVsn, State, _Extra) ->
    {ok, State}.

Hier is een voorbeeld van het gebruik van deze service in de erlang-shell:

1> c(greeter).
{ok,greeter}
2> greeter:start_link().
{ok,<0.62.0>}
3> greeter:greet("Andriy").
Greetings Andriy!
ok
4> greeter:greet("Mike").
Greetings Mike!
ok
5> greeter:get_count().
{ok,2}

Gedrag gen_server gebruiken

Een gen_server is een specifieke eindige toestandsmachine die werkt als een server. gen_server kan verschillende soorten gebeurtenissen verwerken:

• synchrone aanvraag met handle_call
• asynchrone aanvraag met handle_cast
• ander bericht (niet gedefinieerd in OTP-specificatie) met handle_info

Synchrone en asynchrone berichten worden gespecificeerd in OTP en zijn eenvoudig getagde tupels met elke vorm van gegevens erop.

Een eenvoudige gen_server wordt als volgt gedefinieerd:

-module(simple_gen_server).
-behaviour(gen_server).
-export([start_link/0]).
-export([init/1, handle_call/3, handle_cast/2, handle_info/2,
         terminate/2, code_change/3]).

start_link() ->
    Return = gen_server:start_link({local, ?MODULE}, ?MODULE, [], []),
    io:format("start_link: ~p~n", [Return]),
    Return.

init([]) ->
    State = [],
    Return = {ok, State},
    io:format("init: ~p~n", [State]),
    Return.

handle_call(_Request, _From, State) ->
    Reply = ok,
    Return = {reply, Reply, State},
    io:format("handle_call: ~p~n", [Return]),
    Return.

handle_cast(_Msg, State) ->
    Return = {noreply, State},
    io:format("handle_cast: ~p~n", [Return]),
    Return.

handle_info(_Info, State) ->
    Return = {noreply, State},
    io:format("handle_info: ~p~n", [Return]),
    Return.

terminate(_Reason, _State) ->
    Return = ok,
    io:format("terminate: ~p~n", [Return]),
    ok.

code_change(_OldVsn, State, _Extra) ->
    Return = {ok, State},
    io:format("code_change: ~p~n", [Return]),
    Return.

Deze code is eenvoudig: elk ontvangen bericht wordt afgedrukt naar standaarduitvoer.

gen_server gedrag

Om een gen_server te definiëren, moet u dit expliciet aangeven in uw broncode met -behaviour(gen_server) . Merk op dat behaviour kan worden geschreven in de VS (gedrag) of het VK (gedrag).

start_link / 0

Deze functie is een eenvoudige snelkoppeling om een andere functie aan te roepen: gen_server:start_link/3,4 .

start_link / 3,4

start_link() ->
    gen_server:start_link({local, ?MODULE}, ?MODULE, [], []).

Deze functie wordt genoemd wanneer u uw server wilt starten die is gekoppeld aan een supervisor of een ander proces. start_link/3,4 kan uw proces automatisch registreren (als u denkt dat uw proces uniek moet zijn) of kan het eenvoudig uitzetten als een eenvoudig proces. Wanneer deze wordt aangeroepen, voert deze functie init/1 .

Met deze functie kunnen deze gedefinieerde waarden worden geretourneerd:

• {ok,Pid}
• ignore
• {error,Error}

init / 1

init([]) ->
    State = [],
    {ok, State}.

init/1 is de eerste uitgevoerde functie wanneer uw server wordt gestart. Deze initialiseert alle vereisten van uw toepassing en keert terug naar het nieuwe proces.

Deze functie kan alleen deze gedefinieerde waarden retourneren:

• {ok,State}
• {ok,State,Timeout}
• {ok,State,hibernate}
• {stop,Reason}
• ignore

State variabele kan alles, (bv lijst, tupel, proplists, kaart, record) en toegankelijk is voor alle functies binnen voortgebracht proces blijven.

handle_call / 3

handle_call(_Request, _From, State) ->
    Reply = ok,
    {reply, Reply, State}.

gen_server:call/2 voer deze callback uit. Het eerste argument is uw boodschap ( _Request ), de tweede is de oorsprong van het verzoek ( _From ) en de laatste is de huidige toestand ( State ) van uw lopende gen_server gedrag.

Als u een antwoord aan de beller wilt ontvangen, moet handle_call/3 een van deze gegevensstructuur retourneren:

• {reply,Reply,NewState}
• {reply,Reply,NewState,Timeout}
• {reply,Reply,NewState,hibernate}

Als u geen antwoord wilt op beller, moet handle_call/3 een van deze gegevensstructuur retourneren:

• {noreply,NewState}
• {noreply,NewState,Timeout}
• {noreply,NewState,hibernate}

Als u de huidige uitvoering van uw huidige gen_server wilt stoppen, moet handle_call/3 een van deze gegevensstructuur retourneren:

• {stop,Reason,Reply,NewState}
• {stop,Reason,NewState}

handle_cast / 2

handle_cast(_Msg, State) ->
    {noreply, State}.

gen_server:cast/2 voer deze callback uit. Het eerste argument is uw bericht ( _Msg ), en het tweede de huidige status van uw lopende gen_server-gedrag.

Standaard kan deze functie geen gegevens aan de beller doorgeven, dus u hebt slechts twee keuzes, doorgaan met de huidige uitvoering:

• {noreply,NewState}
• {noreply,NewState,Timeout}
• {noreply,NewState,hibernate}

Of stop uw huidige gen_server proces:

• {stop,Reason,NewState}

handle_info / 2

handle_info(_Info, State) ->
    {noreply, State}.

handle_info/2 wordt uitgevoerd wanneer niet-standaard OTP-berichten van buiten de wereld komen. Deze kan niet antwoorden en kan, zoals handle_cast/2 , slechts 2 acties uitvoeren, huidige uitvoering voortzetten:

• {noreply,NewState}
• {noreply,NewState,Timeout}
• {noreply,NewState,hibernate}

Of stop het huidige lopende gen_server proces:

• {stop,Reason,NewState}

beëindigen / 2

terminate(_Reason, _State) ->
    ok.

terminate/2 wordt opgeroepen wanneer er een fout optreedt of wanneer u uw gen_server proces wilt afsluiten.

code_change / 3

code_change(_OldVsn, State, _Extra) ->
    {ok, State}.

code_change/3 functie wordt aangeroepen wanneer u uw lopende code wilt upgraden.

Deze functie kan alleen deze gedefinieerde waarden retourneren:

• {ok, NewState}
• {error, Reason}

Dit proces starten

U kunt uw code compileren en simple_gen_server starten:

simple_gen_server:start_link().

Als u een bericht naar uw server wilt verzenden, kunt u deze functies gebruiken:

% will use handle_call as callback and print:
%   handle_call: mymessage
gen_server:call(simple_gen_server, mymessage).

% will use handle_cast as callback and print:
%   handle_cast: mymessage
gen_server:cast(simple_gen_server, mymessage).

% will use handle_info as callback and print:
%   handle_info: mymessage
erlang:send(whereis(simple_gen_server), mymessage).

Eenvoudige sleutel / waarde-database

Deze broncode maakt een eenvoudige sleutel / waardeopslagservice op basis van Erlang-gegevensstructuur op de map . Allereerst moeten we alle informatie over onze gen_server :

-module(cache).
-behaviour(gen_server).

% our API
-export([start_link/0]).
-export([get/1, put/2, state/0, delete/1, stop/0]).

% our handlers
-export([init/1, handle_call/3, handle_cast/2, handle_info/2,
         terminate/2, code_change/3]).

% Defining our function to start `cache` process:

start_link() ->
    gen_server:start_link({local, ?MODULE}, ?MODULE, [], []).

%%%%%%%%%%%%%%
% API

% Key/Value database is a simple store, value indexed by an unique key. 
% This implementation is based on map, this datastructure is like hash 
# in Perl or dictionaries in Python. 

% put/2
% put a value indexed by a key. We assume the link is stable 
% and the data will be written, so, we use an asynchronous call with 
% gen_server:cast/2.

put(Key, Value) ->
    gen_server:cast(?MODULE, {put, {Key, Value}}).

% get/1
% take one argument, a key and will a return the value indexed 
% by this same key. We use a synchronous call with gen_server:call/2.

get(Key) ->
    gen_server:call(?MODULE, {get, Key}).

% delete/1 
% like `put/1`, we assume the data will be removed. So, we use an 
% asynchronous call with gen_server:cast/2.

delete(Key) ->
    gen_server:cast(?MODULE, {delete, Key}).

% state/0 
% This function will return the current state (here the map who contain all 
% indexed values), we need a synchronous call.

state() ->
    gen_server:call(?MODULE, {get_state}).

% stop/0
% This function stop cache server process.

stop() ->
    gen_server:stop(?MODULE).

%%%%%%%%%%%%%%%
% Handlers

% init/1
% Here init/1 will initialize state with simple empty map datastructure.

init([]) ->
    {ok, #{}}.

% handle_call/3
% Now, we need to define our handle. In a cache server we need to get our 
% value from a key, this feature need to be synchronous, so, using 
% handle_call seems a good choice:

handle_call({get, Key}, From, State) ->
    Response = maps:get(Key, State, undefined),
    {reply, Response, State};

% We need to check our current state, like get_fea

handle_call({get_state}, From, State) ->
    Response = {current_state, State},
    {reply, Response, State};

% All other messages will be dropped here.

handle_call(_Request, _From, State) ->
    Reply = ok,
    {reply, Reply, State}.

% handle_cast/2
% put/2 will execute this function.

handle_cast({put, {Key, Value}}, State) ->
    NewState = maps:put(Key, Value, State),
    {noreply, NewState};

% delete/1 will execute this function.

handle_cast({delete, Key}, State) ->
    NewState = maps:remove(Key, State),
    {noreply, NewState};

% All other messages are dropped here.

handle_cast(_Msg, State) ->
    {noreply, State}.

%%%%%%%%%%%%%%%%
% other handlers

% We don't need other features, other handlers do nothing.

handle_info(_Info, State) ->
    {noreply, State}.

terminate(_Reason, _State) ->
    ok.

code_change(_OldVsn, State, _Extra) ->
    {ok, State}.

Onze cacheserver gebruiken

We kunnen nu onze code compileren en beginnen te gebruiken met erl .

% compile cache
c(cache).

% starting cache server
cache:start_link().

% get current store
% will return:
%   #{}
cache:state().

% put some data
cache:put(1, one).
cache:put(hello, bonjour).
cache:put(list, []).

% get current store
% will return:
%   #{1 => one,hello => bonjour,list => []}
cache:state().

% delete a value
cache:delete(1).
cache:state().
%   #{1 => one,hello => bonjour,list => []}

% stopping cache server
cache:stop().