Visual Basic .NET Language
Foutafhandeling

Probeer ... Catch ... Eindelijk Statement

Structuur:

Try
    'Your program will try to run the code in this block.  
    'If any exceptions are thrown, the code in the Catch Block will be executed,
    'without executing the lines after the one which caused the exception.
Catch ex As System.IO.IOException
    'If an exception occurs when processing the Try block, each Catch statement
    'is examined in textual order to determine which handles the exception. 
    'For example, this Catch block handles an IOException.
Catch ex As Exception
    'This catch block handles all Exception types.
    'Details of the exception, in this case, are in the "ex" variable.
    'You can show the error in a MessageBox with the below line.
    MessageBox.Show(ex.Message)
Finally
    'A finally block is always executed, regardless of if an Exception occurred.
End Try

Voorbeeld code:

Try
    Dim obj = Nothing
    Dim prop = obj.Name 'This line will throw a NullReferenceException

    Console.WriteLine("Test.") ' This line will NOT be executed
Catch ex As System.IO.IOException
    ' Code that reacts to IOException.
Catch ex As NullReferenceException
    ' Code that reacts to a NullReferenceException
    Console.WriteLine("NullReferenceException: " & ex.Message)
    Console.WriteLine("Stack Trace: " & ex.StackTrace)
Catch ex As Exception
    ' Code that reacts to any other exception.
Finally   
    ' This will always be run, regardless of if an exception is thrown.
    Console.WriteLine("Completed")
End Try

Aangepaste uitzondering maken en gooien

U kunt een aangepaste uitzondering maken en deze gooien tijdens de uitvoering van uw functie. Als algemene praktijk moet u alleen een uitzondering maken als uw functie de gedefinieerde functionaliteit niet kon bereiken.

Private Function OpenDatabase(Byval Server as String, Byval User as String, Byval Pwd as String)
    if Server.trim="" then 
        Throw new Exception("Server Name cannot be blank")
    elseif User.trim ="" then 
        Throw new Exception("User name cannot be blank")
    elseif Pwd.trim="" then 
        Throw new Exception("Password cannot be blank")
    endif

    'Here add codes for connecting to the server
End function

Probeer Catch in databasebewerking

U kunt Try..Catch gebruiken om de database terug te draaien door de rollback-instructie in het vangstsegment te plaatsen.

    Try            
        'Do the database operation...        
        xCmd.CommandText = "INSERT into ...."
        xCmd.ExecuteNonQuery()

        objTrans.Commit()
        conn.Close()
    Catch ex As Exception 
        'Rollback action when something goes off           
        objTrans.Rollback()
        conn.Close()
    End Try

De onvangbare uitzondering

Hoewel Catch ex As Exception beweert dat het alle uitzonderingen aankan - er is één uitzondering (geen woordspeling bedoeld).

Imports System
Static Sub StackOverflow() ' Again no pun intended
    StackOverflow()
End Sub
Static Sub Main()
    Try
        StackOverflow()
    Catch ex As Exception
        Console.WriteLine("Exception caught!")
    Finally
        Console.WriteLine("Finally block")
    End Try
End Sub

Oeps ... Er is een niet-gevangen System.StackOverflowException terwijl de console zelfs niets heeft afgedrukt! Volgens MSDN

Te beginnen met .NET Framework 2.0 kunt u een StackOverflowException-object niet vangen met een try / catch-blok en wordt het bijbehorende proces standaard beëindigd. Daarom moet u uw code schrijven om een stapeloverloop te detecteren en te voorkomen.

Dus System.StackOverflowException is niet te vangen. Pas daar voor op!

Kritieke uitzonderingen

Over het algemeen zijn de meeste uitzonderingen niet zo belangrijk, maar er zijn enkele echt ernstige uitzonderingen die u misschien niet kunt verwerken, zoals het beroemde System.StackOverflowException . Er zijn echter anderen die mogelijk worden verborgen door Catch ex As Exception , zoals System.OutOfMemoryException , System.BadImageFormatException en System.InvalidProgramException . Het is een goede programmeerpraktijk om deze weg te laten als u ze niet correct kunt verwerken. Om deze uitzonderingen uit te filteren, hebben we een hulpmethode nodig:

Public Shared Function IsCritical(ex As Exception) As Boolean
    Return TypeOf ex Is OutOfMemoryException OrElse
           TypeOf ex Is AppDomainUnloadedException OrElse
           TypeOf ex Is AccessViolationException OrElse
           TypeOf ex Is BadImageFormatException OrElse
           TypeOf ex Is CannotUnloadAppDomainException OrElse
           TypeOf ex Is ExecutionEngineException OrElse ' Obsolete one, but better to include
           TypeOf ex Is InvalidProgramException OrElse
           TypeOf ex Is System.Threading.ThreadAbortException
End Function

Gebruik:

Try
    SomeMethod()
Catch ex As Exception When Not IsCritical(ex)
    Console.WriteLine("Exception caught: " & ex.Message)
End Try