ActionScript 3
날짜 및 시간 작업

12 시간제 Ante meridiem (AM) 또는 Post meridiem (PM)

function meridiem(d:Date):String {
    return (d.hours > 11) ? "pm" : "am";
}

지정된 월의 날짜 수

/**
 * @param year   Full year as int (ex: 2000).
 * @param month  Month as int, zero-based (ex: 0=January, 11=December).
 */
function daysInMonth(year:int, month:int):int {
    return (new Date(year, ++month, 0)).date;
}

지정된 연도가 윤년인지 여부

function isLeapYear(year:int):Boolean {
    return daysInMonth(year, 1) == 29;
}

일광 절약 시간이 현재 준수되고 있는지 여부

function isDaylightSavings(d:Date):Boolean {
    var months:uint = 12;
    var offset:uint = d.timezoneOffset;
    var offsetCheck:Number;

    while (months--) {
        offsetCheck = (new Date(d.getFullYear(), months, 1)).timezoneOffset;

        if (offsetCheck != offset)
            return (offsetCheck > offset);
    }

    return false;
}

오늘 시작일 자정에

function today(date:Date = null):Date {
    if (date == null)
        date = new Date();

    return new Date(date.fullYear, date.month, date.date, 0, 0, 0, 0);
}