F#
Operatorzy

Jak komponować wartości i funkcje za pomocą wspólnych operatorów

W programowaniu obiektowym powszechnym zadaniem jest komponowanie obiektów (wartości). W Programowaniu Funkcjonalnym równie częstym zadaniem jest tworzenie wartości, jak i funkcji.

Jesteśmy przyzwyczajeni do komponowania wartości z naszego doświadczenia z innymi językami programowania przy użyciu operatorów takich jak + , - , * , / i tak dalej.

Skład wartości

let x = 1 + 2 + 3 * 2

Ponieważ programowanie funkcjonalne składa się zarówno z funkcji, jak i wartości, nic dziwnego, że istnieją wspólne operatory dla kompozycji funkcji, takie jak >> , << , |> i <| .

Skład funkcji

// val f : int -> int
let f v   = v + 1
// val g : int -> int
let g v   = v * 2

// Different ways to compose f and g
// val h : int -> int
let h1 v  = g (f v)
let h2 v  = v |> f |> g   // Forward piping of 'v'
let h3 v  = g <| (f <| v) // Reverse piping of 'v' (because <| has left associcativity we need ())
let h4    = f >> g        // Forward functional composition
let h5    = g << f        // Reverse functional composition (closer to math notation of 'g o f')

W F# preferowane jest przesyłanie dalej niż przesyłanie wstecz, ponieważ:

1. Wnioskowanie typu (ogólnie) przepływa od lewej do prawej, więc wartości i funkcje są naturalne również od lewej do prawej
2. Ponieważ <| i << powinny mieć odpowiednie skojarzenie, ale w F# są one asocjatywne, co zmusza nas do wstawienia ()
3. Mieszanie potoków do przodu i do tyłu zasadniczo nie działa, ponieważ mają taki sam priorytet.

Skład monady

Ponieważ Monady (jak Option<'T> lub List<'T> ) są powszechnie używane w programowaniu funkcjonalnym, istnieją również powszechne, ale mniej znane operatory do komponowania funkcji współpracujących z Monadami, takie jak >>= , >=> , <|> i <*> .

let (>>=) t uf  = Option.bind uf t
let (>=>) tf uf = fun v -> tf v >>= uf
// val oinc   : int -> int option
let oinc   v    = Some (v + 1)    // Increment v
// val ofloat : int -> float option
let ofloat v    = Some (float v)  // Map v to float

// Different ways to compose functions working with Option Monad
// val m : int option -> float option
let m1 v  = Option.bind (fun v -> Some (float (v + 1))) v
let m2 v  = v |> Option.bind oinc |> Option.bind ofloat
let m3 v  = v >>= oinc >>= ofloat
let m4    = oinc >=> ofloat

// Other common operators are <|> (orElse) and <*> (andAlso)

// If 't' has Some value then return t otherwise return u
let (<|>) t u =
  match t with
  | Some _  -> t
  | None    -> u

// If 't' and 'u' has Some values then return Some (tv*uv) otherwise return None
let (<*>) t u =
  match t, u with
  | Some tv, Some tu  -> Some (tv, tu)
  | _                 -> None

// val pickOne : 'a option -> 'a option -> 'a option
let pickOne t u v = t <|> u <|> v

// val combine : 'a option -> 'b option  -> 'c option -> (('a*'b)*'c) option
let combine t u v = t <*> u <*> v

Wniosek

Dla nowych programistów funkcjonalnych skład funkcji za pomocą operatorów może wydawać się nieprzejrzysty i niejasny, ale to dlatego, że znaczenie tych operatorów nie jest tak powszechnie znane, jak operatory pracujące na wartościach. Jednak z pewnym treningiem używanie |> , >> , >>= i >=> staje się tak naturalne, jak używanie + , - , * i / .

Latebinding w F # za pomocą? operator

W statycznie typowanym języku, takim jak F# , pracujemy z typami dobrze znanymi w czasie kompilacji. Korzystamy z zewnętrznych źródeł danych w sposób bezpieczny dla typu, korzystając z dostawców typów.

Czasami jednak konieczne jest użycie późnego wiązania (jak dynamic w C# ). Na przykład podczas pracy z dokumentami JSON , które nie mają dobrze zdefiniowanego schematu.

Aby uprościć pracę z późnym wiązaniem, F# zapewnia obsługę operatorów wyszukiwania dynamicznego ? i ?<- .

Przykład:

// (?) allows us to lookup values in a map like this: map?MyKey
let inline (?)   m k   = Map.tryFind k m
// (?<-) allows us to update values in a map like this: map?MyKey <- 123
let inline (?<-) m k v = Map.add k v m

let getAndUpdate (map : Map<string, int>) : int option*Map<string, int> =
  let i = map?Hello       // Equivalent to map |> Map.tryFind "Hello"
  let m = map?Hello <- 3  // Equivalent to map |> Map.add "Hello" 3
  i, m

Okazuje się, że obsługa F# dla późnego wiązania jest prosta, ale elastyczna.