Embarcadero Delphi
Uruchamianie innych programów

Proces tworzenia

Poniższa funkcja zawiera kod do użycia API Windows CreateProcess do uruchamiania innych programów.

Jest konfigurowalny i może czekać, aż proces wywoływania zakończy się lub powróci natychmiast.

Parametry:

• FileName - pełna ścieżka do pliku wykonywalnego
• Params - parametry wiersza poleceń lub użyj pustego ciągu
• Folder - folder roboczy dla wywoływanego programu - jeśli pusta ścieżka zostanie wyodrębniona z FileName
• WaitUntilTerminated - jeśli funkcja true będzie czekać na zakończenie procesu przez proces
• WaitUntilIdle - jeśli funkcja true wywoła funkcję WaitForInputIdle i poczeka, aż określony proces zakończy przetwarzanie początkowych danych wejściowych i dopóki nie zostanie wprowadzone żadne dane użytkownika
• RunMinimized - jeśli prawdziwy proces zostanie uruchomiony zminimalizowany
• ErrorCode - jeśli funkcja zawiedzie, będzie zawierał napotkany kod błędu systemu Windows

function ExecuteProcess(const FileName, Params: string; Folder: string; WaitUntilTerminated, WaitUntilIdle, RunMinimized: boolean;
  var ErrorCode: integer): boolean;
var
  CmdLine: string;
  WorkingDirP: PChar;
  StartupInfo: TStartupInfo;
  ProcessInfo: TProcessInformation;
begin
  Result := true;
  CmdLine := '"' + FileName + '" ' + Params;
  if Folder = '' then Folder := ExcludeTrailingPathDelimiter(ExtractFilePath(FileName));
  ZeroMemory(@StartupInfo, SizeOf(StartupInfo));
  StartupInfo.cb := SizeOf(StartupInfo);
  if RunMinimized then
    begin
      StartupInfo.dwFlags := STARTF_USESHOWWINDOW;
      StartupInfo.wShowWindow := SW_SHOWMINIMIZED;
    end;
  if Folder <> '' then WorkingDirP := PChar(Folder)
  else WorkingDirP := nil;
  if not CreateProcess(nil, PChar(CmdLine), nil, nil, false, 0, nil, WorkingDirP, StartupInfo, ProcessInfo) then
    begin
      Result := false;
      ErrorCode := GetLastError;
      exit;
    end;
  with ProcessInfo do
    begin
      CloseHandle(hThread);
      if WaitUntilIdle then WaitForInputIdle(hProcess, INFINITE);
      if WaitUntilTerminated then
        repeat
          Application.ProcessMessages;
        until MsgWaitForMultipleObjects(1, hProcess, false, INFINITE, QS_ALLINPUT) <> WAIT_OBJECT_0 + 1;
      CloseHandle(hProcess);
    end;
end;

Zastosowanie powyższej funkcji

var
  FileName, Parameters, WorkingFolder: string;
  Error: integer;
  OK: boolean;
begin
  FileName := 'C:\FullPath\myapp.exe';
  WorkingFolder := ''; // if empty function will extract path from FileName
  Parameters := '-p'; // can be empty 
  OK := ExecuteProcess(FileName, Parameters, WorkingFolder, false, false, false, Error);
  if not OK then ShowMessage('Error: ' + IntToStr(Error));
end;

Utwórz dokumentację procesu