Visual Basic .NET Language
Обработка ошибок

Попробуйте ... Поймать ... Окончательное утверждение

Состав:

Try
    'Your program will try to run the code in this block.  
    'If any exceptions are thrown, the code in the Catch Block will be executed,
    'without executing the lines after the one which caused the exception.
Catch ex As System.IO.IOException
    'If an exception occurs when processing the Try block, each Catch statement
    'is examined in textual order to determine which handles the exception. 
    'For example, this Catch block handles an IOException.
Catch ex As Exception
    'This catch block handles all Exception types.
    'Details of the exception, in this case, are in the "ex" variable.
    'You can show the error in a MessageBox with the below line.
    MessageBox.Show(ex.Message)
Finally
    'A finally block is always executed, regardless of if an Exception occurred.
End Try

Пример кода:

Try
    Dim obj = Nothing
    Dim prop = obj.Name 'This line will throw a NullReferenceException

    Console.WriteLine("Test.") ' This line will NOT be executed
Catch ex As System.IO.IOException
    ' Code that reacts to IOException.
Catch ex As NullReferenceException
    ' Code that reacts to a NullReferenceException
    Console.WriteLine("NullReferenceException: " & ex.Message)
    Console.WriteLine("Stack Trace: " & ex.StackTrace)
Catch ex As Exception
    ' Code that reacts to any other exception.
Finally   
    ' This will always be run, regardless of if an exception is thrown.
    Console.WriteLine("Completed")
End Try

Создание настраиваемого исключения и метания

Вы можете создать настраиваемое исключение и выбросить его во время выполнения вашей функции. В качестве общей практики вы должны просто генерировать исключение, когда ваша функция не может выполнить определенные функции.

Private Function OpenDatabase(Byval Server as String, Byval User as String, Byval Pwd as String)
    if Server.trim="" then 
        Throw new Exception("Server Name cannot be blank")
    elseif User.trim ="" then 
        Throw new Exception("User name cannot be blank")
    elseif Pwd.trim="" then 
        Throw new Exception("Password cannot be blank")
    endif

    'Here add codes for connecting to the server
End function

Попробовать Catch в операции с базой данных

Вы можете использовать команду Try..Catch для отката базы данных, разместив оператор отката на сегменте Catch.

    Try            
        'Do the database operation...        
        xCmd.CommandText = "INSERT into ...."
        xCmd.ExecuteNonQuery()

        objTrans.Commit()
        conn.Close()
    Catch ex As Exception 
        'Rollback action when something goes off           
        objTrans.Rollback()
        conn.Close()
    End Try

Неустранимое исключение

Хотя Catch ex As Exception утверждает, что может обрабатывать все исключения - есть одно исключение (каламбур не предназначен).

Imports System
Static Sub StackOverflow() ' Again no pun intended
    StackOverflow()
End Sub
Static Sub Main()
    Try
        StackOverflow()
    Catch ex As Exception
        Console.WriteLine("Exception caught!")
    Finally
        Console.WriteLine("Finally block")
    End Try
End Sub

Упс ... Существует System.StackOverflowException то время как консоль даже ничего не распечатывала! Согласно MSDN ,

Начиная с .NET Framework 2.0, вы не можете поймать объект StackOverflowException блоком try / catch, и соответствующий процесс будет завершен по умолчанию. Следовательно, вы должны написать свой код для обнаружения и предотвращения переполнения стека.

Таким образом, System.StackOverflowException недоступен. Остерегайтесь!

Критические исключения

Как правило, большинство исключений не являются критическими, но есть некоторые действительно серьезные исключения, которые вы, возможно, не способны обрабатывать, например, известное исключение System.StackOverflowException . Однако есть и другие, которые могут быть скрыты Catch ex As Exception , такие как System.OutOfMemoryException , System.BadImageFormatException и System.InvalidProgramException . Это хорошая практика программирования, чтобы оставить их, если вы не можете правильно их обработать. Чтобы отфильтровать эти исключения, нам нужен вспомогательный метод:

Public Shared Function IsCritical(ex As Exception) As Boolean
    Return TypeOf ex Is OutOfMemoryException OrElse
           TypeOf ex Is AppDomainUnloadedException OrElse
           TypeOf ex Is AccessViolationException OrElse
           TypeOf ex Is BadImageFormatException OrElse
           TypeOf ex Is CannotUnloadAppDomainException OrElse
           TypeOf ex Is ExecutionEngineException OrElse ' Obsolete one, but better to include
           TypeOf ex Is InvalidProgramException OrElse
           TypeOf ex Is System.Threading.ThreadAbortException
End Function

Использование:

Try
    SomeMethod()
Catch ex As Exception When Not IsCritical(ex)
    Console.WriteLine("Exception caught: " & ex.Message)
End Try