VBA
arrays

Een array declareren in VBA

Het declareren van een array lijkt sterk op het declareren van een variabele, behalve dat u de dimensie van de array direct achter de naam moet opgeven:

Dim myArray(9) As String 'Declaring an array that will contain up to 10 strings

Standaard worden arrays in VBA geïndexeerd op nul , dus het getal tussen haakjes verwijst niet naar de grootte van de array, maar naar de index van het laatste element

Toegang tot elementen

U krijgt toegang tot een element van de array met behulp van de naam van de array, gevolgd door de index van het element, tussen haakjes:

myArray(0) = "first element"
myArray(5) = "sixth element"
myArray(9) = "last element"

Matrixindexering

U kunt de indexering van arrays wijzigen door deze regel bovenaan een module te plaatsen:

Option Base 1

Met deze regel worden alle in de module gedeclareerde arrays geïndexeerd vanaf ONE .

Specifieke index

U kunt ook elke array met zijn eigen index declareren met het trefwoord To en de onder- en bovengrens (= index):

Dim mySecondArray(1 To 12) As String 'Array of 12 strings indexed from 1 to 12
Dim myThirdArray(13 To 24) As String 'Array of 12 strings indexed from 13 to 24

Dynamische verklaring

Als u de grootte van uw array niet kent voordat u de aangifte doet, kunt u de dynamische aangifte en het sleutelwoord ReDim :

Dim myDynamicArray() As Strings 'Creates an Array of an unknown number of strings
ReDim myDynamicArray(5) 'This resets the array to 6 elements

Merk op dat het gebruik van het ReDim trefwoord alle eerdere inhoud van uw array zal wissen. Om dit te voorkomen, kunt u het sleutelwoord Preserve na ReDim :

Dim myDynamicArray(5) As String
myDynamicArray(0) = "Something I want to keep"

ReDim Preserve myDynamicArray(8) 'Expand the size to up to 9 strings
Debug.Print myDynamicArray(0) ' still prints the element

Gebruik Split om een array van een string te maken

Split functie

retourneert een op nul gebaseerde, eendimensionale array met een opgegeven aantal substrings.

Syntaxis

Splitsen (expressie [, scheidingsteken [, limiet [, vergelijken ]]] )

instellingen

Het vergelijkingsargument kan de volgende waarden hebben:

Voorbeeld

In dit voorbeeld wordt aangetoond hoe Split werkt door verschillende stijlen te tonen. De opmerkingen tonen het resultaatset voor elk van de verschillende uitgevoerde Split-opties. Ten slotte wordt aangetoond hoe de lus-reeks moet worden herhaald.

Sub Test
    
    Dim textArray() as String

    textArray = Split("Tech on the Net")
    'Result: {"Tech", "on", "the", "Net"}

    textArray = Split("172.23.56.4", ".")
    'Result: {"172", "23", "56", "4"}

    textArray = Split("A;B;C;D", ";")
    'Result: {"A", "B", "C", "D"}

    textArray = Split("A;B;C;D", ";", 1)
    'Result: {"A;B;C;D"}

    textArray = Split("A;B;C;D", ";", 2)
    'Result: {"A", "B;C;D"}

    textArray = Split("A;B;C;D", ";", 3)
    'Result: {"A", "B", "C;D"}

    textArray = Split("A;B;C;D", ";", 4)
    'Result: {"A", "B", "C", "D"}

    'You can iterate over the created array
    Dim counter As Long

    For counter = LBound(textArray) To UBound(textArray)
        Debug.Print textArray(counter)
    Next
 End Sub

Elementen van een array herhalen

Voor de volgende

Het gebruik van de iteratorvariabele als het indexnummer is de snelste manier om de elementen van een array te herhalen:

Dim items As Variant
items = Array(0, 1, 2, 3)

Dim index As Integer
For index = LBound(items) To UBound(items)
    'assumes value can be implicitly converted to a String:
    Debug.Print items(index) 
Next

Geneste lussen kunnen worden gebruikt om multidimensionale arrays te herhalen:

Dim items(0 To 1, 0 To 1) As Integer
items(0, 0) = 0
items(0, 1) = 1
items(1, 0) = 2
items(1, 1) = 3

Dim outer As Integer
Dim inner As Integer
For outer = LBound(items, 1) To UBound(items, 1)
    For inner = LBound(items, 2) To UBound(items, 2)
        'assumes value can be implicitly converted to a String:
        Debug.Print items(outer, inner)
    Next
Next

Voor elke ... Volgende

Een For Each...Next lus kan ook worden gebruikt om arrays te herhalen, als de prestaties er niet toe doen:

Dim items As Variant
items = Array(0, 1, 2, 3)

Dim item As Variant 'must be variant
For Each item In items
    'assumes value can be implicitly converted to a String:
    Debug.Print item
Next

A For Each lus itereert alle dimensies van buiten naar binnen (in dezelfde volgorde als waarin de elementen in het geheugen zijn vastgelegd), dus er zijn geen geneste lussen nodig:

Dim items(0 To 1, 0 To 1) As Integer
items(0, 0) = 0
items(1, 0) = 1
items(0, 1) = 2
items(1, 1) = 3

Dim item As Variant 'must be Variant
For Each item In items
    'assumes value can be implicitly converted to a String:
    Debug.Print item
Next

Merk op dat For Each lussen het beste worden gebruikt om Collection objecten te itereren, als de prestaties ertoe doen.

Alle 4 bovenstaande fragmenten produceren dezelfde uitvoer:

 0
 1
 2
 3

Dynamic Arrays (Array Resizing and Dynamic Handling)

Dynamische arrays

Het dynamisch toevoegen en verkleinen van variabelen in een array is een enorm voordeel wanneer de informatie die u behandelt geen vast aantal variabelen heeft.

Waarden dynamisch toevoegen

U kunt eenvoudig het formaat van de array wijzigen met de ReDim instructie, hierdoor wordt het formaat van de array ReDim , maar als u de informatie wilt behouden die al in de array is opgeslagen, hebt u het onderdeel Preserve .

In het onderstaande voorbeeld maken we een array en verhogen deze met nog een variabele in elke iteratie met behoud van de waarden die al in de array zijn.

Dim Dynamic_array As Variant
' first we set Dynamic_array as variant

For n = 1 To 100

    If IsEmpty(Dynamic_array) Then
        'isempty() will check if we need to add the first value to the array or subsequent ones
    
        ReDim Dynamic_array(0)
        'ReDim Dynamic_array(0) will resize the array to one variable only
        Dynamic_array(0) = n

    Else
        ReDim Preserve Dynamic_array(0 To UBound(Dynamic_array) + 1)
        'in the line above we resize the array from variable 0 to the UBound() = last variable, plus one effectivelly increeasing the size of the array by one
        Dynamic_array(UBound(Dynamic_array)) = n
        'attribute a value to the last variable of Dynamic_array
    End If

Next

Waarden dynamisch verwijderen

We kunnen dezelfde logica gebruiken om de array te verkleinen. In het voorbeeld wordt de waarde "last" uit de array verwijderd.

Dim Dynamic_array As Variant
Dynamic_array = Array("first", "middle", "last")
    
ReDim Preserve Dynamic_array(0 To UBound(Dynamic_array) - 1)
' Resize Preserve while dropping the last value

Een array opnieuw instellen en dynamisch hergebruiken

We kunnen de arrays die we maken net zo goed opnieuw gebruiken als er niet veel in het geheugen zijn, waardoor de uitvoeringstijd langzamer zou zijn. Dit is handig voor arrays van verschillende grootte. Een fragment dat u kunt gebruiken om de array opnieuw te gebruiken, is om de array opnieuw te re- ReDim naar (0) , een variabele toe te wijzen aan de array en de array weer vrij te vergroten.

In het onderstaande fragment construeer ik een array met de waarden 1 tot 40, maak de array leeg en vul de array opnieuw met waarden 40 tot 100, dit alles dynamisch gedaan.

Dim Dynamic_array As Variant

For n = 1 To 100

    If IsEmpty(Dynamic_array) Then
        ReDim Dynamic_array(0)
        Dynamic_array(0) = n
    
    ElseIf Dynamic_array(0) = "" Then
        'if first variant is empty ( = "") then give it the value of n
        Dynamic_array(0) = n
    Else
        ReDim Preserve Dynamic_array(0 To UBound(Dynamic_array) + 1)
        Dynamic_array(UBound(Dynamic_array)) = n
    End If
    If n = 40 Then
        ReDim Dynamic_array(0)
        'Resizing the array back to one variable without Preserving,
        'leaving the first value of the array empty
    End If

Next

Jagged Arrays (Arrays of Arrays)

Jagged Arrays NIET multidimensionale arrays

Arrays of Arrays (Jagged Arrays) zijn niet hetzelfde als Multidimensional Arrays als je er visueel aan denkt Multidimensional Arrays zou eruit zien als Matrices (rechthoekig) met een gedefinieerd aantal elementen op hun afmetingen (binnen arrays), terwijl Jagged Array zou zijn als een jaarlijkse kalender met de binnenste arrays met een verschillend aantal elementen, zoals dagen binnen op verschillende maanden.

Hoewel Jagged Arrays nogal rommelig en lastig te gebruiken zijn vanwege hun geneste niveaus en niet veel typeveiligheid hebben, maar ze zijn zeer flexibel, stellen u in staat om verschillende soorten gegevens vrij gemakkelijk te manipuleren en hoeven ze geen ongebruikte of lege elementen.

Een gekartelde array maken

In het onderstaande voorbeeld initialiseren we een gekartelde array met twee arrays, één voor namen en een andere voor nummers, en vervolgens toegang tot één element van elk

Dim OuterArray() As Variant
Dim Names() As Variant
Dim Numbers() As Variant
'arrays are declared variant so we can access attribute any data type to its elements

Names = Array("Person1", "Person2", "Person3")
Numbers = Array("001", "002", "003")

OuterArray = Array(Names, Numbers)
'Directly giving OuterArray an array containing both Names and Numbers arrays inside

Debug.Print OuterArray(0)(1)
Debug.Print OuterArray(1)(1)
'accessing elements inside the jagged by giving the coordenades of the element

Dynamisch gekartelde arrays maken en lezen

We kunnen net zo goed dynamischer zijn om de arrays samen te stellen, stel je voor dat we een klantgegevensblad in excel hebben en we willen een array bouwen om de klantdetails uit te voeren.

   Name -   Phone   -  Email  - Customer Number 
Person1 - 153486231 - 1@STACK - 001
Person2 - 153486242 - 2@STACK - 002
Person3 - 153486253 - 3@STACK - 003
Person4 - 153486264 - 4@STACK - 004
Person5 - 153486275 - 5@STACK - 005

We zullen dynamisch een koptekstarray en een klantenmatrix maken, de koptekst bevat de kolomtitels en de klantenmatrix bevat de informatie van elke klant / rij als arrays.

Dim Headers As Variant
' headers array with the top section of the customer data sheet
    For c = 1 To 4
        If IsEmpty(Headers) Then
            ReDim Headers(0)
            Headers(0) = Cells(1, c).Value
        Else
            ReDim Preserve Headers(0 To UBound(Headers) + 1)
            Headers(UBound(Headers)) = Cells(1, c).Value
        End If
    Next
    
Dim Customers As Variant
'Customers array will contain arrays of customer values
Dim Customer_Values As Variant
'Customer_Values will be an array of the customer in its elements (Name-Phone-Email-CustNum)
    
    For r = 2 To 6
    'iterate through the customers/rows
        For c = 1 To 4
        'iterate through the values/columns
            
            'build array containing customer values
            If IsEmpty(Customer_Values) Then
                ReDim Customer_Values(0)
                Customer_Values(0) = Cells(r, c).Value
            ElseIf Customer_Values(0) = "" Then
                Customer_Values(0) = Cells(r, c).Value
            Else
                ReDim Preserve Customer_Values(0 To UBound(Customer_Values) + 1)
                Customer_Values(UBound(Customer_Values)) = Cells(r, c).Value
            End If
        Next
        
        'add customer_values array to Customers Array
        If IsEmpty(Customers) Then
            ReDim Customers(0)
            Customers(0) = Customer_Values
        Else
            ReDim Preserve Customers(0 To UBound(Customers) + 1)
            Customers(UBound(Customers)) = Customer_Values
        End If
        
        'reset Custumer_Values to rebuild a new array if needed
        ReDim Customer_Values(0)
    Next

    Dim Main_Array(0 To 1) As Variant
    'main array will contain both the Headers and Customers
    
    Main_Array(0) = Headers
    Main_Array(1) = Customers

To better understand the way to Dynamically construct a one dimensional array please check Dynamic Arrays (Array Resizing and Dynamic Handling) on the Arrays documentation.

Het resultaat van het bovenstaande fragment is een Jagged Array met twee arrays, een van die arrays met 4 elementen, 2 inspringingsniveaus, en de andere zelf een andere Jagged Array met 5 arrays van 4 elementen elk en 3 inspringingsniveaus, zie hieronder de structuur:

Main_Array(0) - Headers - Array("Name","Phone","Email","Customer Number")
          (1) - Customers(0) - Array("Person1",153486231,"1@STACK",001)
                Customers(1) - Array("Person2",153486242,"2@STACK",002)
                ...
                Customers(4) - Array("Person5",153486275,"5@STACK",005)

Om toegang te krijgen tot de informatie moet je rekening houden met de structuur van de Jagged Array die je maakt, in het bovenstaande voorbeeld kun je zien dat de Main Array een Array of Headers en een Array of Arrays ( Customers ) bevat, dus met verschillende manieren om toegang tot de elementen.

Nu zullen we de informatie van de Main Array en elke Main Array afdrukken als Info Type: Info .

For n = 0 To UBound(Main_Array(1))
    'n to iterate from fisrt to last array in Main_Array(1)
    
    For j = 0 To UBound(Main_Array(1)(n))
        'j will iterate from first to last element in each array of Main_Array(1)
        
        Debug.Print Main_Array(0)(j) & ": " & Main_Array(1)(n)(j)
        'print Main_Array(0)(j) which is the header and Main_Array(0)(n)(j) which is the element in the customer array
        'we can call the header with j as the header array has the same structure as the customer array
    Next
Next

HERINNER me om de structuur van uw Jagged Array bij te houden, in het bovenstaande voorbeeld om toegang te krijgen tot de naam van een klant is door Main_Array -> Customers -> CustomerNumber -> Name met drie niveaus te openen om "Person4" te retourneren die u nodig hebt de locatie van Klanten in de Main_Array, vervolgens de Locatie van klant vier op de klanten Jagged array en ten slotte de locatie van het element dat u nodig hebt, in dit geval Main_Array(1)(3)(0) dat is Main_Array(Customers)(CustomerNumber)(Name) .

Multidimensionale arrays

Multidimensionale arrays

Zoals de naam aangeeft, zijn multidimensionale arrays arrays die meer dan één dimensie bevatten, meestal twee of drie, maar deze kunnen maximaal 32 dimensies hebben.

Een multi-array werkt als een matrix met verschillende niveaus, neem bijvoorbeeld een vergelijking tussen één, twee en drie dimensies.

One Dimension is je typische array, het ziet eruit als een lijst met elementen.

Dim 1D(3) as Variant

*1D - Visually*
(0)
(1)
(2)

Twee dimensies zien eruit als een Sudoku-raster of een Excel-blad, wanneer u de array initialiseert, definieert u hoeveel rijen en kolommen de array zou hebben.

Dim 2D(3,3) as Variant
'this would result in a 3x3 grid 

*2D - Visually*
(0,0) (0,1) (0,2)
(1,0) (1,1) (1,2)
(2,0) (2,1) (2,2)

Drie dimensies zouden op Rubik's Cube gaan lijken, bij het initialiseren van de array definieert u rijen en kolommen en lagen / dieptes die de array zou hebben.

Dim 3D(3,3,2) as Variant
'this would result in a 3x3x3 grid

*3D - Visually*
       1st layer                 2nd layer                  3rd layer
         front                     middle                     back
(0,0,0) (0,0,1) (0,0,2) ¦ (1,0,0) (1,0,1) (1,0,2) ¦ (2,0,0) (2,0,1) (2,0,2)
(0,1,0) (0,1,1) (0,1,2) ¦ (1,1,0) (1,1,1) (1,1,2) ¦ (2,1,0) (2,1,1) (2,1,2)
(0,2,0) (0,2,1) (0,2,2) ¦ (1,2,0) (1,2,1) (1,2,2) ¦ (2,2,0) (2,2,1) (2,2,2)

Verdere dimensies kunnen worden gedacht als de vermenigvuldiging van de 3D, dus een 4D (1,3,3,3) zou twee naast elkaar liggende 3D-arrays zijn.

Tweedimensionale array

Creëren

Het onderstaande voorbeeld is een compilatie van een lijst met werknemers, elke werknemer heeft een set informatie op de lijst (voornaam, achternaam, adres, e-mail, telefoon ...), het voorbeeld wordt hoofdzakelijk opgeslagen in de array ( medewerker, informatie) zijnde de (0,0) is de voornaam van de eerste medewerker.

Dim Bosses As Variant
'set bosses as Variant, so we can input any data type we want

Bosses = [{"Jonh","Snow","President";"Ygritte","Wild","Vice-President"}]
'initialise a 2D array directly by filling it with information, the redult wil be a array(1,2) size 2x3 = 6 elements

Dim Employees As Variant
'initialize your Employees array as variant
'initialize and ReDim the Employee array so it is a dynamic array instead of a static one, hence treated differently by the VBA Compiler
ReDim Employees(100, 5)
'declaring an 2D array that can store 100 employees with 6 elements of information each, but starts empty
'the array size is 101 x 6 and contains 606 elements

For employee = 0 To UBound(Employees, 1)
'for each employee/row in the array, UBound for 2D arrays, which will get the last element on the array
'needs two parameters 1st the array you which to check and 2nd the dimension, in this case 1 = employee and 2 = information
    For information_e = 0 To UBound(Employees, 2)
    'for each information element/column in the array
        
        Employees(employee, information_e) = InformationNeeded ' InformationNeeded would be the data to fill the array
        'iterating the full array will allow for direct attribution of information into the element coordinates
    Next
Next

Het formaat

Resizing of ReDim Preserve een Multi-Array zoals de norm voor een One-Dimension-array zou een foutmelding krijgen, in plaats daarvan moet de informatie worden overgebracht naar een tijdelijke array met dezelfde grootte als het origineel plus het aantal toe te voegen rijen / kolommen. In het onderstaande voorbeeld zullen we zien hoe een Temp Array te initialiseren, de informatie overbrengen van de oorspronkelijke array, de resterende lege elementen vullen en de tijdelijke array vervangen door de oorspronkelijke array.

Dim TempEmp As Variant
'initialise your temp array as variant
ReDim TempEmp(UBound(Employees, 1) + 1, UBound(Employees, 2))
'ReDim/Resize Temp array as a 2D array with size UBound(Employees)+1 = (last element in Employees 1st dimension) + 1,
'the 2nd dimension remains the same as the original array. we effectively add 1 row in the Employee array

'transfer
For emp = LBound(Employees, 1) To UBound(Employees, 1)
    For info = LBound(Employees, 2) To UBound(Employees, 2)
        'to transfer Employees into TempEmp we iterate both arrays and fill TempEmp with the corresponding element value in Employees
        TempEmp(emp, info) = Employees(emp, info)
    
    Next
Next

'fill remaining
'after the transfers the Temp array still has unused elements at the end, being that it was increased
'to fill the remaining elements iterate from the last "row" with values to the last row in the array
'in this case the last row in Temp will be the size of the Employees array rows + 1, as the last row of Employees array is already filled in the TempArray

For emp = UBound(Employees, 1) + 1 To UBound(TempEmp, 1)
    For info = LBound(TempEmp, 2) To UBound(TempEmp, 2)
        
        TempEmp(emp, info) = InformationNeeded & "NewRow"
    
    Next
Next

'erase Employees, attribute Temp array to Employees and erase Temp array
Erase Employees
Employees = TempEmp
Erase TempEmp

Elementwaarden wijzigen

U kunt de waarden in een bepaald element wijzigen / wijzigen door eenvoudig de coördinaat te wijzigen aan te roepen en deze een nieuwe waarde te geven: Employees(0, 0) = "NewValue"

Alternatief doorloop de coördinaten de gebruiksvoorwaarden om waarden overeen te laten komen die overeenkomen met de benodigde parameters:

For emp = 0 To UBound(Employees)
    If Employees(emp, 0) = "Gloria" And Employees(emp, 1) = "Stephan" Then
    'if value found
        Employees(emp, 1) = "Married, Last Name Change"
        Exit For
        'don't iterate through a full array unless necessary
    End If
Next

Lezing

Toegang krijgen tot de elementen in de array kan worden gedaan met een geneste lus (elk element herhalend), lus en coördinaat (rijen herhalen en rechtstreeks toegang krijgen tot kolommen), of rechtstreeks toegang krijgen met beide coördinaten.

'nested loop, will iterate through all elements
For emp = LBound(Employees, 1) To UBound(Employees, 1)
    For info = LBound(Employees, 2) To UBound(Employees, 2)
        Debug.Print Employees(emp, info)
    Next
Next

'loop and coordinate, iteration through all rows and in each row accessing all columns directly
For emp = LBound(Employees, 1) To UBound(Employees, 1)
    Debug.Print Employees(emp, 0)
    Debug.Print Employees(emp, 1)
    Debug.Print Employees(emp, 2)
    Debug.Print Employees(emp, 3)
    Debug.Print Employees(emp, 4)
    Debug.Print Employees(emp, 5)
Next

'directly accessing element with coordinates
Debug.Print Employees(5, 5)

Vergeet niet dat het altijd handig is om een matrixkaart bij te houden wanneer u multidimensionale arrays gebruikt, deze kunnen gemakkelijk verwarring veroorzaken.

Driedimensionale array

Voor de 3D-array gebruiken we hetzelfde uitgangspunt als de 2D-array, met de toevoeging van niet alleen het opslaan van de medewerker en informatie, maar ook het gebouw waarin ze werken.

De 3D-array heeft de werknemers (kunnen worden beschouwd als rijen), de informatie (kolommen) en het gebouw die kunnen worden gezien als verschillende bladen in een Excel-document, ze hebben dezelfde grootte daartussen, maar elk blad heeft een andere set informatie in zijn cellen / elementen. De 3D-array bevat n aantal 2D-arrays.

Creëren

Een 3D-array heeft 3 coördinaten nodig om te worden geïnitialiseerd Dim 3Darray(2,5,5) As Variant de eerste coördinaat op de array het aantal gebouwen / bladen (verschillende sets rijen en kolommen), de tweede coördinaat definieert rijen en derde columns. De bovenstaande Dim resulteert in een 3D-array met 108 elementen ( 3*6*6 ), met in feite 3 verschillende sets 2D-arrays.

Dim ThreeDArray As Variant
'initialise your ThreeDArray array as variant
ReDim ThreeDArray(1, 50, 5)
'declaring an 3D array that can store two sets of 51 employees with 6 elements of information each, but starts empty
'the array size is 2 x 51 x 6 and contains 612 elements

For building = 0 To UBound(ThreeDArray, 1)
    'for each building/set in the array
    For employee = 0 To UBound(ThreeDArray, 2)
    'for each employee/row in the array
        For information_e = 0 To UBound(ThreeDArray, 3)
        'for each information element/column in the array
            
            ThreeDArray(building, employee, information_e) = InformationNeeded ' InformationNeeded would be the data to fill the array
        'iterating the full array will allow for direct attribution of information into the element coordinates
        Next
    Next
Next

Het formaat

Het formaat van een 3D-array wijzigen is vergelijkbaar met het wijzigen van een 2D-array, maak eerst een tijdelijke array met dezelfde grootte van het origineel door er een toe te voegen in de coördinaat van de parameter die moet worden verhoogd, de eerste coördinaat verhoogt het aantal sets in de array, de tweede en derde coördinaten verhogen het aantal rijen of kolommen in elke set.

Het onderstaande voorbeeld verhoogt het aantal rijen in elke set met één en vult die recent toegevoegde elementen met nieuwe informatie.

Dim TempEmp As Variant
'initialise your temp array as variant
ReDim TempEmp(UBound(ThreeDArray, 1), UBound(ThreeDArray, 2) + 1, UBound(ThreeDArray, 3))
'ReDim/Resize Temp array as a 3D array with size UBound(ThreeDArray)+1 = (last element in Employees 2nd dimension) + 1,
'the other dimension remains the same as the original array. we effectively add 1 row in the for each set of the 3D array

'transfer
For building = LBound(ThreeDArray, 1) To UBound(ThreeDArray, 1)
    For emp = LBound(ThreeDArray, 2) To UBound(ThreeDArray, 2)
        For info = LBound(ThreeDArray, 3) To UBound(ThreeDArray, 3)
            'to transfer ThreeDArray into TempEmp by iterating all sets in the 3D array and fill TempEmp with the corresponding element value in each set of each row
            TempEmp(building, emp, info) = ThreeDArray(building, emp, info)
        
        Next
    Next
Next

'fill remaining
'to fill the remaining elements we need to iterate from the last "row" with values to the last row in the array in each set, remember that the first empty element is the original array Ubound() plus 1
For building = LBound(TempEmp, 1) To UBound(TempEmp, 1)
    For emp = UBound(ThreeDArray, 2) + 1 To UBound(TempEmp, 2)
        For info = LBound(TempEmp, 3) To UBound(TempEmp, 3)
            
            TempEmp(building, emp, info) = InformationNeeded & "NewRow"
        
        Next
    Next
Next

'erase Employees, attribute Temp array to Employees and erase Temp array
Erase ThreeDArray
ThreeDArray = TempEmp
Erase TempEmp

Elementwaarden wijzigen en lezen

Het lezen en wijzigen van de elementen op de 3D-array kan op dezelfde manier worden gedaan als de 2D-array, gewoon aanpassen voor het extra niveau in de lussen en coördinaten.

Do
' using Do ... While for early exit
    For building = 0 To UBound(ThreeDArray, 1)
        For emp = 0 To UBound(ThreeDArray, 2)
            If ThreeDArray(building, emp, 0) = "Gloria" And ThreeDArray(building, emp, 1) = "Stephan" Then
            'if value found
                ThreeDArray(building, emp, 1) = "Married, Last Name Change"
                Exit Do
                'don't iterate through all the array unless necessary
            End If
        Next
    Next
Loop While False

'nested loop, will iterate through all elements
For building = LBound(ThreeDArray, 1) To UBound(ThreeDArray, 1)
    For emp = LBound(ThreeDArray, 2) To UBound(ThreeDArray, 2)
        For info = LBound(ThreeDArray, 3) To UBound(ThreeDArray, 3)
            Debug.Print ThreeDArray(building, emp, info)
        Next
    Next
Next

'loop and coordinate, will iterate through all set of rows and ask for the row plus the value we choose for the columns
For building = LBound(ThreeDArray, 1) To UBound(ThreeDArray, 1)
    For emp = LBound(ThreeDArray, 2) To UBound(ThreeDArray, 2)
        Debug.Print ThreeDArray(building, emp, 0)
        Debug.Print ThreeDArray(building, emp, 1)
        Debug.Print ThreeDArray(building, emp, 2)
        Debug.Print ThreeDArray(building, emp, 3)
        Debug.Print ThreeDArray(building, emp, 4)
        Debug.Print ThreeDArray(building, emp, 5)
    Next
Next

'directly accessing element with coordinates
Debug.Print Employees(0, 5, 5)