F#
Zapamiętywanie

Proste zapamiętywanie

Zapamiętywanie składa się z wyników funkcji buforowania, aby uniknąć wielokrotnego obliczania tego samego wyniku. Jest to przydatne podczas pracy z funkcjami, które wykonują kosztowne obliczenia.

Jako przykład możemy użyć prostej funkcji silniowej:

let factorial index =
    let rec innerLoop i acc =
        match i with
        | 0 | 1 -> acc
        | _ -> innerLoop (i - 1) (acc * i)

    innerLoop index 1

Wielokrotne wywołanie tej funkcji z tym samym parametrem powoduje powtarzanie tego samego obliczenia.

Zapamiętywanie pomoże nam buforować wynik czynnikowy i zwrócić go, jeśli ten sam parametr zostanie ponownie przekazany.

Oto prosta implementacja zapamiętywania:

// memoization takes a function as a parameter
// This function will be called every time a value is not in the cache
let memoization f =
    // The dictionary is used to store values for every parameter that has been seen
    let cache = Dictionary<_,_>()
    fun c ->
        let exist, value = cache.TryGetValue (c)
        match exist with
        | true -> 
            // Return the cached result directly, no method call
            printfn "%O -> In cache" c
            value
        | _ -> 
            // Function call is required first followed by caching the result for next call with the same parameters
            printfn "%O -> Not in cache, calling function..." c
            let value = f c
            cache.Add (c, value)
            value

Funkcja memoization po prostu przyjmuje funkcję jako parametr i zwraca funkcję o tej samej sygnaturze. Można to zobaczyć w sygnaturze metody f:('a -> 'b) -> ('a -> 'b) . W ten sposób możesz używać zapamiętywania w taki sam sposób, jakbyś wywoływał metodę silni.

printfn mają pokazać, co się stanie, gdy printfn funkcję wiele razy; można je bezpiecznie usunąć.

Korzystanie z zapamiętywania jest łatwe:

// Pass the function we want to cache as a parameter via partial application
let factorialMem = memoization factorial

// Then call the memoized function
printfn "%i" (factorialMem 10)
printfn "%i" (factorialMem 10)
printfn "%i" (factorialMem 10)
printfn "%i" (factorialMem 4)
printfn "%i" (factorialMem 4)

// Prints
// 10 -> Not in cache, calling function...
// 3628800
// 10 -> In cache
// 3628800
// 10 -> In cache
// 3628800
// 4 -> Not in cache, calling function...
// 24
// 4 -> In cache
// 24

Zapamiętywanie w funkcji rekurencyjnej

Korzystając z poprzedniego przykładu obliczania silni liczby całkowitej, umieść w tablicy mieszającej wszystkie wartości silni obliczone wewnątrz rekurencji, które nie pojawiają się w tabeli.

Podobnie jak w artykule na temat zapamiętywania , deklarujemy funkcję f która akceptuje fact parametru funkcji i parametr liczby całkowitej. Funkcja f , zawiera instrukcje do obliczania silni n z fact(n-1) .

Pozwala to obsłużyć rekurencję przez funkcję zwróconą przez memorec a nie przez sam fact , i może przerwać obliczenia, jeśli wartość fact(n-1) została już obliczona i znajduje się w tabeli skrótów.

let memorec f =
   let cache = Dictionary<_,_>()
   let rec frec n = 
       let value = ref 0
       let exist = cache.TryGetValue(n, value)
       match exist with
       | true -> 
           printfn "%O -> In cache" n
       | false ->
           printfn "%O -> Not in cache, calling function..." n
           value := f frec n
           cache.Add(n, !value)
       !value
   in frec

let f = fun fact n -> if n<2 then 1 else n*fact(n-1)

[<EntryPoint>]
let main argv = 
    let g = memorec(f)
    printfn "%A" (g 10)
    printfn "%A" "---------------------"
    printfn "%A" (g 5)
    Console.ReadLine()
    0

Wynik:

10 -> Not in cache, calling function...
9 -> Not in cache, calling function...
8 -> Not in cache, calling function...
7 -> Not in cache, calling function...
6 -> Not in cache, calling function...
5 -> Not in cache, calling function...
4 -> Not in cache, calling function...
3 -> Not in cache, calling function...
2 -> Not in cache, calling function...
1 -> Not in cache, calling function...
3628800
"---------------------"
5 -> In cache
120