Erlang Language
zachowanie gen_server

Uwagi

Usługa Greeter

Oto przykład usługi, która wita ludzi pod danym imieniem i śledzi, ilu użytkowników napotkało. Zobacz użycie poniżej.

%% greeter.erl
%% Greets people and counts number of times it did so.
-module(greeter).
-behaviour(gen_server).
%% Export API Functions
-export([start_link/0, greet/1, get_count/0]).
%% Required gen server callbacks
-export([init/1, handle_call/3, handle_cast/2, handle_info/2, terminate/2, code_change/3]).

-record(state, {count::integer()}).

%% Public API
start_link() ->
    gen_server:start_link({local, ?MODULE}, ?MODULE, {}, []).

greet(Name) ->
    gen_server:cast(?MODULE, {greet, Name}).

get_count() ->
    gen_server:call(?MODULE, {get_count}).

%% Private
init({}) ->
    {ok, #state{count=0}}.

handle_cast({greet, Name}, #state{count = Count} = State) ->
    io:format("Greetings ~s!~n", [Name]),
    {noreply, State#state{count = Count + 1}};

handle_cast(Msg, State) ->
    error_logger:warning_msg("Bad message: ~p~n", [Msg]),
    {noreply, State}.

handle_call({get_count}, _From, State) ->
    {reply, {ok, State#state.count}, State};

handle_call(Request, _From, State) ->
    error_logger:warning_msg("Bad message: ~p~n", [Request]),
    {reply, {error, unknown_call}, State}.

%% Other gen_server callbacks
handle_info(Info, State) ->
    error_logger:warning_msg("Bad message: ~p~n", [Info]),
    {noreply, State}.

terminate(_Reason, _State) ->
    ok.

code_change(_OldVsn, State, _Extra) ->
    {ok, State}.

Oto przykładowe użycie tej usługi w powłoce erlang:

1> c(greeter).
{ok,greeter}
2> greeter:start_link().
{ok,<0.62.0>}
3> greeter:greet("Andriy").
Greetings Andriy!
ok
4> greeter:greet("Mike").
Greetings Mike!
ok
5> greeter:get_count().
{ok,2}

Korzystanie z zachowania gen_server

gen_server to konkretna skończona maszyna stanów działająca jak serwer. gen_server może obsługiwać różne typy zdarzeń:

• żądanie synchroniczne z handle_call
• żądanie asynchroniczne z handle_cast
• inna wiadomość (nie zdefiniowana w specyfikacji OTP) z handle_info

Wiadomości synchroniczne i asynchroniczne są określone w OTP i są prostymi krotkami z dowolnymi danymi na nich.

Prosty gen_server jest zdefiniowany następująco:

-module(simple_gen_server).
-behaviour(gen_server).
-export([start_link/0]).
-export([init/1, handle_call/3, handle_cast/2, handle_info/2,
         terminate/2, code_change/3]).

start_link() ->
    Return = gen_server:start_link({local, ?MODULE}, ?MODULE, [], []),
    io:format("start_link: ~p~n", [Return]),
    Return.

init([]) ->
    State = [],
    Return = {ok, State},
    io:format("init: ~p~n", [State]),
    Return.

handle_call(_Request, _From, State) ->
    Reply = ok,
    Return = {reply, Reply, State},
    io:format("handle_call: ~p~n", [Return]),
    Return.

handle_cast(_Msg, State) ->
    Return = {noreply, State},
    io:format("handle_cast: ~p~n", [Return]),
    Return.

handle_info(_Info, State) ->
    Return = {noreply, State},
    io:format("handle_info: ~p~n", [Return]),
    Return.

terminate(_Reason, _State) ->
    Return = ok,
    io:format("terminate: ~p~n", [Return]),
    ok.

code_change(_OldVsn, State, _Extra) ->
    Return = {ok, State},
    io:format("code_change: ~p~n", [Return]),
    Return.

Ten kod jest prosty: każda otrzymana wiadomość jest drukowana na standardowe wyjście.

zachowanie gen_server

Aby zdefiniować gen_server , musisz jawnie zadeklarować go w kodzie źródłowym za pomocą -behaviour(gen_server) . Uwaga: behaviour można zapisać w USA (zachowanie) lub Wielkiej Brytanii (zachowanie).

link_początkowy / 0

Ta funkcja jest prostym skrótem do wywołania innej funkcji: gen_server:start_link/3,4 .

start_link / 3,4

start_link() ->
    gen_server:start_link({local, ?MODULE}, ?MODULE, [], []).

Ta funkcja jest wywoływana, gdy chcesz uruchomić serwer połączony z supervisor lub innym procesem. start_link/3,4 może automatycznie zarejestrować twój proces (jeśli uważasz, że twój proces musi być unikalny) lub po prostu spawnować go jak prosty proces. Po wywołaniu ta funkcja wykonuje init/1 .

Ta funkcja może zwrócić te zdefiniowane wartości:

• {ok,Pid}
• ignore
• {error,Error}

init / 1

init([]) ->
    State = [],
    {ok, State}.

init/1 to pierwsza uruchomiona funkcja, kiedy serwer zostanie uruchomiony. Ta inicjuje wszystkie wymagania wstępne aplikacji i przywraca stan do nowo utworzonego procesu.

Ta funkcja może zwrócić tylko te zdefiniowane wartości:

• {ok,State}
• {ok,State,Timeout}
• {ok,State,hibernate}
• {stop,Reason}
• ignore

Zmienna State może być wszystkim (np. Listą, krotką, listami propozycji, mapą, zapisem) i pozostać dostępna dla wszystkich funkcji wewnątrz spawnowanego procesu.

handle_call / 3

handle_call(_Request, _From, State) ->
    Reply = ok,
    {reply, Reply, State}.

gen_server:call/2 wykonuje to wywołanie zwrotne. Pierwszy argument to twoja wiadomość ( _Request ), drugi to początek żądania ( _From ), a ostatni to aktualny stan ( State ) twojego zachowania gen_server.

Jeśli chcesz uzyskać odpowiedź do dzwoniącego, handle_call/3 musi zwrócić jedną z następujących struktur danych:

• {reply,Reply,NewState}
• {reply,Reply,NewState,Timeout}
• {reply,Reply,NewState,hibernate}

Jeśli nie chcesz odpowiadać na dzwoniącego, handle_call/3 musi zwrócić jedną z następujących struktur danych:

• {noreply,NewState}
• {noreply,NewState,Timeout}
• {noreply,NewState,hibernate}

Jeśli chcesz zatrzymać bieżące wykonywanie bieżącego serwera gen_server, handle_call/3 musi zwrócić jedną z następujących struktur danych:

• {stop,Reason,Reply,NewState}
• {stop,Reason,NewState}

handle_cast / 2

handle_cast(_Msg, State) ->
    {noreply, State}.

gen_server:cast/2 wykonuje to wywołanie zwrotne. Pierwszy argument to twoja wiadomość ( _Msg ), a drugi aktualny stan twojego działania gen_server.

Domyślnie ta funkcja nie może przesyłać danych do dzwoniącego, więc masz tylko dwie możliwości, kontynuuj bieżące wykonanie:

• {noreply,NewState}
• {noreply,NewState,Timeout}
• {noreply,NewState,hibernate}

Lub zatrzymaj obecny proces gen_server :

• {stop,Reason,NewState}

uchwyt_info / 2

handle_info(_Info, State) ->
    {noreply, State}.

handle_info/2 jest wykonywany, gdy niestandardowe wiadomości OTP pochodzą ze świata zewnętrznego. Ten nie może odpowiedzieć i, podobnie jak handle_cast/2 może wykonać tylko 2 akcje, kontynuując bieżące wykonanie:

• {noreply,NewState}
• {noreply,NewState,Timeout}
• {noreply,NewState,hibernate}

Lub zatrzymaj bieżący proces gen_server :

• {stop,Reason,NewState}

zakończyć / 2

terminate(_Reason, _State) ->
    ok.

terminate/2 jest wywoływany, gdy wystąpi błąd lub gdy chcesz zamknąć proces gen_server .

zmiana_kodu / 3

code_change(_OldVsn, State, _Extra) ->
    {ok, State}.

code_change/3 jest wywoływana, gdy chcesz zaktualizować działający kod.

Ta funkcja może zwrócić tylko te zdefiniowane wartości:

• {ok, NewState}
• {error, Reason}

Rozpoczęcie tego procesu

Możesz skompilować swój kod i uruchomić simple_gen_server :

simple_gen_server:start_link().

Jeśli chcesz wysłać wiadomość na serwer, możesz użyć tych funkcji:

% will use handle_call as callback and print:
%   handle_call: mymessage
gen_server:call(simple_gen_server, mymessage).

% will use handle_cast as callback and print:
%   handle_cast: mymessage
gen_server:cast(simple_gen_server, mymessage).

% will use handle_info as callback and print:
%   handle_info: mymessage
erlang:send(whereis(simple_gen_server), mymessage).

Prosta baza danych kluczy / wartości

Ten kod źródłowy tworzy prostą usługę przechowywania kluczy / wartości w oparciu o map Erlang. Po pierwsze, musimy zdefiniować wszystkie informacje dotyczące naszego gen_server :

-module(cache).
-behaviour(gen_server).

% our API
-export([start_link/0]).
-export([get/1, put/2, state/0, delete/1, stop/0]).

% our handlers
-export([init/1, handle_call/3, handle_cast/2, handle_info/2,
         terminate/2, code_change/3]).

% Defining our function to start `cache` process:

start_link() ->
    gen_server:start_link({local, ?MODULE}, ?MODULE, [], []).

%%%%%%%%%%%%%%
% API

% Key/Value database is a simple store, value indexed by an unique key. 
% This implementation is based on map, this datastructure is like hash 
# in Perl or dictionaries in Python. 

% put/2
% put a value indexed by a key. We assume the link is stable 
% and the data will be written, so, we use an asynchronous call with 
% gen_server:cast/2.

put(Key, Value) ->
    gen_server:cast(?MODULE, {put, {Key, Value}}).

% get/1
% take one argument, a key and will a return the value indexed 
% by this same key. We use a synchronous call with gen_server:call/2.

get(Key) ->
    gen_server:call(?MODULE, {get, Key}).

% delete/1 
% like `put/1`, we assume the data will be removed. So, we use an 
% asynchronous call with gen_server:cast/2.

delete(Key) ->
    gen_server:cast(?MODULE, {delete, Key}).

% state/0 
% This function will return the current state (here the map who contain all 
% indexed values), we need a synchronous call.

state() ->
    gen_server:call(?MODULE, {get_state}).

% stop/0
% This function stop cache server process.

stop() ->
    gen_server:stop(?MODULE).

%%%%%%%%%%%%%%%
% Handlers

% init/1
% Here init/1 will initialize state with simple empty map datastructure.

init([]) ->
    {ok, #{}}.

% handle_call/3
% Now, we need to define our handle. In a cache server we need to get our 
% value from a key, this feature need to be synchronous, so, using 
% handle_call seems a good choice:

handle_call({get, Key}, From, State) ->
    Response = maps:get(Key, State, undefined),
    {reply, Response, State};

% We need to check our current state, like get_fea

handle_call({get_state}, From, State) ->
    Response = {current_state, State},
    {reply, Response, State};

% All other messages will be dropped here.

handle_call(_Request, _From, State) ->
    Reply = ok,
    {reply, Reply, State}.

% handle_cast/2
% put/2 will execute this function.

handle_cast({put, {Key, Value}}, State) ->
    NewState = maps:put(Key, Value, State),
    {noreply, NewState};

% delete/1 will execute this function.

handle_cast({delete, Key}, State) ->
    NewState = maps:remove(Key, State),
    {noreply, NewState};

% All other messages are dropped here.

handle_cast(_Msg, State) ->
    {noreply, State}.

%%%%%%%%%%%%%%%%
% other handlers

% We don't need other features, other handlers do nothing.

handle_info(_Info, State) ->
    {noreply, State}.

terminate(_Reason, _State) ->
    ok.

code_change(_OldVsn, State, _Extra) ->
    {ok, State}.

Korzystanie z naszego serwera pamięci podręcznej

Możemy teraz skompilować nasz kod i zacząć używać go z erl .

% compile cache
c(cache).

% starting cache server
cache:start_link().

% get current store
% will return:
%   #{}
cache:state().

% put some data
cache:put(1, one).
cache:put(hello, bonjour).
cache:put(list, []).

% get current store
% will return:
%   #{1 => one,hello => bonjour,list => []}
cache:state().

% delete a value
cache:delete(1).
cache:state().
%   #{1 => one,hello => bonjour,list => []}

% stopping cache server
cache:stop().