Embarcadero Delphi
Esecuzione di altri programmi

CreateProcess

La seguente funzione incapsula il codice per l'utilizzo dell'API di Windows CreateProcess per l'avvio di altri programmi.

È configurabile e può attendere fino al termine del processo di chiamata o alla restituzione immediata.

parametri:

• FileName : percorso completo dell'eseguibile
• Params - parametri della riga di comando o usare una stringa vuota
• Folder - cartella di lavoro per programma chiamato - se il percorso vuoto verrà estratto da FileName
• WaitUntilTerminated : se la funzione true attende il completamento del processo
• WaitUntilIdle - se la funzione true chiamerà la funzione WaitForInputIdle e attenderà fino a quando il processo specificato avrà terminato l'elaborazione del suo input iniziale e fino a quando non ci sarà alcun input dell'utente in sospeso
• RunMinimized - se il processo vero verrà eseguito minimizzato
• ErrorCode : se la funzione non riesce, conterrà il codice errore di Windows rilevato

function ExecuteProcess(const FileName, Params: string; Folder: string; WaitUntilTerminated, WaitUntilIdle, RunMinimized: boolean;
  var ErrorCode: integer): boolean;
var
  CmdLine: string;
  WorkingDirP: PChar;
  StartupInfo: TStartupInfo;
  ProcessInfo: TProcessInformation;
begin
  Result := true;
  CmdLine := '"' + FileName + '" ' + Params;
  if Folder = '' then Folder := ExcludeTrailingPathDelimiter(ExtractFilePath(FileName));
  ZeroMemory(@StartupInfo, SizeOf(StartupInfo));
  StartupInfo.cb := SizeOf(StartupInfo);
  if RunMinimized then
    begin
      StartupInfo.dwFlags := STARTF_USESHOWWINDOW;
      StartupInfo.wShowWindow := SW_SHOWMINIMIZED;
    end;
  if Folder <> '' then WorkingDirP := PChar(Folder)
  else WorkingDirP := nil;
  if not CreateProcess(nil, PChar(CmdLine), nil, nil, false, 0, nil, WorkingDirP, StartupInfo, ProcessInfo) then
    begin
      Result := false;
      ErrorCode := GetLastError;
      exit;
    end;
  with ProcessInfo do
    begin
      CloseHandle(hThread);
      if WaitUntilIdle then WaitForInputIdle(hProcess, INFINITE);
      if WaitUntilTerminated then
        repeat
          Application.ProcessMessages;
        until MsgWaitForMultipleObjects(1, hProcess, false, INFINITE, QS_ALLINPUT) <> WAIT_OBJECT_0 + 1;
      CloseHandle(hProcess);
    end;
end;

Uso della funzione precedente

var
  FileName, Parameters, WorkingFolder: string;
  Error: integer;
  OK: boolean;
begin
  FileName := 'C:\FullPath\myapp.exe';
  WorkingFolder := ''; // if empty function will extract path from FileName
  Parameters := '-p'; // can be empty 
  OK := ExecuteProcess(FileName, Parameters, WorkingFolder, false, false, false, Error);
  if not OK then ShowMessage('Error: ' + IntToStr(Error));
end;

Documentazione CreateProcess