Erlang Language
Comportement de gen_server

Remarques

Greeter Service

Voici un exemple de service qui accueille les utilisateurs par leur nom et suit le nombre d'utilisateurs rencontrés. Voir utilisation ci-dessous.

%% greeter.erl
%% Greets people and counts number of times it did so.
-module(greeter).
-behaviour(gen_server).
%% Export API Functions
-export([start_link/0, greet/1, get_count/0]).
%% Required gen server callbacks
-export([init/1, handle_call/3, handle_cast/2, handle_info/2, terminate/2, code_change/3]).

-record(state, {count::integer()}).

%% Public API
start_link() ->
    gen_server:start_link({local, ?MODULE}, ?MODULE, {}, []).

greet(Name) ->
    gen_server:cast(?MODULE, {greet, Name}).

get_count() ->
    gen_server:call(?MODULE, {get_count}).

%% Private
init({}) ->
    {ok, #state{count=0}}.

handle_cast({greet, Name}, #state{count = Count} = State) ->
    io:format("Greetings ~s!~n", [Name]),
    {noreply, State#state{count = Count + 1}};

handle_cast(Msg, State) ->
    error_logger:warning_msg("Bad message: ~p~n", [Msg]),
    {noreply, State}.

handle_call({get_count}, _From, State) ->
    {reply, {ok, State#state.count}, State};

handle_call(Request, _From, State) ->
    error_logger:warning_msg("Bad message: ~p~n", [Request]),
    {reply, {error, unknown_call}, State}.

%% Other gen_server callbacks
handle_info(Info, State) ->
    error_logger:warning_msg("Bad message: ~p~n", [Info]),
    {noreply, State}.

terminate(_Reason, _State) ->
    ok.

code_change(_OldVsn, State, _Extra) ->
    {ok, State}.

Voici un exemple d'utilisation de ce service dans le shell erlang:

1> c(greeter).
{ok,greeter}
2> greeter:start_link().
{ok,<0.62.0>}
3> greeter:greet("Andriy").
Greetings Andriy!
ok
4> greeter:greet("Mike").
Greetings Mike!
ok
5> greeter:get_count().
{ok,2}

Utilisation du comportement de gen_server

Un gen_server est une machine à états finis spécifique fonctionnant comme un serveur. gen_server peut gérer différents types d'événements:

• requête synchrone avec handle_call
• demande asynchrone avec handle_cast
• autre message (non défini dans la spécification OTP) avec handle_info

Les messages synchrones et asynchrones sont spécifiés dans OTP et sont de simples tuples marqués avec n'importe quel type de données.

Un simple gen_server est défini comme ceci:

-module(simple_gen_server).
-behaviour(gen_server).
-export([start_link/0]).
-export([init/1, handle_call/3, handle_cast/2, handle_info/2,
         terminate/2, code_change/3]).

start_link() ->
    Return = gen_server:start_link({local, ?MODULE}, ?MODULE, [], []),
    io:format("start_link: ~p~n", [Return]),
    Return.

init([]) ->
    State = [],
    Return = {ok, State},
    io:format("init: ~p~n", [State]),
    Return.

handle_call(_Request, _From, State) ->
    Reply = ok,
    Return = {reply, Reply, State},
    io:format("handle_call: ~p~n", [Return]),
    Return.

handle_cast(_Msg, State) ->
    Return = {noreply, State},
    io:format("handle_cast: ~p~n", [Return]),
    Return.

handle_info(_Info, State) ->
    Return = {noreply, State},
    io:format("handle_info: ~p~n", [Return]),
    Return.

terminate(_Reason, _State) ->
    Return = ok,
    io:format("terminate: ~p~n", [Return]),
    ok.

code_change(_OldVsn, State, _Extra) ->
    Return = {ok, State},
    io:format("code_change: ~p~n", [Return]),
    Return.

Ce code est simple: chaque message reçu est imprimé sur une sortie standard.

Comportement de gen_server

Pour définir un gen_server , vous devez le déclarer explicitement dans votre code source avec -behaviour(gen_server) . Notez que le behaviour peut être écrit aux États-Unis (comportement) ou au Royaume-Uni (comportement).

start_link / 0

Cette fonction est un simple raccourci pour appeler une autre fonction: gen_server:start_link/3,4 .

start_link / 3,4

start_link() ->
    gen_server:start_link({local, ?MODULE}, ?MODULE, [], []).

Cette fonction est appelée lorsque vous souhaitez démarrer votre serveur lié à un supervisor ou à un autre processus. start_link/3,4 peut enregistrer automatiquement votre processus (si vous pensez que votre processus doit être unique) ou peut simplement le générer comme un processus simple. Lorsqu'elle est appelée, cette fonction exécute init/1 .

Cette fonction peut renvoyer ces valeurs de définition:

• {ok,Pid}
• ignore
• {error,Error}

init / 1

init([]) ->
    State = [],
    {ok, State}.

init/1 est la première fonction exécutée lorsque votre serveur sera lancé. Celui-ci initialise tous les prérequis de votre application et renvoie l'état au processus nouvellement créé.

Cette fonction ne peut renvoyer que les valeurs définies:

• {ok,State}
• {ok,State,Timeout}
• {ok,State,hibernate}
• {stop,Reason}
• ignore

State variable d' State peut être tout (par exemple liste, tuple, listes de propriétés, carte, enregistrement) et rester accessible à toutes les fonctions à l'intérieur du processus généré.

handle_call / 3

handle_call(_Request, _From, State) ->
    Reply = ok,
    {reply, Reply, State}.

gen_server:call/2 exécute ce rappel. Le premier argument est votre message ( _Request ), le second est l'origine de la requête ( _From ) et le dernier est l'état actuel ( State ) de votre comportement gen_server en cours d'exécution.

Si vous souhaitez une réponse à l'appelant, handle_call/3 doit renvoyer l'une de ces structures de données:

• {reply,Reply,NewState}
• {reply,Reply,NewState,Timeout}
• {reply,Reply,NewState,hibernate}

Si vous ne souhaitez pas répondre à l'appelant, handle_call/3 doit renvoyer l'une de ces structures de données:

• {noreply,NewState}
• {noreply,NewState,Timeout}
• {noreply,NewState,hibernate}

Si vous souhaitez arrêter l'exécution en cours de votre gen_server actuel, handle_call/3 doit renvoyer l'une de ces structures de données:

• {stop,Reason,Reply,NewState}
• {stop,Reason,NewState}

handle_cast / 2

handle_cast(_Msg, State) ->
    {noreply, State}.

gen_server:cast/2 exécute ce rappel. Le premier argument est votre message ( _Msg ) et le second l'état actuel de votre comportement gen_server en cours d'exécution.

Par défaut, cette fonction ne peut pas transmettre de données à l'appelant. Vous n'avez donc que deux choix, continuez l'exécution en cours:

• {noreply,NewState}
• {noreply,NewState,Timeout}
• {noreply,NewState,hibernate}

Ou arrêtez votre processus gen_server actuel:

• {stop,Reason,NewState}

handle_info / 2

handle_info(_Info, State) ->
    {noreply, State}.

handle_info/2 est exécuté lorsque le message OTP non standard provient du monde extérieur. Celui-ci ne peut pas répondre et, comme handle_cast/2 ne peut faire que 2 actions, continue l'exécution en cours:

• {noreply,NewState}
• {noreply,NewState,Timeout}
• {noreply,NewState,hibernate}

Ou arrêtez le processus en cours de gen_server cours d' gen_server :

• {stop,Reason,NewState}

terminer / 2

terminate(_Reason, _State) ->
    ok.

terminate/2 est appelée lorsqu'une erreur survient ou lorsque vous souhaitez arrêter votre processus gen_server .

code_change / 3

code_change(_OldVsn, State, _Extra) ->
    {ok, State}.

code_change/3 fonction code_change/3 est appelée lorsque vous souhaitez mettre à niveau votre code en cours d'exécution.

Cette fonction ne peut renvoyer que les valeurs définies:

• {ok, NewState}
• {error, Reason}

Commencer ce processus

Vous pouvez compiler votre code et démarrer simple_gen_server :

simple_gen_server:start_link().

Si vous souhaitez envoyer un message à votre serveur, vous pouvez utiliser ces fonctions:

% will use handle_call as callback and print:
%   handle_call: mymessage
gen_server:call(simple_gen_server, mymessage).

% will use handle_cast as callback and print:
%   handle_cast: mymessage
gen_server:cast(simple_gen_server, mymessage).

% will use handle_info as callback and print:
%   handle_info: mymessage
erlang:send(whereis(simple_gen_server), mymessage).

Base de données simple clé / valeur

Ce code source crée un service de banque de clés / valeur simple basé sur la structure de données de map Erlang. Tout d'abord, nous devons définir toutes les informations concernant notre gen_server :

-module(cache).
-behaviour(gen_server).

% our API
-export([start_link/0]).
-export([get/1, put/2, state/0, delete/1, stop/0]).

% our handlers
-export([init/1, handle_call/3, handle_cast/2, handle_info/2,
         terminate/2, code_change/3]).

% Defining our function to start `cache` process:

start_link() ->
    gen_server:start_link({local, ?MODULE}, ?MODULE, [], []).

%%%%%%%%%%%%%%
% API

% Key/Value database is a simple store, value indexed by an unique key. 
% This implementation is based on map, this datastructure is like hash 
# in Perl or dictionaries in Python. 

% put/2
% put a value indexed by a key. We assume the link is stable 
% and the data will be written, so, we use an asynchronous call with 
% gen_server:cast/2.

put(Key, Value) ->
    gen_server:cast(?MODULE, {put, {Key, Value}}).

% get/1
% take one argument, a key and will a return the value indexed 
% by this same key. We use a synchronous call with gen_server:call/2.

get(Key) ->
    gen_server:call(?MODULE, {get, Key}).

% delete/1 
% like `put/1`, we assume the data will be removed. So, we use an 
% asynchronous call with gen_server:cast/2.

delete(Key) ->
    gen_server:cast(?MODULE, {delete, Key}).

% state/0 
% This function will return the current state (here the map who contain all 
% indexed values), we need a synchronous call.

state() ->
    gen_server:call(?MODULE, {get_state}).

% stop/0
% This function stop cache server process.

stop() ->
    gen_server:stop(?MODULE).

%%%%%%%%%%%%%%%
% Handlers

% init/1
% Here init/1 will initialize state with simple empty map datastructure.

init([]) ->
    {ok, #{}}.

% handle_call/3
% Now, we need to define our handle. In a cache server we need to get our 
% value from a key, this feature need to be synchronous, so, using 
% handle_call seems a good choice:

handle_call({get, Key}, From, State) ->
    Response = maps:get(Key, State, undefined),
    {reply, Response, State};

% We need to check our current state, like get_fea

handle_call({get_state}, From, State) ->
    Response = {current_state, State},
    {reply, Response, State};

% All other messages will be dropped here.

handle_call(_Request, _From, State) ->
    Reply = ok,
    {reply, Reply, State}.

% handle_cast/2
% put/2 will execute this function.

handle_cast({put, {Key, Value}}, State) ->
    NewState = maps:put(Key, Value, State),
    {noreply, NewState};

% delete/1 will execute this function.

handle_cast({delete, Key}, State) ->
    NewState = maps:remove(Key, State),
    {noreply, NewState};

% All other messages are dropped here.

handle_cast(_Msg, State) ->
    {noreply, State}.

%%%%%%%%%%%%%%%%
% other handlers

% We don't need other features, other handlers do nothing.

handle_info(_Info, State) ->
    {noreply, State}.

terminate(_Reason, _State) ->
    ok.

code_change(_OldVsn, State, _Extra) ->
    {ok, State}.

Utiliser notre serveur de cache

Nous pouvons maintenant compiler notre code et commencer à l'utiliser avec erl .

% compile cache
c(cache).

% starting cache server
cache:start_link().

% get current store
% will return:
%   #{}
cache:state().

% put some data
cache:put(1, one).
cache:put(hello, bonjour).
cache:put(list, []).

% get current store
% will return:
%   #{1 => one,hello => bonjour,list => []}
cache:state().

% delete a value
cache:delete(1).
cache:state().
%   #{1 => one,hello => bonjour,list => []}

% stopping cache server
cache:stop().