VBA
Arrays

Declarando un Array en VBA

Declarar una matriz es muy similar a declarar una variable, excepto que necesita declarar la dimensión de la Matriz justo después de su nombre:

Dim myArray(9) As String 'Declaring an array that will contain up to 10 strings

De forma predeterminada, las matrices en VBA se indexan desde CERO , por lo tanto, el número dentro del paréntesis no se refiere al tamaño de la matriz, sino al índice del último elemento

Elementos de acceso

El acceso a un elemento de la matriz se realiza utilizando el nombre de la matriz, seguido del índice del elemento, entre paréntesis:

myArray(0) = "first element"
myArray(5) = "sixth element"
myArray(9) = "last element"

Indexación de matrices

Puede cambiar la indexación de Arrays colocando esta línea en la parte superior de un módulo:

Option Base 1

Con esta línea, todos los Arrays declarados en el módulo serán indexados desde UNO .

Índice especifico

También puede declarar cada Array con su propio índice usando la palabra clave To , y el límite inferior y superior (= índice):

Dim mySecondArray(1 To 12) As String 'Array of 12 strings indexed from 1 to 12
Dim myThirdArray(13 To 24) As String 'Array of 12 strings indexed from 13 to 24

Declaración dinámica

Cuando no conoce el tamaño de su Array antes de su declaración, puede usar la declaración dinámica y la palabra clave ReDim :

Dim myDynamicArray() As Strings 'Creates an Array of an unknown number of strings
ReDim myDynamicArray(5) 'This resets the array to 6 elements

Tenga en cuenta que el uso de la palabra clave ReDim eliminará cualquier contenido anterior de su Array. Para evitar esto, puede usar la palabra clave Preserve después de ReDim :

Dim myDynamicArray(5) As String
myDynamicArray(0) = "Something I want to keep"

ReDim Preserve myDynamicArray(8) 'Expand the size to up to 9 strings
Debug.Print myDynamicArray(0) ' still prints the element

Uso de Split para crear una matriz a partir de una cadena

Función de división

devuelve una matriz unidimensional basada en cero que contiene un número específico de subcadenas.

Sintaxis

División (expresión [, delimitador [, límite [, comparar ]]] )

Ajustes

El argumento de comparación puede tener los siguientes valores:

Ejemplo

En este ejemplo se muestra cómo funciona la división mostrando varios estilos. Los comentarios mostrarán el conjunto de resultados para cada una de las diferentes opciones de división realizadas. Finalmente, se demuestra cómo recorrer la matriz de cadena devuelta.

Sub Test
    
    Dim textArray() as String

    textArray = Split("Tech on the Net")
    'Result: {"Tech", "on", "the", "Net"}

    textArray = Split("172.23.56.4", ".")
    'Result: {"172", "23", "56", "4"}

    textArray = Split("A;B;C;D", ";")
    'Result: {"A", "B", "C", "D"}

    textArray = Split("A;B;C;D", ";", 1)
    'Result: {"A;B;C;D"}

    textArray = Split("A;B;C;D", ";", 2)
    'Result: {"A", "B;C;D"}

    textArray = Split("A;B;C;D", ";", 3)
    'Result: {"A", "B", "C;D"}

    textArray = Split("A;B;C;D", ";", 4)
    'Result: {"A", "B", "C", "D"}

    'You can iterate over the created array
    Dim counter As Long

    For counter = LBound(textArray) To UBound(textArray)
        Debug.Print textArray(counter)
    Next
 End Sub

Iterando elementos de una matriz

Para ... siguiente

Usar la variable iterador como el número de índice es la forma más rápida de iterar los elementos de una matriz:

Dim items As Variant
items = Array(0, 1, 2, 3)

Dim index As Integer
For index = LBound(items) To UBound(items)
    'assumes value can be implicitly converted to a String:
    Debug.Print items(index) 
Next

Los bucles anidados se pueden usar para iterar matrices multidimensionales:

Dim items(0 To 1, 0 To 1) As Integer
items(0, 0) = 0
items(0, 1) = 1
items(1, 0) = 2
items(1, 1) = 3

Dim outer As Integer
Dim inner As Integer
For outer = LBound(items, 1) To UBound(items, 1)
    For inner = LBound(items, 2) To UBound(items, 2)
        'assumes value can be implicitly converted to a String:
        Debug.Print items(outer, inner)
    Next
Next

Para cada ... siguiente

A For Each...Next loop también se puede utilizar para iterar matrices, si el rendimiento no importa:

Dim items As Variant
items = Array(0, 1, 2, 3)

Dim item As Variant 'must be variant
For Each item In items
    'assumes value can be implicitly converted to a String:
    Debug.Print item
Next

A For Each loop iterará todas las dimensiones de exterior a interno (el mismo orden que los elementos están en la memoria), por lo que no hay necesidad de bucles anidados:

Dim items(0 To 1, 0 To 1) As Integer
items(0, 0) = 0
items(1, 0) = 1
items(0, 1) = 2
items(1, 1) = 3

Dim item As Variant 'must be Variant
For Each item In items
    'assumes value can be implicitly converted to a String:
    Debug.Print item
Next

Tenga en cuenta que los bucles For Each se utilizan mejor para iterar objetos de la Collection , si el rendimiento es importante.

Los 4 fragmentos anteriores producen el mismo resultado:

 0
 1
 2
 3

Arreglos dinámicos (cambio de tamaño de matriz y manejo dinámico)

Arrays dinámicos

Agregar y reducir dinámicamente las variables en una matriz es una gran ventaja para cuando la información que está tratando no tiene un número determinado de variables.

Agregando valores dinámicamente

Simplemente puede cambiar el tamaño de la matriz con la declaración ReDim , esto cambiará el tamaño de la matriz, pero si desea conservar la información ya almacenada en la matriz, necesitará la parte Preserve .

En el siguiente ejemplo, creamos una matriz y la aumentamos en una variable más en cada iteración, a la vez que conservamos los valores que ya se encuentran en la matriz.

Dim Dynamic_array As Variant
' first we set Dynamic_array as variant

For n = 1 To 100

    If IsEmpty(Dynamic_array) Then
        'isempty() will check if we need to add the first value to the array or subsequent ones
    
        ReDim Dynamic_array(0)
        'ReDim Dynamic_array(0) will resize the array to one variable only
        Dynamic_array(0) = n

    Else
        ReDim Preserve Dynamic_array(0 To UBound(Dynamic_array) + 1)
        'in the line above we resize the array from variable 0 to the UBound() = last variable, plus one effectivelly increeasing the size of the array by one
        Dynamic_array(UBound(Dynamic_array)) = n
        'attribute a value to the last variable of Dynamic_array
    End If

Next

Eliminar valores dinámicamente

Podemos utilizar la misma lógica para disminuir la matriz. En el ejemplo, el valor "último" se eliminará de la matriz.

Dim Dynamic_array As Variant
Dynamic_array = Array("first", "middle", "last")
    
ReDim Preserve Dynamic_array(0 To UBound(Dynamic_array) - 1)
' Resize Preserve while dropping the last value

Restablecimiento de una matriz y reutilización dinámica

También podemos reutilizar los arreglos que creamos para no tener muchos en la memoria, lo que haría más lento el tiempo de ejecución. Esto es útil para matrices de varios tamaños. Un fragmento de código que podría utilizar para reutilizar la matriz es volver a ReDim la matriz a (0) , atribuir una variable a la matriz y volver a aumentar la matriz libremente.

En el siguiente fragmento, construyo una matriz con los valores de 1 a 40, vacío la matriz y la recargo con los valores de 40 a 100, todo esto se hace de forma dinámica.

Dim Dynamic_array As Variant

For n = 1 To 100

    If IsEmpty(Dynamic_array) Then
        ReDim Dynamic_array(0)
        Dynamic_array(0) = n
    
    ElseIf Dynamic_array(0) = "" Then
        'if first variant is empty ( = "") then give it the value of n
        Dynamic_array(0) = n
    Else
        ReDim Preserve Dynamic_array(0 To UBound(Dynamic_array) + 1)
        Dynamic_array(UBound(Dynamic_array)) = n
    End If
    If n = 40 Then
        ReDim Dynamic_array(0)
        'Resizing the array back to one variable without Preserving,
        'leaving the first value of the array empty
    End If

Next

Arreglos irregulares (Arrays of Arrays)

Matrices dentadas NO matrices multidimensionales

Las matrices de matrices (matrices irregulares) no son lo mismo que las matrices multidimensionales si las piensa visualmente Las matrices multidimensionales se verían como matrices (rectangulares) con un número definido de elementos en sus dimensiones (matrices internas), mientras que la matriz dentada sería como una anual Calendario con las matrices internas que tienen un número diferente de elementos, como días en diferentes meses.

Aunque los Arreglos Jagged son bastante complicados y difíciles de usar debido a sus niveles anidados y no tienen muchos tipos de seguridad, pero son muy flexibles, le permiten manipular diferentes tipos de datos con bastante facilidad y no necesitan contener datos no utilizados o elementos vacios.

Creación de una matriz irregular

En el siguiente ejemplo, iniciaremos una matriz dentada que contiene dos matrices, una para Nombres y otra para Números, y luego accederemos a un elemento de cada una.

Dim OuterArray() As Variant
Dim Names() As Variant
Dim Numbers() As Variant
'arrays are declared variant so we can access attribute any data type to its elements

Names = Array("Person1", "Person2", "Person3")
Numbers = Array("001", "002", "003")

OuterArray = Array(Names, Numbers)
'Directly giving OuterArray an array containing both Names and Numbers arrays inside

Debug.Print OuterArray(0)(1)
Debug.Print OuterArray(1)(1)
'accessing elements inside the jagged by giving the coordenades of the element

Creación y lectura dinámica de matrices dentadas

También podemos ser más dinámicos en nuestro tiempo aproximado para construir los arreglos, imaginemos que tenemos una hoja de datos del cliente en Excel y queremos construir un arreglo para generar los detalles del cliente.

   Name -   Phone   -  Email  - Customer Number 
Person1 - 153486231 - 1@STACK - 001
Person2 - 153486242 - 2@STACK - 002
Person3 - 153486253 - 3@STACK - 003
Person4 - 153486264 - 4@STACK - 004
Person5 - 153486275 - 5@STACK - 005

Construiremos dinámicamente una matriz de encabezado y una matriz de clientes, el encabezado contendrá los títulos de columna y la matriz de clientes contendrá la información de cada cliente / fila como matrices.

Dim Headers As Variant
' headers array with the top section of the customer data sheet
    For c = 1 To 4
        If IsEmpty(Headers) Then
            ReDim Headers(0)
            Headers(0) = Cells(1, c).Value
        Else
            ReDim Preserve Headers(0 To UBound(Headers) + 1)
            Headers(UBound(Headers)) = Cells(1, c).Value
        End If
    Next
    
Dim Customers As Variant
'Customers array will contain arrays of customer values
Dim Customer_Values As Variant
'Customer_Values will be an array of the customer in its elements (Name-Phone-Email-CustNum)
    
    For r = 2 To 6
    'iterate through the customers/rows
        For c = 1 To 4
        'iterate through the values/columns
            
            'build array containing customer values
            If IsEmpty(Customer_Values) Then
                ReDim Customer_Values(0)
                Customer_Values(0) = Cells(r, c).Value
            ElseIf Customer_Values(0) = "" Then
                Customer_Values(0) = Cells(r, c).Value
            Else
                ReDim Preserve Customer_Values(0 To UBound(Customer_Values) + 1)
                Customer_Values(UBound(Customer_Values)) = Cells(r, c).Value
            End If
        Next
        
        'add customer_values array to Customers Array
        If IsEmpty(Customers) Then
            ReDim Customers(0)
            Customers(0) = Customer_Values
        Else
            ReDim Preserve Customers(0 To UBound(Customers) + 1)
            Customers(UBound(Customers)) = Customer_Values
        End If
        
        'reset Custumer_Values to rebuild a new array if needed
        ReDim Customer_Values(0)
    Next

    Dim Main_Array(0 To 1) As Variant
    'main array will contain both the Headers and Customers
    
    Main_Array(0) = Headers
    Main_Array(1) = Customers

To better understand the way to Dynamically construct a one dimensional array please check Dynamic Arrays (Array Resizing and Dynamic Handling) on the Arrays documentation.

El resultado del fragmento de código anterior es una matriz dentada con dos matrices, una de esas matrices con 4 elementos, 2 niveles de sangría y la otra es otra matriz dentada que contiene 5 matrices de 4 elementos cada una y 3 niveles de sangría, vea a continuación la estructura:

Main_Array(0) - Headers - Array("Name","Phone","Email","Customer Number")
          (1) - Customers(0) - Array("Person1",153486231,"1@STACK",001)
                Customers(1) - Array("Person2",153486242,"2@STACK",002)
                ...
                Customers(4) - Array("Person5",153486275,"5@STACK",005)

Para acceder a la información, deberá tener en cuenta la estructura de la matriz irregular que cree, en el ejemplo anterior puede ver que la Main Array contiene una matriz de Headers y una matriz de matrices ( Customers ), por lo tanto, con diferentes formas de Accediendo a los elementos.

Ahora leeremos la información de la Main Array e imprimiremos cada información de los clientes como Info Type: Info .

For n = 0 To UBound(Main_Array(1))
    'n to iterate from fisrt to last array in Main_Array(1)
    
    For j = 0 To UBound(Main_Array(1)(n))
        'j will iterate from first to last element in each array of Main_Array(1)
        
        Debug.Print Main_Array(0)(j) & ": " & Main_Array(1)(n)(j)
        'print Main_Array(0)(j) which is the header and Main_Array(0)(n)(j) which is the element in the customer array
        'we can call the header with j as the header array has the same structure as the customer array
    Next
Next

RECUERDE para hacer un seguimiento de la estructura de su Jagged Array, en el ejemplo anterior para acceder al nombre de un cliente es accediendo a Main_Array -> Customers -> CustomerNumber -> Name que es de tres niveles, para devolver "Person4" que necesitará la ubicación de los Clientes en Main_Array, luego la Ubicación del cliente cuatro en la matriz Jagged Clientes y por último la ubicación del elemento que necesita, en este caso Main_Array(1)(3)(0) que es Main_Array(Customers)(CustomerNumber)(Name) .

Arreglos Multidimensionales

Arreglos Multidimensionales

Como su nombre lo indica, las matrices multidimensionales son matrices que contienen más de una dimensión, generalmente dos o tres, pero pueden tener hasta 32 dimensiones.

Una matriz múltiple funciona como una matriz con varios niveles, tome como ejemplo una comparación entre una, dos y tres dimensiones.

One Dimension es su matriz típica, parece una lista de elementos.

Dim 1D(3) as Variant

*1D - Visually*
(0)
(1)
(2)

Two Dimensions se vería como una cuadrícula de Sudoku o una hoja de Excel. Al inicializar la matriz, definiría cuántas filas y columnas tendría la matriz.

Dim 2D(3,3) as Variant
'this would result in a 3x3 grid 

*2D - Visually*
(0,0) (0,1) (0,2)
(1,0) (1,1) (1,2)
(2,0) (2,1) (2,2)

Three Dimensions comenzaría a parecerse al Cubo de Rubik, al inicializar la matriz, definiría filas y columnas y las capas / profundidades que tendría la matriz.

Dim 3D(3,3,2) as Variant
'this would result in a 3x3x3 grid

*3D - Visually*
       1st layer                 2nd layer                  3rd layer
         front                     middle                     back
(0,0,0) (0,0,1) (0,0,2) ¦ (1,0,0) (1,0,1) (1,0,2) ¦ (2,0,0) (2,0,1) (2,0,2)
(0,1,0) (0,1,1) (0,1,2) ¦ (1,1,0) (1,1,1) (1,1,2) ¦ (2,1,0) (2,1,1) (2,1,2)
(0,2,0) (0,2,1) (0,2,2) ¦ (1,2,0) (1,2,1) (1,2,2) ¦ (2,2,0) (2,2,1) (2,2,2)

Otras dimensiones podrían pensarse como la multiplicación de la 3D, por lo que una 4D (1,3,3,3) sería dos matrices 3D de lado a lado.

Array de dos dimensiones

Creando

El siguiente ejemplo será una compilación de una lista de empleados, cada empleado tendrá un conjunto de información en la lista (Nombre, Apellido, Dirección, Correo electrónico, Teléfono ...), el ejemplo esencialmente se almacenará en la matriz ( empleado, información) siendo el (0,0) es el primer nombre del primer empleado.

Dim Bosses As Variant
'set bosses as Variant, so we can input any data type we want

Bosses = [{"Jonh","Snow","President";"Ygritte","Wild","Vice-President"}]
'initialise a 2D array directly by filling it with information, the redult wil be a array(1,2) size 2x3 = 6 elements

Dim Employees As Variant
'initialize your Employees array as variant
'initialize and ReDim the Employee array so it is a dynamic array instead of a static one, hence treated differently by the VBA Compiler
ReDim Employees(100, 5)
'declaring an 2D array that can store 100 employees with 6 elements of information each, but starts empty
'the array size is 101 x 6 and contains 606 elements

For employee = 0 To UBound(Employees, 1)
'for each employee/row in the array, UBound for 2D arrays, which will get the last element on the array
'needs two parameters 1st the array you which to check and 2nd the dimension, in this case 1 = employee and 2 = information
    For information_e = 0 To UBound(Employees, 2)
    'for each information element/column in the array
        
        Employees(employee, information_e) = InformationNeeded ' InformationNeeded would be the data to fill the array
        'iterating the full array will allow for direct attribution of information into the element coordinates
    Next
Next

Redimensionamiento

Cambiar el tamaño o ReDim Preserve una Multi-Array como la norma para una matriz de One-Dimension obtendría un error, en lugar de eso, la información debe transferirse a una matriz Temporal con el mismo tamaño que el original más el número de filas / columnas para agregar. En el siguiente ejemplo, veremos cómo inicializar una matriz temporal, transferir la información de la matriz original, llenar los elementos vacíos restantes y reemplazar la matriz temporal por la matriz original.

Dim TempEmp As Variant
'initialise your temp array as variant
ReDim TempEmp(UBound(Employees, 1) + 1, UBound(Employees, 2))
'ReDim/Resize Temp array as a 2D array with size UBound(Employees)+1 = (last element in Employees 1st dimension) + 1,
'the 2nd dimension remains the same as the original array. we effectively add 1 row in the Employee array

'transfer
For emp = LBound(Employees, 1) To UBound(Employees, 1)
    For info = LBound(Employees, 2) To UBound(Employees, 2)
        'to transfer Employees into TempEmp we iterate both arrays and fill TempEmp with the corresponding element value in Employees
        TempEmp(emp, info) = Employees(emp, info)
    
    Next
Next

'fill remaining
'after the transfers the Temp array still has unused elements at the end, being that it was increased
'to fill the remaining elements iterate from the last "row" with values to the last row in the array
'in this case the last row in Temp will be the size of the Employees array rows + 1, as the last row of Employees array is already filled in the TempArray

For emp = UBound(Employees, 1) + 1 To UBound(TempEmp, 1)
    For info = LBound(TempEmp, 2) To UBound(TempEmp, 2)
        
        TempEmp(emp, info) = InformationNeeded & "NewRow"
    
    Next
Next

'erase Employees, attribute Temp array to Employees and erase Temp array
Erase Employees
Employees = TempEmp
Erase TempEmp

Cambiar los valores de los elementos

Para cambiar / alterar los valores en un elemento determinado se puede hacer simplemente llamando a la coordenada para cambiar y dándole un nuevo valor: Employees(0, 0) = "NewValue"

Alternativamente, iterar a través de las coordenadas usa las condiciones para hacer coincidir los valores correspondientes a los parámetros necesarios:

For emp = 0 To UBound(Employees)
    If Employees(emp, 0) = "Gloria" And Employees(emp, 1) = "Stephan" Then
    'if value found
        Employees(emp, 1) = "Married, Last Name Change"
        Exit For
        'don't iterate through a full array unless necessary
    End If
Next

Leyendo

El acceso a los elementos de la matriz se puede hacer con un bucle anidado (iterando cada elemento), Loop y Coordenadas (iterar filas y acceder a columnas directamente), o acceder directamente con ambas coordenadas.

'nested loop, will iterate through all elements
For emp = LBound(Employees, 1) To UBound(Employees, 1)
    For info = LBound(Employees, 2) To UBound(Employees, 2)
        Debug.Print Employees(emp, info)
    Next
Next

'loop and coordinate, iteration through all rows and in each row accessing all columns directly
For emp = LBound(Employees, 1) To UBound(Employees, 1)
    Debug.Print Employees(emp, 0)
    Debug.Print Employees(emp, 1)
    Debug.Print Employees(emp, 2)
    Debug.Print Employees(emp, 3)
    Debug.Print Employees(emp, 4)
    Debug.Print Employees(emp, 5)
Next

'directly accessing element with coordinates
Debug.Print Employees(5, 5)

Recuerde , siempre es útil mantener un mapa de matriz cuando se usan matrices multidimensionales, ya que pueden convertirse fácilmente en confusión.

Array de tres dimensiones

Para la matriz 3D, usaremos la misma premisa que la matriz 2D, con la adición de no solo almacenar el empleado y la información, sino también la construcción en la que trabajan.

La matriz 3D tendrá los Empleados (se pueden considerar como Filas), la Información (Columnas) y la Construcción que se pueden considerar como hojas diferentes en un documento de Excel, tienen el mismo tamaño entre ellas, pero cada hoja tiene un Diferentes conjuntos de información en sus celdas / elementos. La matriz 3D contendrá n número de matrices 2D.

Creando

Una matriz 3D necesita 3 coordenadas para ser inicializada Dim 3Darray(2,5,5) As Variant la primera coordenada en la matriz será el número de Building / Sheets (diferentes conjuntos de filas y columnas), la segunda coordenada definirá Rows y la tercera Columnas La Dim arriba dará como resultado una matriz 3D con 108 elementos ( 3*6*6 ), que tendrá efectivamente 3 conjuntos diferentes de matrices 2D.

Dim ThreeDArray As Variant
'initialise your ThreeDArray array as variant
ReDim ThreeDArray(1, 50, 5)
'declaring an 3D array that can store two sets of 51 employees with 6 elements of information each, but starts empty
'the array size is 2 x 51 x 6 and contains 612 elements

For building = 0 To UBound(ThreeDArray, 1)
    'for each building/set in the array
    For employee = 0 To UBound(ThreeDArray, 2)
    'for each employee/row in the array
        For information_e = 0 To UBound(ThreeDArray, 3)
        'for each information element/column in the array
            
            ThreeDArray(building, employee, information_e) = InformationNeeded ' InformationNeeded would be the data to fill the array
        'iterating the full array will allow for direct attribution of information into the element coordinates
        Next
    Next
Next

Redimensionamiento

Cambiar el tamaño de una matriz 3D es similar a cambiar el tamaño de una 2D, primero cree una matriz temporal con el mismo tamaño del original agregando una en la coordenada del parámetro para aumentar, la primera coordenada aumentará el número de conjuntos en la matriz, la segunda y Las terceras coordenadas aumentarán el número de filas o columnas en cada conjunto.

El siguiente ejemplo aumenta la cantidad de Filas en cada conjunto en uno, y llena los nuevos elementos agregados con nueva información.

Dim TempEmp As Variant
'initialise your temp array as variant
ReDim TempEmp(UBound(ThreeDArray, 1), UBound(ThreeDArray, 2) + 1, UBound(ThreeDArray, 3))
'ReDim/Resize Temp array as a 3D array with size UBound(ThreeDArray)+1 = (last element in Employees 2nd dimension) + 1,
'the other dimension remains the same as the original array. we effectively add 1 row in the for each set of the 3D array

'transfer
For building = LBound(ThreeDArray, 1) To UBound(ThreeDArray, 1)
    For emp = LBound(ThreeDArray, 2) To UBound(ThreeDArray, 2)
        For info = LBound(ThreeDArray, 3) To UBound(ThreeDArray, 3)
            'to transfer ThreeDArray into TempEmp by iterating all sets in the 3D array and fill TempEmp with the corresponding element value in each set of each row
            TempEmp(building, emp, info) = ThreeDArray(building, emp, info)
        
        Next
    Next
Next

'fill remaining
'to fill the remaining elements we need to iterate from the last "row" with values to the last row in the array in each set, remember that the first empty element is the original array Ubound() plus 1
For building = LBound(TempEmp, 1) To UBound(TempEmp, 1)
    For emp = UBound(ThreeDArray, 2) + 1 To UBound(TempEmp, 2)
        For info = LBound(TempEmp, 3) To UBound(TempEmp, 3)
            
            TempEmp(building, emp, info) = InformationNeeded & "NewRow"
        
        Next
    Next
Next

'erase Employees, attribute Temp array to Employees and erase Temp array
Erase ThreeDArray
ThreeDArray = TempEmp
Erase TempEmp

Cambio de valores de elementos y lectura

La lectura y el cambio de los elementos en la matriz 3D se pueden hacer de manera similar a la forma en que hacemos la matriz 2D, simplemente ajuste el nivel adicional en los bucles y coordenadas.

Do
' using Do ... While for early exit
    For building = 0 To UBound(ThreeDArray, 1)
        For emp = 0 To UBound(ThreeDArray, 2)
            If ThreeDArray(building, emp, 0) = "Gloria" And ThreeDArray(building, emp, 1) = "Stephan" Then
            'if value found
                ThreeDArray(building, emp, 1) = "Married, Last Name Change"
                Exit Do
                'don't iterate through all the array unless necessary
            End If
        Next
    Next
Loop While False

'nested loop, will iterate through all elements
For building = LBound(ThreeDArray, 1) To UBound(ThreeDArray, 1)
    For emp = LBound(ThreeDArray, 2) To UBound(ThreeDArray, 2)
        For info = LBound(ThreeDArray, 3) To UBound(ThreeDArray, 3)
            Debug.Print ThreeDArray(building, emp, info)
        Next
    Next
Next

'loop and coordinate, will iterate through all set of rows and ask for the row plus the value we choose for the columns
For building = LBound(ThreeDArray, 1) To UBound(ThreeDArray, 1)
    For emp = LBound(ThreeDArray, 2) To UBound(ThreeDArray, 2)
        Debug.Print ThreeDArray(building, emp, 0)
        Debug.Print ThreeDArray(building, emp, 1)
        Debug.Print ThreeDArray(building, emp, 2)
        Debug.Print ThreeDArray(building, emp, 3)
        Debug.Print ThreeDArray(building, emp, 4)
        Debug.Print ThreeDArray(building, emp, 5)
    Next
Next

'directly accessing element with coordinates
Debug.Print Employees(0, 5, 5)