Embarcadero Delphi
Ejecutando otros programas

Proceso de creación

La siguiente función encapsula el código para usar la API de Windows CreateProcess para iniciar otros programas.

Es configurable y puede esperar hasta que el proceso de llamada finalice o regrese inmediatamente.

Parámetros:

• FileName - ruta completa al ejecutable
• Params - Parámetros de línea de comandos o utilizar cadena vacía
• Folder - carpeta de trabajo para el programa llamado - si la ruta vacía será extraída de FileName
• WaitUntilTerminated : si la función true esperará a que el proceso finalice la ejecución
• WaitUntilIdle : si la función true llamará a la función WaitForInputIdle y esperará hasta que el proceso especificado haya terminado de procesar su entrada inicial y hasta que no haya ninguna entrada de usuario pendiente
• RunMinimized - si el proceso verdadero se ejecuta minimizado
• ErrorCode - si la función falla este código de error de Windows contendrá encontrado

function ExecuteProcess(const FileName, Params: string; Folder: string; WaitUntilTerminated, WaitUntilIdle, RunMinimized: boolean;
  var ErrorCode: integer): boolean;
var
  CmdLine: string;
  WorkingDirP: PChar;
  StartupInfo: TStartupInfo;
  ProcessInfo: TProcessInformation;
begin
  Result := true;
  CmdLine := '"' + FileName + '" ' + Params;
  if Folder = '' then Folder := ExcludeTrailingPathDelimiter(ExtractFilePath(FileName));
  ZeroMemory(@StartupInfo, SizeOf(StartupInfo));
  StartupInfo.cb := SizeOf(StartupInfo);
  if RunMinimized then
    begin
      StartupInfo.dwFlags := STARTF_USESHOWWINDOW;
      StartupInfo.wShowWindow := SW_SHOWMINIMIZED;
    end;
  if Folder <> '' then WorkingDirP := PChar(Folder)
  else WorkingDirP := nil;
  if not CreateProcess(nil, PChar(CmdLine), nil, nil, false, 0, nil, WorkingDirP, StartupInfo, ProcessInfo) then
    begin
      Result := false;
      ErrorCode := GetLastError;
      exit;
    end;
  with ProcessInfo do
    begin
      CloseHandle(hThread);
      if WaitUntilIdle then WaitForInputIdle(hProcess, INFINITE);
      if WaitUntilTerminated then
        repeat
          Application.ProcessMessages;
        until MsgWaitForMultipleObjects(1, hProcess, false, INFINITE, QS_ALLINPUT) <> WAIT_OBJECT_0 + 1;
      CloseHandle(hProcess);
    end;
end;

Uso de la función anterior

var
  FileName, Parameters, WorkingFolder: string;
  Error: integer;
  OK: boolean;
begin
  FileName := 'C:\FullPath\myapp.exe';
  WorkingFolder := ''; // if empty function will extract path from FileName
  Parameters := '-p'; // can be empty 
  OK := ExecuteProcess(FileName, Parameters, WorkingFolder, false, false, false, Error);
  if not OK then ShowMessage('Error: ' + IntToStr(Error));
end;

Documentación de CreateProcess