Visual Basic .NET Language
Felhantering

Försök ... Fånga ... Slutligen uttalande

Strukturera:

Try
    'Your program will try to run the code in this block.  
    'If any exceptions are thrown, the code in the Catch Block will be executed,
    'without executing the lines after the one which caused the exception.
Catch ex As System.IO.IOException
    'If an exception occurs when processing the Try block, each Catch statement
    'is examined in textual order to determine which handles the exception. 
    'For example, this Catch block handles an IOException.
Catch ex As Exception
    'This catch block handles all Exception types.
    'Details of the exception, in this case, are in the "ex" variable.
    'You can show the error in a MessageBox with the below line.
    MessageBox.Show(ex.Message)
Finally
    'A finally block is always executed, regardless of if an Exception occurred.
End Try

Exempel kod:

Try
    Dim obj = Nothing
    Dim prop = obj.Name 'This line will throw a NullReferenceException

    Console.WriteLine("Test.") ' This line will NOT be executed
Catch ex As System.IO.IOException
    ' Code that reacts to IOException.
Catch ex As NullReferenceException
    ' Code that reacts to a NullReferenceException
    Console.WriteLine("NullReferenceException: " & ex.Message)
    Console.WriteLine("Stack Trace: " & ex.StackTrace)
Catch ex As Exception
    ' Code that reacts to any other exception.
Finally   
    ' This will always be run, regardless of if an exception is thrown.
    Console.WriteLine("Completed")
End Try

Skapa anpassat undantag och kasta

Du kan skapa ett anpassat undantag och kasta dem under körningen av din funktion. Som allmän praxis bör du bara kasta ett undantag när din funktion inte kunde uppnå sin definierade funktionalitet.

Private Function OpenDatabase(Byval Server as String, Byval User as String, Byval Pwd as String)
    if Server.trim="" then 
        Throw new Exception("Server Name cannot be blank")
    elseif User.trim ="" then 
        Throw new Exception("User name cannot be blank")
    elseif Pwd.trim="" then 
        Throw new Exception("Password cannot be blank")
    endif

    'Here add codes for connecting to the server
End function

Försök Fånga i databasdrift

Du kan använda Try..Catch för att återföra databasåtgärder genom att placera rollback-uttalandet vid fångstsegmentet.

    Try            
        'Do the database operation...        
        xCmd.CommandText = "INSERT into ...."
        xCmd.ExecuteNonQuery()

        objTrans.Commit()
        conn.Close()
    Catch ex As Exception 
        'Rollback action when something goes off           
        objTrans.Rollback()
        conn.Close()
    End Try

Det oupptagbara undantaget

Även om Catch ex As Exception påstår att den kan hantera alla undantag - finns det ett undantag (ingen ordlista avsedd).

Imports System
Static Sub StackOverflow() ' Again no pun intended
    StackOverflow()
End Sub
Static Sub Main()
    Try
        StackOverflow()
    Catch ex As Exception
        Console.WriteLine("Exception caught!")
    Finally
        Console.WriteLine("Finally block")
    End Try
End Sub

Oj ... Det finns ett System.StackOverflowException medan konsolen inte ens skrev ut någonting! Enligt MSDN

Från .NET Framework 2.0 kan du inte fånga ett StackOverflowException-objekt med ett try / catch-block, och motsvarande process avslutas som standard. Följaktligen bör du skriva din kod för att upptäcka och förhindra ett stacköverskridande.

Så System.StackOverflowException är oupphämtningsbar. Se upp för det!

Kritiska undantag

Generellt sett är de flesta undantag inte så kritiska, men det finns några riktigt allvarliga undantag som du kanske inte kan hantera, till exempel den berömda System.StackOverflowException . Det finns dock andra som kan döljas av Catch ex As Exception , till exempel System.OutOfMemoryException , System.BadImageFormatException och System.InvalidProgramException . Det är en bra programmeringspraxis att lämna dessa ut om du inte kan hantera dem korrekt. För att filtrera bort dessa undantag behöver vi en hjälpmetod:

Public Shared Function IsCritical(ex As Exception) As Boolean
    Return TypeOf ex Is OutOfMemoryException OrElse
           TypeOf ex Is AppDomainUnloadedException OrElse
           TypeOf ex Is AccessViolationException OrElse
           TypeOf ex Is BadImageFormatException OrElse
           TypeOf ex Is CannotUnloadAppDomainException OrElse
           TypeOf ex Is ExecutionEngineException OrElse ' Obsolete one, but better to include
           TypeOf ex Is InvalidProgramException OrElse
           TypeOf ex Is System.Threading.ThreadAbortException
End Function

Användande:

Try
    SomeMethod()
Catch ex As Exception When Not IsCritical(ex)
    Console.WriteLine("Exception caught: " & ex.Message)
End Try