Visual Basic .NET Language
Szyk

Uwagi

Dim myArray(2) As Integer

someFunc(myArray)

Definicja tablicy

Dim array(9) As Integer ' Defines an array variable with 10 Integer elements (0-9).

Dim array = New Integer(10) {} ' Defines an array variable with 11 Integer elements (0-10)
                               'using New.

Dim array As Integer() = {1, 2, 3, 4} ' Defines an Integer array variable and populate it
                                      'using an array literal. Populates the array with
                                      '4 elements.

ReDim Preserve array(10) ' Redefines the size of an existing array variable preserving any
                         'existing values in the array. The array will now have 11 Integer
                         'elements (0-10).

ReDim array(10) ' Redefines the size of an existing array variable discarding any
                'existing values in the array. The array will now have 11 Integer
                'elements (0-10).

Zero-Based

Wszystkie tablice w VB.NET są zerowane. Innymi słowy, indeks pierwszego elementu (dolna granica) w tablicy VB.NET wynosi zawsze 0 . Starsze wersje VB, takie jak VB6 i VBA, były domyślnie oparte na jednej, ale zapewniały sposób na przesłonięcie domyślnych granic. We wcześniejszych wersjach VB dolne i górne granice można wyraźnie określić (np. Dim array(5 To 10) . W VB.NET, aby zachować zgodność z innymi językami .NET, elastyczność ta została usunięta, a dolna granica od teraz jest zawsze wymuszane 0 Jednak w VB.NET nadal można używać składni To , co może wyraźnie zwiększyć zakres. Na przykład poniższe przykłady są równoważne z powyższymi:

Dim array(0 To 9) As Integer

Dim array = New Integer(0 To 10) {} 

ReDim Preserve array(0 To 10)

ReDim array(0 To 10)

Deklaracje zagnieżdżonych tablic

Dim myArray = {{1, 2}, {3, 4}}

Zadeklaruj tablicę jednowymiarową i ustaw wartości elementów tablicy

Dim array = New Integer() {1, 2, 3, 4}

lub

Dim array As Int32() = {1, 2, 3, 4}

Inicjalizacja tablicy

Dim array() As Integer = {2, 0, 1, 6}                   ''Initialize an array of four Integers.
Dim strings() As String = {"this", "is", "an", "array"} ''Initialize an array of four Strings.
Dim floats() As Single = {56.2, 55.633, 1.2, 5.7743, 22.345}
              ''Initialize an array of five Singles, which are the same as floats in C#.
Dim miscellaneous() as Object = { New Object(), "Hello", New List(of String) }
              ''Initialize an array of three references to any reference type objects
              ''and point them to objects of three different types.

Inicjalizacja tablicy wielowymiarowej

Dim array2D(,) As Integer = {{1, 2, 3}, {4, 5, 6}}
' array2D(0, 0) is 1 ; array2D(0, 1) is 2 ; array2D(1, 0) is 4

Dim array3D(,,) As Integer = {{{1, 2, 3}, {4, 5, 6}}, {{7, 8, 9}, {10, 11, 12}}}
' array3D(0, 0, 0) is 1 ; array3D(0, 0, 1) is 2
' array3D(0, 1, 0) is 4 ; array3D(1, 0, 0) is 7

Inicjalizacja Jagged Array

Zwróć uwagę na nawias, aby odróżnić tablicę postrzępioną od tablicy wielowymiarowej Tablice podrzędne mogą mieć różną długość

Dim jaggedArray()() As Integer = { ({1, 2, 3}), ({4, 5, 6}), ({7}) }
' jaggedArray(0) is {1, 2, 3} and so jaggedArray(0)(0) is 1
' jaggedArray(1) is {4, 5, 6} and so jaggedArray(1)(0) is 4
' jaggedArray(2) is {7} and so jaggedArray(2)(0) is 7

Zmienne tablic zerowych

Ponieważ tablice są typami referencyjnymi, zmienna tablicowa może mieć wartość NULL. Aby zadeklarować zmienną tablicę zerową, musisz zadeklarować ją bez rozmiaru:

Dim array() As Integer

Lub

Dim array As Integer()

Aby sprawdzić, czy tablica jest pusta, sprawdź, czy nie Is Nothing :

Dim array() As Integer
If array Is Nothing Then
    array = {1, 2, 3}
End If

Aby ustawić istniejącą zmienną tablicową na null, po prostu ustaw ją na Nothing :

Dim array() As Integer = {1, 2, 3}
array = Nothing
Console.WriteLine(array(0))  ' Throws a NullReferenceException

Lub użyj Erase , który robi to samo:

Dim array() As Integer = {1, 2, 3}
Erase array
Console.WriteLine(array(0))  ' Throws a NullReferenceException

Odwoływanie się do tej samej tablicy z dwóch zmiennych

Ponieważ tablice są typami referencyjnymi, możliwe jest posiadanie wielu zmiennych wskazujących na ten sam obiekt tablicy.

Dim array1() As Integer = {1, 2, 3}
Dim array2() As Integer = array1
array1(0) = 4
Console.WriteLine(String.Join(", ", array2))  ' Writes "4, 2, 3"

Niezerowe dolne granice

Przy Option Strict On , chociaż .NET Framework pozwala na tworzenie tablic jednowymiarowych z niezerowymi dolnymi granicami, nie są one „wektorami” i dlatego nie są kompatybilne z tablicami typu VB.NET. Oznacza to, że można je postrzegać tylko jako Array a zatem nie mogą używać normalnych odwołań do tablicy (index) .

Dim a As Array = Array.CreateInstance(GetType(Integer), {4}, {-1})
For y = LBound(a) To UBound(a)
    a.SetValue(y * y, y)
Next
For y = LBound(a) To UBound(a)
    Console.WriteLine($"{y}: {a.GetValue(y)}")
Next

Oprócz użycia Option Strict Off możesz odzyskać składnię (index) , traktując tablicę jako IList , ale wtedy nie jest to tablica, więc nie możesz używać LBound i UBound dla tej nazwy zmiennej (i możesz nadal nie unikam boksu):

Dim nsz As IList = a
For y = LBound(a) To UBound(a)
    nsz(y) = 2 - CInt(nsz(y))
Next
For y = LBound(a) To UBound(a)
    Console.WriteLine($"{y}: {nsz(y)}")
Next

Wielowymiarowe niezerowe dolne tablice ograniczone są kompatybilne z wielowymiarowymi tablicami typowymi VB.NET:

Dim nza(,) As Integer = DirectCast(Array.CreateInstance(GetType(Integer),
                                   {4, 3}, {1, -1}), Integer(,))
For y = LBound(nza) To UBound(nza)
    For w = LBound(nza, 2) To UBound(nza, 2)
        nza(y, w) = -y * w + nza(UBound(nza) - y + LBound(nza),
                                 UBound(nza, 2) - w + LBound(nza, 2))
    Next
Next
For y = LBound(nza) To UBound(nza)
    Dim ly = y
    Console.WriteLine(String.Join(" ",
        Enumerable.Repeat(ly & ":", 1).Concat(
            Enumerable.Range(LBound(nza, 2), UBound(nza, 2) - LBound(nza, 2) + 1) _
            .Select(Function(w) CStr(nza(ly, w))))))
Next

Odwołanie MSDN: Array.CreateInstance