Visual Basic .NET Language
Obsługa błędów

Spróbuj ... Złap ... Wreszcie oświadczenie

Struktura:

Try
    'Your program will try to run the code in this block.  
    'If any exceptions are thrown, the code in the Catch Block will be executed,
    'without executing the lines after the one which caused the exception.
Catch ex As System.IO.IOException
    'If an exception occurs when processing the Try block, each Catch statement
    'is examined in textual order to determine which handles the exception. 
    'For example, this Catch block handles an IOException.
Catch ex As Exception
    'This catch block handles all Exception types.
    'Details of the exception, in this case, are in the "ex" variable.
    'You can show the error in a MessageBox with the below line.
    MessageBox.Show(ex.Message)
Finally
    'A finally block is always executed, regardless of if an Exception occurred.
End Try

Przykładowy kod:

Try
    Dim obj = Nothing
    Dim prop = obj.Name 'This line will throw a NullReferenceException

    Console.WriteLine("Test.") ' This line will NOT be executed
Catch ex As System.IO.IOException
    ' Code that reacts to IOException.
Catch ex As NullReferenceException
    ' Code that reacts to a NullReferenceException
    Console.WriteLine("NullReferenceException: " & ex.Message)
    Console.WriteLine("Stack Trace: " & ex.StackTrace)
Catch ex As Exception
    ' Code that reacts to any other exception.
Finally   
    ' This will always be run, regardless of if an exception is thrown.
    Console.WriteLine("Completed")
End Try

Tworzenie niestandardowego wyjątku i rzucanie

Możesz utworzyć niestandardowy wyjątek i wyrzucić go podczas wykonywania funkcji. Jako ogólną praktykę powinieneś rzucać wyjątek tylko wtedy, gdy twoja funkcja nie może osiągnąć zdefiniowanej funkcjonalności.

Private Function OpenDatabase(Byval Server as String, Byval User as String, Byval Pwd as String)
    if Server.trim="" then 
        Throw new Exception("Server Name cannot be blank")
    elseif User.trim ="" then 
        Throw new Exception("User name cannot be blank")
    elseif Pwd.trim="" then 
        Throw new Exception("Password cannot be blank")
    endif

    'Here add codes for connecting to the server
End function

Spróbuj złapać w operacji na bazie danych

Możesz użyć Try..Catch do wycofania operacji na bazie danych poprzez umieszczenie instrukcji wycofania w segmencie Catch.

    Try            
        'Do the database operation...        
        xCmd.CommandText = "INSERT into ...."
        xCmd.ExecuteNonQuery()

        objTrans.Commit()
        conn.Close()
    Catch ex As Exception 
        'Rollback action when something goes off           
        objTrans.Rollback()
        conn.Close()
    End Try

Wyjątek niemożliwy do złapania

Chociaż Catch ex As Exception twierdzi, że może obsłużyć wszystkie wyjątki - istnieje jeden wyjątek (nie jest przeznaczona gra słów).

Imports System
Static Sub StackOverflow() ' Again no pun intended
    StackOverflow()
End Sub
Static Sub Main()
    Try
        StackOverflow()
    Catch ex As Exception
        Console.WriteLine("Exception caught!")
    Finally
        Console.WriteLine("Finally block")
    End Try
End Sub

Ups ... Wystąpił System.StackOverflowException podczas gdy konsola nawet nic nie wydrukowała! Według MSDN

Począwszy od .NET Framework 2.0, nie można złapać obiektu StackOverflowException za pomocą bloku try / catch, a odpowiedni proces jest domyślnie kończony. W związku z tym powinieneś napisać kod, aby wykryć i zapobiec przepełnieniu stosu.

Dlatego System.StackOverflowException jest nie do złapania. Uważaj na to!

Krytyczne wyjątki

Zasadniczo większość wyjątków nie jest tak krytyczna, ale istnieje kilka naprawdę poważnych wyjątków, z którymi możesz nie być w stanie sobie poradzić, takich jak słynny wyjątek System.StackOverflowException . Istnieją jednak inne, które mogą zostać ukryte przez Catch ex As Exception , takie jak System.OutOfMemoryException , System.BadImageFormatException i System.InvalidProgramException . Dobrą praktyką programistyczną jest ich pomijanie, jeśli nie można ich poprawnie obsłużyć. Aby odfiltrować te wyjątki, potrzebujemy metody pomocniczej:

Public Shared Function IsCritical(ex As Exception) As Boolean
    Return TypeOf ex Is OutOfMemoryException OrElse
           TypeOf ex Is AppDomainUnloadedException OrElse
           TypeOf ex Is AccessViolationException OrElse
           TypeOf ex Is BadImageFormatException OrElse
           TypeOf ex Is CannotUnloadAppDomainException OrElse
           TypeOf ex Is ExecutionEngineException OrElse ' Obsolete one, but better to include
           TypeOf ex Is InvalidProgramException OrElse
           TypeOf ex Is System.Threading.ThreadAbortException
End Function

Stosowanie:

Try
    SomeMethod()
Catch ex As Exception When Not IsCritical(ex)
    Console.WriteLine("Exception caught: " & ex.Message)
End Try