Erlang Language
gen_server beteende

Anmärkningar

Greeter Service

Här är ett exempel på en tjänst som hälsar människor med förnamnet och håller reda på hur många användare de stött på. Se användning nedan.

%% greeter.erl
%% Greets people and counts number of times it did so.
-module(greeter).
-behaviour(gen_server).
%% Export API Functions
-export([start_link/0, greet/1, get_count/0]).
%% Required gen server callbacks
-export([init/1, handle_call/3, handle_cast/2, handle_info/2, terminate/2, code_change/3]).

-record(state, {count::integer()}).

%% Public API
start_link() ->
    gen_server:start_link({local, ?MODULE}, ?MODULE, {}, []).

greet(Name) ->
    gen_server:cast(?MODULE, {greet, Name}).

get_count() ->
    gen_server:call(?MODULE, {get_count}).

%% Private
init({}) ->
    {ok, #state{count=0}}.

handle_cast({greet, Name}, #state{count = Count} = State) ->
    io:format("Greetings ~s!~n", [Name]),
    {noreply, State#state{count = Count + 1}};

handle_cast(Msg, State) ->
    error_logger:warning_msg("Bad message: ~p~n", [Msg]),
    {noreply, State}.

handle_call({get_count}, _From, State) ->
    {reply, {ok, State#state.count}, State};

handle_call(Request, _From, State) ->
    error_logger:warning_msg("Bad message: ~p~n", [Request]),
    {reply, {error, unknown_call}, State}.

%% Other gen_server callbacks
handle_info(Info, State) ->
    error_logger:warning_msg("Bad message: ~p~n", [Info]),
    {noreply, State}.

terminate(_Reason, _State) ->
    ok.

code_change(_OldVsn, State, _Extra) ->
    {ok, State}.

Här är ett exempel på användning av den här tjänsten i erlang shell:

1> c(greeter).
{ok,greeter}
2> greeter:start_link().
{ok,<0.62.0>}
3> greeter:greet("Andriy").
Greetings Andriy!
ok
4> greeter:greet("Mike").
Greetings Mike!
ok
5> greeter:get_count().
{ok,2}

Med gen_server beteende

En gen_server är en specifik finitisk maskin som fungerar som en server. gen_server kan hantera olika typer av händelser:

• synkron begäran med handle_call
• asynkron begäran med handle_cast
• annat meddelande (inte definierat i OTP-specifikationen) med handle_info

Synkrona och asynkrona meddelanden anges i OTP och är enkla taggade tuplar med alla typer av data på det.

En enkel gen_server definieras så här:

-module(simple_gen_server).
-behaviour(gen_server).
-export([start_link/0]).
-export([init/1, handle_call/3, handle_cast/2, handle_info/2,
         terminate/2, code_change/3]).

start_link() ->
    Return = gen_server:start_link({local, ?MODULE}, ?MODULE, [], []),
    io:format("start_link: ~p~n", [Return]),
    Return.

init([]) ->
    State = [],
    Return = {ok, State},
    io:format("init: ~p~n", [State]),
    Return.

handle_call(_Request, _From, State) ->
    Reply = ok,
    Return = {reply, Reply, State},
    io:format("handle_call: ~p~n", [Return]),
    Return.

handle_cast(_Msg, State) ->
    Return = {noreply, State},
    io:format("handle_cast: ~p~n", [Return]),
    Return.

handle_info(_Info, State) ->
    Return = {noreply, State},
    io:format("handle_info: ~p~n", [Return]),
    Return.

terminate(_Reason, _State) ->
    Return = ok,
    io:format("terminate: ~p~n", [Return]),
    ok.

code_change(_OldVsn, State, _Extra) ->
    Return = {ok, State},
    io:format("code_change: ~p~n", [Return]),
    Return.

Den här koden är enkel: varje mottaget meddelande skrivs ut på standardutdata.

gen_server beteende

För att definiera en gen_server måste du uttryckligen förklara den i din källkod med -behaviour(gen_server) . Observera att behaviour kan skrivas i USA (beteende) eller Storbritannien (beteende).

start_link / 0

Denna funktion är en enkel genväg för att kalla en annan funktion: gen_server:start_link/3,4 .

start_link / 3,4

start_link() ->
    gen_server:start_link({local, ?MODULE}, ?MODULE, [], []).

Denna funktion anropas när du vill starta din server länkad till en supervisor eller en annan process. start_link/3,4 kan registrera din process automatiskt (om du tror att din process måste vara unik) eller helt enkelt kan leka den som enkel process. Vid anrop utför denna funktion init/1 .

Denna funktion kan returnera dessa definierade värden:

• {ok,Pid}
• ignore
• {error,Error}

init / 1

init([]) ->
    State = [],
    {ok, State}.

init/1 är den första exekverade funktionen när servern startas. Den här initialiserar alla förutsättningar för din ansökan och återlämnar tillstånd till nyskapad process.

Denna funktion kan bara returnera dessa definierade värden:

• {ok,State}
• {ok,State,Timeout}
• {ok,State,hibernate}
• {stop,Reason}
• ignore

State kan vara allt (t.ex. lista, tupel, proplister, karta, post) och förbli tillgänglig för alla funktioner inom spawned process.

handle_call / 3

handle_call(_Request, _From, State) ->
    Reply = ok,
    {reply, Reply, State}.

gen_server:call/2 kör detta återuppringning. Det första argumentet är ditt meddelande ( _Request ), det andra är ursprunget till begäran ( _From ) och det sista är det aktuella läget ( State ) för ditt körande gen_server-beteende.

Om du vill ha ett svar till den som ringer handle_call/3 returnera en av dessa datastrukturer:

• {reply,Reply,NewState}
• {reply,Reply,NewState,Timeout}
• {reply,Reply,NewState,hibernate}

Om du inte vill ha något svar till den som ringer handle_call/3 returnera en av dessa datastrukturer:

• {noreply,NewState}
• {noreply,NewState,Timeout}
• {noreply,NewState,hibernate}

Om du vill stoppa den nuvarande exekveringen av din nuvarande gen_server, handle_call/3 returnera en av dessa datastrukturer:

• {stop,Reason,Reply,NewState}
• {stop,Reason,NewState}

handle_cast / 2

handle_cast(_Msg, State) ->
    {noreply, State}.

gen_server:cast/2 kör detta återuppringning. Det första argumentet är ditt meddelande ( _Msg ) och det andra det aktuella läget för ditt körande gen_server-beteende.

Som standard kan denna funktion inte data till den som ringer, så du har bara två val, fortsätt den aktuella exekveringen:

• {noreply,NewState}
• {noreply,NewState,Timeout}
• {noreply,NewState,hibernate}

Eller stoppa din nuvarande gen_server process:

• {stop,Reason,NewState}

handle_info / 2

handle_info(_Info, State) ->
    {noreply, State}.

handle_info/2 körs när icke-standard OTP-meddelanden kommer från omvärlden. Den här kan inte svara, och som handle_cast/2 kan bara göra två åtgärder, fortsätta den aktuella exekveringen:

• {noreply,NewState}
• {noreply,NewState,Timeout}
• {noreply,NewState,hibernate}

Eller stoppa den aktuella gen_server processen:

• {stop,Reason,NewState}

avsluta / 2

terminate(_Reason, _State) ->
    ok.

terminate/2 kallas när ett fel uppstår eller när du vill stänga av din gen_server process.

code_change / 3

code_change(_OldVsn, State, _Extra) ->
    {ok, State}.

code_change/3 funktionen anropas när du vill uppgradera din körkod.

Denna funktion kan bara returnera dessa definierade värden:

• {ok, NewState}
• {error, Reason}

Starta denna process

Du kan sammanställa din kod och starta simple_gen_server :

simple_gen_server:start_link().

Om du vill skicka meddelande till din server kan du använda dessa funktioner:

% will use handle_call as callback and print:
%   handle_call: mymessage
gen_server:call(simple_gen_server, mymessage).

% will use handle_cast as callback and print:
%   handle_cast: mymessage
gen_server:cast(simple_gen_server, mymessage).

% will use handle_info as callback and print:
%   handle_info: mymessage
erlang:send(whereis(simple_gen_server), mymessage).

Enkel nyckel- / värdedatabas

Denna källkod skapar en enkel nyckel- / värdeförvaringstjänst baserad på map Erlang datastruktur. För det första måste vi definiera all information om vår gen_server :

-module(cache).
-behaviour(gen_server).

% our API
-export([start_link/0]).
-export([get/1, put/2, state/0, delete/1, stop/0]).

% our handlers
-export([init/1, handle_call/3, handle_cast/2, handle_info/2,
         terminate/2, code_change/3]).

% Defining our function to start `cache` process:

start_link() ->
    gen_server:start_link({local, ?MODULE}, ?MODULE, [], []).

%%%%%%%%%%%%%%
% API

% Key/Value database is a simple store, value indexed by an unique key. 
% This implementation is based on map, this datastructure is like hash 
# in Perl or dictionaries in Python. 

% put/2
% put a value indexed by a key. We assume the link is stable 
% and the data will be written, so, we use an asynchronous call with 
% gen_server:cast/2.

put(Key, Value) ->
    gen_server:cast(?MODULE, {put, {Key, Value}}).

% get/1
% take one argument, a key and will a return the value indexed 
% by this same key. We use a synchronous call with gen_server:call/2.

get(Key) ->
    gen_server:call(?MODULE, {get, Key}).

% delete/1 
% like `put/1`, we assume the data will be removed. So, we use an 
% asynchronous call with gen_server:cast/2.

delete(Key) ->
    gen_server:cast(?MODULE, {delete, Key}).

% state/0 
% This function will return the current state (here the map who contain all 
% indexed values), we need a synchronous call.

state() ->
    gen_server:call(?MODULE, {get_state}).

% stop/0
% This function stop cache server process.

stop() ->
    gen_server:stop(?MODULE).

%%%%%%%%%%%%%%%
% Handlers

% init/1
% Here init/1 will initialize state with simple empty map datastructure.

init([]) ->
    {ok, #{}}.

% handle_call/3
% Now, we need to define our handle. In a cache server we need to get our 
% value from a key, this feature need to be synchronous, so, using 
% handle_call seems a good choice:

handle_call({get, Key}, From, State) ->
    Response = maps:get(Key, State, undefined),
    {reply, Response, State};

% We need to check our current state, like get_fea

handle_call({get_state}, From, State) ->
    Response = {current_state, State},
    {reply, Response, State};

% All other messages will be dropped here.

handle_call(_Request, _From, State) ->
    Reply = ok,
    {reply, Reply, State}.

% handle_cast/2
% put/2 will execute this function.

handle_cast({put, {Key, Value}}, State) ->
    NewState = maps:put(Key, Value, State),
    {noreply, NewState};

% delete/1 will execute this function.

handle_cast({delete, Key}, State) ->
    NewState = maps:remove(Key, State),
    {noreply, NewState};

% All other messages are dropped here.

handle_cast(_Msg, State) ->
    {noreply, State}.

%%%%%%%%%%%%%%%%
% other handlers

% We don't need other features, other handlers do nothing.

handle_info(_Info, State) ->
    {noreply, State}.

terminate(_Reason, _State) ->
    ok.

code_change(_OldVsn, State, _Extra) ->
    {ok, State}.

Med vår cache-server

Vi kan nu sammanställa vår kod och börja använda den med erl .

% compile cache
c(cache).

% starting cache server
cache:start_link().

% get current store
% will return:
%   #{}
cache:state().

% put some data
cache:put(1, one).
cache:put(hello, bonjour).
cache:put(list, []).

% get current store
% will return:
%   #{1 => one,hello => bonjour,list => []}
cache:state().

% delete a value
cache:delete(1).
cache:state().
%   #{1 => one,hello => bonjour,list => []}

% stopping cache server
cache:stop().