VBA
arrayer

Förklara en array i VBA

Att förklara en matris liknar mycket att förklara en variabel, förutom att du behöver förklara dimensionen på arrayen direkt efter dess namn:

Dim myArray(9) As String 'Declaring an array that will contain up to 10 strings

Som standard indexeras Arrays i VBA från ZERO , vilket betyder att antalet inuti parentesen inte avser storleken på matrisen utan snarare till indexet för det sista elementet

Åtkomst till element

Åtkomst till ett element i Array görs genom att använda namnet på Array, följt av indexet för elementet, inom parentes:

myArray(0) = "first element"
myArray(5) = "sixth element"
myArray(9) = "last element"

Arrayindexering

Du kan ändra Arrays-indexering genom att placera den här raden högst upp i en modul:

Option Base 1

Med denna rad kommer alla Arrays som deklareras i modulen att indexeras från ONE .

Specifikt index

Du kan också deklarera varje Array med sin egen index med hjälp av To nyckelordet, och den nedre och övre gränsen (= index):

Dim mySecondArray(1 To 12) As String 'Array of 12 strings indexed from 1 to 12
Dim myThirdArray(13 To 24) As String 'Array of 12 strings indexed from 13 to 24

Dynamisk förklaring

När du inte vet storleken på din array innan den deklareras kan du använda den dynamiska deklarationen och ReDim nyckelordet:

Dim myDynamicArray() As Strings 'Creates an Array of an unknown number of strings
ReDim myDynamicArray(5) 'This resets the array to 6 elements

Observera att med ReDim nyckelordet kommer att utplåna allt tidigare innehåll i din array. För att förhindra detta kan du använda Preserve nyckelordet efter ReDim :

Dim myDynamicArray(5) As String
myDynamicArray(0) = "Something I want to keep"

ReDim Preserve myDynamicArray(8) 'Expand the size to up to 9 strings
Debug.Print myDynamicArray(0) ' still prints the element

Använd Split för att skapa en matris från en sträng

Delad funktion

returnerar en nollbaserad, endimensionell matris som innehåller ett specificerat antal underlag.

Syntax

Dela (uttryck [, avgränsare [, begränsa [, jämför ]]] )

inställningar

Jämför- argumentet kan ha följande värden:

Exempel

I det här exemplet visas hur Split fungerar genom att visa flera stilar. Kommentarerna visar resultatuppsättningen för vart och ett av de olika utförda split-alternativen. Slutligen demonstreras hur man slingrar över den returnerade strängmatrisen.

Sub Test
    
    Dim textArray() as String

    textArray = Split("Tech on the Net")
    'Result: {"Tech", "on", "the", "Net"}

    textArray = Split("172.23.56.4", ".")
    'Result: {"172", "23", "56", "4"}

    textArray = Split("A;B;C;D", ";")
    'Result: {"A", "B", "C", "D"}

    textArray = Split("A;B;C;D", ";", 1)
    'Result: {"A;B;C;D"}

    textArray = Split("A;B;C;D", ";", 2)
    'Result: {"A", "B;C;D"}

    textArray = Split("A;B;C;D", ";", 3)
    'Result: {"A", "B", "C;D"}

    textArray = Split("A;B;C;D", ";", 4)
    'Result: {"A", "B", "C", "D"}

    'You can iterate over the created array
    Dim counter As Long

    For counter = LBound(textArray) To UBound(textArray)
        Debug.Print textArray(counter)
    Next
 End Sub

Iterererande element i en matris

För nästa

Att använda iteratorvariabeln som indexnummer är det snabbaste sättet att iterera elementen i en matris:

Dim items As Variant
items = Array(0, 1, 2, 3)

Dim index As Integer
For index = LBound(items) To UBound(items)
    'assumes value can be implicitly converted to a String:
    Debug.Print items(index) 
Next

Kapslade slingor kan användas för att iterera flerdimensionella matriser:

Dim items(0 To 1, 0 To 1) As Integer
items(0, 0) = 0
items(0, 1) = 1
items(1, 0) = 2
items(1, 1) = 3

Dim outer As Integer
Dim inner As Integer
For outer = LBound(items, 1) To UBound(items, 1)
    For inner = LBound(items, 2) To UBound(items, 2)
        'assumes value can be implicitly converted to a String:
        Debug.Print items(outer, inner)
    Next
Next

För varje ... Nästa

A For Each...Next slinga kan också användas för att iterera matriser om prestanda inte spelar någon roll:

Dim items As Variant
items = Array(0, 1, 2, 3)

Dim item As Variant 'must be variant
For Each item In items
    'assumes value can be implicitly converted to a String:
    Debug.Print item
Next

A For Each slinga itererar alla dimensioner från yttre till inre (i samma ordning som elementen läggs ut i minnet), så det finns inget behov av kapslade slingor:

Dim items(0 To 1, 0 To 1) As Integer
items(0, 0) = 0
items(1, 0) = 1
items(0, 1) = 2
items(1, 1) = 3

Dim item As Variant 'must be Variant
For Each item In items
    'assumes value can be implicitly converted to a String:
    Debug.Print item
Next

Observera att For Each slingor bäst används för att iterera Collection , om prestanda är viktigt.

Alla fyra utdragen ovan ger samma utgång:

 0
 1
 2
 3

Dynamiska matriser (Array-storlek och dynamisk hantering)

Dynamiska matriser

Att lägga till och minska variabler på en matris dynamiskt är en enorm fördel för när informationen du behandlar inte har ett fast antal variabler.

Lägga till värden dynamiskt

Du kan helt enkelt ändra storlek på arrayen med ReDim uttalandet, detta kommer att ändra storlek på arrayen, men om du vill behålla den information som redan finns lagrad i arrayen behöver du delen Preserve .

I exemplet nedan skapar vi en matris och ökar den med ytterligare en variabel i varje iteration samtidigt som värdena redan finns i matrisen.

Dim Dynamic_array As Variant
' first we set Dynamic_array as variant

For n = 1 To 100

    If IsEmpty(Dynamic_array) Then
        'isempty() will check if we need to add the first value to the array or subsequent ones
    
        ReDim Dynamic_array(0)
        'ReDim Dynamic_array(0) will resize the array to one variable only
        Dynamic_array(0) = n

    Else
        ReDim Preserve Dynamic_array(0 To UBound(Dynamic_array) + 1)
        'in the line above we resize the array from variable 0 to the UBound() = last variable, plus one effectivelly increeasing the size of the array by one
        Dynamic_array(UBound(Dynamic_array)) = n
        'attribute a value to the last variable of Dynamic_array
    End If

Next

Ta bort värden dynamiskt

Vi kan använda samma logik för att minska matrisen. I exemplet kommer värdet "sista" att tas bort från matrisen.

Dim Dynamic_array As Variant
Dynamic_array = Array("first", "middle", "last")
    
ReDim Preserve Dynamic_array(0 To UBound(Dynamic_array) - 1)
' Resize Preserve while dropping the last value

Återställa en matris och återanvända dynamiskt

Vi kan lika bra använda de matriser som vi skapar för att inte ha många i minnet, vilket skulle göra körtiden långsammare. Detta är användbart för matriser i olika storlekar. Ett utdrag du kan använda för att återanvända matrisen är att ReDim arrayen tillbaka till (0) , attribut till en variabel till arrayen och fritt öka matrisen igen.

I utdraget nedan konstruerar jag en matris med värdena 1 till 40, töm arrayen och fyller upp matrisen med värden 40 till 100, allt detta görs dynamiskt.

Dim Dynamic_array As Variant

For n = 1 To 100

    If IsEmpty(Dynamic_array) Then
        ReDim Dynamic_array(0)
        Dynamic_array(0) = n
    
    ElseIf Dynamic_array(0) = "" Then
        'if first variant is empty ( = "") then give it the value of n
        Dynamic_array(0) = n
    Else
        ReDim Preserve Dynamic_array(0 To UBound(Dynamic_array) + 1)
        Dynamic_array(UBound(Dynamic_array)) = n
    End If
    If n = 40 Then
        ReDim Dynamic_array(0)
        'Resizing the array back to one variable without Preserving,
        'leaving the first value of the array empty
    End If

Next

Jagged Arrays (Arrays of Arrays)

Jagged Arrays INTE Flerdimensionella Arrays

Arrays of Arrays (Jagged Arrays) är inte samma som Multidimensionella Arrays om du tänker på dem visuellt Multidimensionella Arrays skulle se ut som matriser (rektangulära) med definierat antal element på deras dimensioner (inuti matriser), medan Jagged array skulle vara som ett årligt kalender med insidan matriser med olika antal element, som dagar i på olika månader.

Även om Jagged Arrays är ganska röriga och svåra att använda på grund av deras kapslade nivåer och inte har mycket typ av säkerhet, men de är väldigt flexibla, låter dig manipulera olika typer av data ganska enkelt och behöver inte innehålla oanvända eller tomma element.

Skapa en Jagged Array

I exemplet nedan kommer vi att initiera en taggad matris som innehåller två matriser, en för namn och en annan för siffror, och sedan åtkomst till ett element i varje

Dim OuterArray() As Variant
Dim Names() As Variant
Dim Numbers() As Variant
'arrays are declared variant so we can access attribute any data type to its elements

Names = Array("Person1", "Person2", "Person3")
Numbers = Array("001", "002", "003")

OuterArray = Array(Names, Numbers)
'Directly giving OuterArray an array containing both Names and Numbers arrays inside

Debug.Print OuterArray(0)(1)
Debug.Print OuterArray(1)(1)
'accessing elements inside the jagged by giving the coordenades of the element

Dynamiskt Skapa och läsa Jagged Arrays

Vi kan också vara mer dynamiska i våra ungefär att konstruera matriserna, föreställa oss att vi har ett kunddatablad i Excel och vi vill konstruera en matris för att skriva ut kundinformationen.

   Name -   Phone   -  Email  - Customer Number 
Person1 - 153486231 - 1@STACK - 001
Person2 - 153486242 - 2@STACK - 002
Person3 - 153486253 - 3@STACK - 003
Person4 - 153486264 - 4@STACK - 004
Person5 - 153486275 - 5@STACK - 005

Vi konstruerar dynamiskt en rubrik-grupp och en kundgrupp, rubriken kommer att innehålla kolumntitlar och kundgruppen kommer att innehålla information om varje kund / rad som matriser.

Dim Headers As Variant
' headers array with the top section of the customer data sheet
    For c = 1 To 4
        If IsEmpty(Headers) Then
            ReDim Headers(0)
            Headers(0) = Cells(1, c).Value
        Else
            ReDim Preserve Headers(0 To UBound(Headers) + 1)
            Headers(UBound(Headers)) = Cells(1, c).Value
        End If
    Next
    
Dim Customers As Variant
'Customers array will contain arrays of customer values
Dim Customer_Values As Variant
'Customer_Values will be an array of the customer in its elements (Name-Phone-Email-CustNum)
    
    For r = 2 To 6
    'iterate through the customers/rows
        For c = 1 To 4
        'iterate through the values/columns
            
            'build array containing customer values
            If IsEmpty(Customer_Values) Then
                ReDim Customer_Values(0)
                Customer_Values(0) = Cells(r, c).Value
            ElseIf Customer_Values(0) = "" Then
                Customer_Values(0) = Cells(r, c).Value
            Else
                ReDim Preserve Customer_Values(0 To UBound(Customer_Values) + 1)
                Customer_Values(UBound(Customer_Values)) = Cells(r, c).Value
            End If
        Next
        
        'add customer_values array to Customers Array
        If IsEmpty(Customers) Then
            ReDim Customers(0)
            Customers(0) = Customer_Values
        Else
            ReDim Preserve Customers(0 To UBound(Customers) + 1)
            Customers(UBound(Customers)) = Customer_Values
        End If
        
        'reset Custumer_Values to rebuild a new array if needed
        ReDim Customer_Values(0)
    Next

    Dim Main_Array(0 To 1) As Variant
    'main array will contain both the Headers and Customers
    
    Main_Array(0) = Headers
    Main_Array(1) = Customers

To better understand the way to Dynamically construct a one dimensional array please check Dynamic Arrays (Array Resizing and Dynamic Handling) on the Arrays documentation.

Resultatet av ovannämnda utdrag är en Jagged Array med två matriser, en av dessa matriser med 4 element, 2 indragningsnivåer, och den andra är i sig en annan Jagged Array som innehåller 5 matriser med 4 element vardera och 3 indragningsnivåer, se nedan strukturen:

Main_Array(0) - Headers - Array("Name","Phone","Email","Customer Number")
          (1) - Customers(0) - Array("Person1",153486231,"1@STACK",001)
                Customers(1) - Array("Person2",153486242,"2@STACK",002)
                ...
                Customers(4) - Array("Person5",153486275,"5@STACK",005)

För att få tillgång till informationen måste du komma ihåg strukturen för den Jagged Array du skapar, i exemplet ovan kan du se att Main Array innehåller en Array of Headers och en Array of Arrays ( Customers ) därmed med olika sätt att åtkomst till elementen.

Nu ska vi läsa informationen i Main Array och skriva ut var och en av kundinformationen som Info Type: Info .

For n = 0 To UBound(Main_Array(1))
    'n to iterate from fisrt to last array in Main_Array(1)
    
    For j = 0 To UBound(Main_Array(1)(n))
        'j will iterate from first to last element in each array of Main_Array(1)
        
        Debug.Print Main_Array(0)(j) & ": " & Main_Array(1)(n)(j)
        'print Main_Array(0)(j) which is the header and Main_Array(0)(n)(j) which is the element in the customer array
        'we can call the header with j as the header array has the same structure as the customer array
    Next
Next

HUSK att hålla reda på strukturen för din Jagged Array, i exemplet ovan för att komma åt kundens namn är genom att Main_Array -> Customers -> CustomerNumber -> Name som är tre nivåer, för att returnera "Person4" du behöver platsen för kunder i Main_Array, sedan platsen för kund fyra på klienten Jagged-matrisen och slutligen platsen för det element du behöver, i detta fall Main_Array(1)(3)(0) som är Main_Array(Customers)(CustomerNumber)(Name) .

Multidimensionella matriser

Multidimensionella matriser

Som namnet antyder är multidimensionella matriser matriser som innehåller mer än en dimension, vanligtvis två eller tre, men det kan ha upp till 32 dimensioner.

En multi-array fungerar som en matris med olika nivåer, ta i exempel en jämförelse mellan en, två och tre dimensioner.

En dimension är din typiska grupp, det ser ut som en lista över element.

Dim 1D(3) as Variant

*1D - Visually*
(0)
(1)
(2)

Två dimensioner skulle se ut som ett Sudoku-rutnät eller ett Excel-ark, när du initierar matrisen skulle du definiera hur många rader och kolumner matrisen skulle ha.

Dim 2D(3,3) as Variant
'this would result in a 3x3 grid 

*2D - Visually*
(0,0) (0,1) (0,2)
(1,0) (1,1) (1,2)
(2,0) (2,1) (2,2)

Tre dimensioner skulle börja se ut som Rubiks kub, när du initierar matrisen skulle du definiera rader och kolumner och lager / djup som matrisen skulle ha.

Dim 3D(3,3,2) as Variant
'this would result in a 3x3x3 grid

*3D - Visually*
       1st layer                 2nd layer                  3rd layer
         front                     middle                     back
(0,0,0) (0,0,1) (0,0,2) ¦ (1,0,0) (1,0,1) (1,0,2) ¦ (2,0,0) (2,0,1) (2,0,2)
(0,1,0) (0,1,1) (0,1,2) ¦ (1,1,0) (1,1,1) (1,1,2) ¦ (2,1,0) (2,1,1) (2,1,2)
(0,2,0) (0,2,1) (0,2,2) ¦ (1,2,0) (1,2,1) (1,2,2) ¦ (2,2,0) (2,2,1) (2,2,2)

Ytterligare dimensioner kan tänkas som multiplikationen av 3D, så en 4D (1,3,3,3) skulle vara två sida vid sida 3D-arrayer.

Två-dimensionen array

Skapande

Exemplet nedan är en sammanställning av en lista över anställda, varje anställd kommer att ha en uppsättning information på listan (Förnamn, Efternamn, Adress, E-post, Telefon ...), exemplet kommer i huvudsak att lagras i matrisen ( anställd, information) som (0,0) är den första anställdas förnamn.

Dim Bosses As Variant
'set bosses as Variant, so we can input any data type we want

Bosses = [{"Jonh","Snow","President";"Ygritte","Wild","Vice-President"}]
'initialise a 2D array directly by filling it with information, the redult wil be a array(1,2) size 2x3 = 6 elements

Dim Employees As Variant
'initialize your Employees array as variant
'initialize and ReDim the Employee array so it is a dynamic array instead of a static one, hence treated differently by the VBA Compiler
ReDim Employees(100, 5)
'declaring an 2D array that can store 100 employees with 6 elements of information each, but starts empty
'the array size is 101 x 6 and contains 606 elements

For employee = 0 To UBound(Employees, 1)
'for each employee/row in the array, UBound for 2D arrays, which will get the last element on the array
'needs two parameters 1st the array you which to check and 2nd the dimension, in this case 1 = employee and 2 = information
    For information_e = 0 To UBound(Employees, 2)
    'for each information element/column in the array
        
        Employees(employee, information_e) = InformationNeeded ' InformationNeeded would be the data to fill the array
        'iterating the full array will allow for direct attribution of information into the element coordinates
    Next
Next

Ändra storlek

Ändra storleken på eller ReDim Preserve en fleruppsättning som normen för en endimension-matris skulle få ett fel, istället måste informationen överföras till en tillfällig matris med samma storlek som originalet plus antalet rad / kolumner som ska läggas till. I exemplet nedan ser vi hur man initialiserar en Temp Array, överför informationen från den ursprungliga matrisen, fyller de återstående tomma elementen och ersätter temp-arrayen med den ursprungliga arrayen.

Dim TempEmp As Variant
'initialise your temp array as variant
ReDim TempEmp(UBound(Employees, 1) + 1, UBound(Employees, 2))
'ReDim/Resize Temp array as a 2D array with size UBound(Employees)+1 = (last element in Employees 1st dimension) + 1,
'the 2nd dimension remains the same as the original array. we effectively add 1 row in the Employee array

'transfer
For emp = LBound(Employees, 1) To UBound(Employees, 1)
    For info = LBound(Employees, 2) To UBound(Employees, 2)
        'to transfer Employees into TempEmp we iterate both arrays and fill TempEmp with the corresponding element value in Employees
        TempEmp(emp, info) = Employees(emp, info)
    
    Next
Next

'fill remaining
'after the transfers the Temp array still has unused elements at the end, being that it was increased
'to fill the remaining elements iterate from the last "row" with values to the last row in the array
'in this case the last row in Temp will be the size of the Employees array rows + 1, as the last row of Employees array is already filled in the TempArray

For emp = UBound(Employees, 1) + 1 To UBound(TempEmp, 1)
    For info = LBound(TempEmp, 2) To UBound(TempEmp, 2)
        
        TempEmp(emp, info) = InformationNeeded & "NewRow"
    
    Next
Next

'erase Employees, attribute Temp array to Employees and erase Temp array
Erase Employees
Employees = TempEmp
Erase TempEmp

Ändra elementvärden

Att ändra / ändra värdena i ett visst element kan göras genom att helt enkelt ringa koordinaten för att ändra och ge det ett nytt värde: Employees(0, 0) = "NewValue"

Alternativt iterera genom koordinaterna användningsvillkor för att matcha värden som motsvarar de parametrar som behövs:

For emp = 0 To UBound(Employees)
    If Employees(emp, 0) = "Gloria" And Employees(emp, 1) = "Stephan" Then
    'if value found
        Employees(emp, 1) = "Married, Last Name Change"
        Exit For
        'don't iterate through a full array unless necessary
    End If
Next

Läsning

Åtkomst till elementen i matrisen kan göras med en kapslad slinga (iterering av varje element), slinga och koordinat (iterera rader och åtkomst till kolumner direkt), eller åtkomst direkt med båda koordinaterna.

'nested loop, will iterate through all elements
For emp = LBound(Employees, 1) To UBound(Employees, 1)
    For info = LBound(Employees, 2) To UBound(Employees, 2)
        Debug.Print Employees(emp, info)
    Next
Next

'loop and coordinate, iteration through all rows and in each row accessing all columns directly
For emp = LBound(Employees, 1) To UBound(Employees, 1)
    Debug.Print Employees(emp, 0)
    Debug.Print Employees(emp, 1)
    Debug.Print Employees(emp, 2)
    Debug.Print Employees(emp, 3)
    Debug.Print Employees(emp, 4)
    Debug.Print Employees(emp, 5)
Next

'directly accessing element with coordinates
Debug.Print Employees(5, 5)

Kom ihåg att det alltid är praktiskt att hålla en matris karta när du använder flerdimensionella matriser, de kan lätt bli förvirring.

Tre-dimensionen array

För 3D-arrayen använder vi samma förutsättning som 2D-arrayen, med tillägg av att inte bara lagra anställd och information utan också bygga de arbetar i.

3D-arrayen kommer att ha de anställda (kan tänkas vara rader), informationen (kolumner) och byggnad som kan betraktas som olika ark på ett Excel-dokument, de har samma storlek mellan dem, men varje ark har en olika uppsättningar information i dess celler / element. 3D array kommer att innehålla n antal 2D-arrayer.

Skapande

En 3D-array behöver 3 koordinater för att initialiseras. Dim 3Darray(2,5,5) As Variant den första koordinaten på arrayen att vara antalet Building / Sheets (olika uppsättningar av rader och kolumner), den andra koordinaten definierar rader och tredje kolumner. Dim ovan kommer att resultera i en 3D-grupp med 108 element ( 3*6*6 ), som effektivt har 3 olika uppsättningar av 2D-arrayer.

Dim ThreeDArray As Variant
'initialise your ThreeDArray array as variant
ReDim ThreeDArray(1, 50, 5)
'declaring an 3D array that can store two sets of 51 employees with 6 elements of information each, but starts empty
'the array size is 2 x 51 x 6 and contains 612 elements

For building = 0 To UBound(ThreeDArray, 1)
    'for each building/set in the array
    For employee = 0 To UBound(ThreeDArray, 2)
    'for each employee/row in the array
        For information_e = 0 To UBound(ThreeDArray, 3)
        'for each information element/column in the array
            
            ThreeDArray(building, employee, information_e) = InformationNeeded ' InformationNeeded would be the data to fill the array
        'iterating the full array will allow for direct attribution of information into the element coordinates
        Next
    Next
Next

Ändra storlek

Ändra storlek på en 3D-array liknar storleken på en 2D, skapa först en tillfällig matris med samma storlek på originalet och lägg till en i koordinaten för parametern för att öka, den första koordinaten kommer att öka antalet uppsättningar i arrayen, den andra och tredje koordinater kommer att öka antalet rader eller kolumner i varje uppsättning.

Exemplet nedan ökar antalet rader i varje uppsättning med en och fyller de nyligen tillagda elementen med ny information.

Dim TempEmp As Variant
'initialise your temp array as variant
ReDim TempEmp(UBound(ThreeDArray, 1), UBound(ThreeDArray, 2) + 1, UBound(ThreeDArray, 3))
'ReDim/Resize Temp array as a 3D array with size UBound(ThreeDArray)+1 = (last element in Employees 2nd dimension) + 1,
'the other dimension remains the same as the original array. we effectively add 1 row in the for each set of the 3D array

'transfer
For building = LBound(ThreeDArray, 1) To UBound(ThreeDArray, 1)
    For emp = LBound(ThreeDArray, 2) To UBound(ThreeDArray, 2)
        For info = LBound(ThreeDArray, 3) To UBound(ThreeDArray, 3)
            'to transfer ThreeDArray into TempEmp by iterating all sets in the 3D array and fill TempEmp with the corresponding element value in each set of each row
            TempEmp(building, emp, info) = ThreeDArray(building, emp, info)
        
        Next
    Next
Next

'fill remaining
'to fill the remaining elements we need to iterate from the last "row" with values to the last row in the array in each set, remember that the first empty element is the original array Ubound() plus 1
For building = LBound(TempEmp, 1) To UBound(TempEmp, 1)
    For emp = UBound(ThreeDArray, 2) + 1 To UBound(TempEmp, 2)
        For info = LBound(TempEmp, 3) To UBound(TempEmp, 3)
            
            TempEmp(building, emp, info) = InformationNeeded & "NewRow"
        
        Next
    Next
Next

'erase Employees, attribute Temp array to Employees and erase Temp array
Erase ThreeDArray
ThreeDArray = TempEmp
Erase TempEmp

Ändra elementvärden och läsning

Läsa och ändra elementen i 3D-arrayen kan göras på samma sätt som vi gör 2D-arrayen, justera bara för den extra nivån i slingorna och koordinaterna.

Do
' using Do ... While for early exit
    For building = 0 To UBound(ThreeDArray, 1)
        For emp = 0 To UBound(ThreeDArray, 2)
            If ThreeDArray(building, emp, 0) = "Gloria" And ThreeDArray(building, emp, 1) = "Stephan" Then
            'if value found
                ThreeDArray(building, emp, 1) = "Married, Last Name Change"
                Exit Do
                'don't iterate through all the array unless necessary
            End If
        Next
    Next
Loop While False

'nested loop, will iterate through all elements
For building = LBound(ThreeDArray, 1) To UBound(ThreeDArray, 1)
    For emp = LBound(ThreeDArray, 2) To UBound(ThreeDArray, 2)
        For info = LBound(ThreeDArray, 3) To UBound(ThreeDArray, 3)
            Debug.Print ThreeDArray(building, emp, info)
        Next
    Next
Next

'loop and coordinate, will iterate through all set of rows and ask for the row plus the value we choose for the columns
For building = LBound(ThreeDArray, 1) To UBound(ThreeDArray, 1)
    For emp = LBound(ThreeDArray, 2) To UBound(ThreeDArray, 2)
        Debug.Print ThreeDArray(building, emp, 0)
        Debug.Print ThreeDArray(building, emp, 1)
        Debug.Print ThreeDArray(building, emp, 2)
        Debug.Print ThreeDArray(building, emp, 3)
        Debug.Print ThreeDArray(building, emp, 4)
        Debug.Print ThreeDArray(building, emp, 5)
    Next
Next

'directly accessing element with coordinates
Debug.Print Employees(0, 5, 5)