Visual Basic .NET Language
Gestione degli errori

Prova ... Catch ... Finally Statement

Struttura:

Try
    'Your program will try to run the code in this block.  
    'If any exceptions are thrown, the code in the Catch Block will be executed,
    'without executing the lines after the one which caused the exception.
Catch ex As System.IO.IOException
    'If an exception occurs when processing the Try block, each Catch statement
    'is examined in textual order to determine which handles the exception. 
    'For example, this Catch block handles an IOException.
Catch ex As Exception
    'This catch block handles all Exception types.
    'Details of the exception, in this case, are in the "ex" variable.
    'You can show the error in a MessageBox with the below line.
    MessageBox.Show(ex.Message)
Finally
    'A finally block is always executed, regardless of if an Exception occurred.
End Try

Codice di esempio:

Try
    Dim obj = Nothing
    Dim prop = obj.Name 'This line will throw a NullReferenceException

    Console.WriteLine("Test.") ' This line will NOT be executed
Catch ex As System.IO.IOException
    ' Code that reacts to IOException.
Catch ex As NullReferenceException
    ' Code that reacts to a NullReferenceException
    Console.WriteLine("NullReferenceException: " & ex.Message)
    Console.WriteLine("Stack Trace: " & ex.StackTrace)
Catch ex As Exception
    ' Code that reacts to any other exception.
Finally   
    ' This will always be run, regardless of if an exception is thrown.
    Console.WriteLine("Completed")
End Try

Creazione di eccezioni e lanci personalizzati

È possibile creare un'eccezione personalizzata e lanciarle durante l'esecuzione della propria funzione. Come pratica generale dovresti solo lanciare un'eccezione quando la tua funzione non è in grado di raggiungere la sua funzionalità definita.

Private Function OpenDatabase(Byval Server as String, Byval User as String, Byval Pwd as String)
    if Server.trim="" then 
        Throw new Exception("Server Name cannot be blank")
    elseif User.trim ="" then 
        Throw new Exception("User name cannot be blank")
    elseif Pwd.trim="" then 
        Throw new Exception("Password cannot be blank")
    endif

    'Here add codes for connecting to the server
End function

Prova Catch in Database Operation

È possibile utilizzare Try..Catch per eseguire il rollback dell'operazione del database posizionando l'istruzione rollback nel segmento Catch.

    Try            
        'Do the database operation...        
        xCmd.CommandText = "INSERT into ...."
        xCmd.ExecuteNonQuery()

        objTrans.Commit()
        conn.Close()
    Catch ex As Exception 
        'Rollback action when something goes off           
        objTrans.Rollback()
        conn.Close()
    End Try

L'eccezione non intercettabile

Anche se Catch ex As Exception afferma che può gestire tutte le eccezioni - c'è un'eccezione (nessun gioco di parole).

Imports System
Static Sub StackOverflow() ' Again no pun intended
    StackOverflow()
End Sub
Static Sub Main()
    Try
        StackOverflow()
    Catch ex As Exception
        Console.WriteLine("Exception caught!")
    Finally
        Console.WriteLine("Finally block")
    End Try
End Sub

Oops ... C'è un System.StackOverflowException non catturato mentre la console non ha nemmeno stampato nulla! Secondo MSDN ,

A partire da .NET Framework 2.0, non è possibile catturare un oggetto StackOverflowException con un blocco try / catch e il processo corrispondente viene terminato per impostazione predefinita. Di conseguenza, dovresti scrivere il tuo codice per rilevare e prevenire un overflow dello stack.

Quindi, System.StackOverflowException non è catchable. Attenzione a quello!

Eccezioni critiche

Generalmente la maggior parte delle eccezioni non è così importante, ma ci sono alcune eccezioni davvero serie che potresti non essere in grado di gestire, come la famosa System.StackOverflowException . Tuttavia, ce ne sono altri che potrebbero essere nascosti da Catch ex As Exception , come System.OutOfMemoryException , System.BadImageFormatException e System.InvalidProgramException . È una buona pratica di programmazione lasciarli fuori se non riesci a gestirli correttamente. Per filtrare queste eccezioni, abbiamo bisogno di un metodo di supporto:

Public Shared Function IsCritical(ex As Exception) As Boolean
    Return TypeOf ex Is OutOfMemoryException OrElse
           TypeOf ex Is AppDomainUnloadedException OrElse
           TypeOf ex Is AccessViolationException OrElse
           TypeOf ex Is BadImageFormatException OrElse
           TypeOf ex Is CannotUnloadAppDomainException OrElse
           TypeOf ex Is ExecutionEngineException OrElse ' Obsolete one, but better to include
           TypeOf ex Is InvalidProgramException OrElse
           TypeOf ex Is System.Threading.ThreadAbortException
End Function

Uso:

Try
    SomeMethod()
Catch ex As Exception When Not IsCritical(ex)
    Console.WriteLine("Exception caught: " & ex.Message)
End Try