progress-4gl
frågor
Sök…
Introduktion
Exemplen kommer att baseras på en kopia av demodatabasen Sports 2000 medföljer installationen av Progress.
När du arbetar med frågor som pågår måste du:
DEFINE frågan och ange vilka buffertar (tabeller) och fält den fungerar mot.
OPEN frågan med en specifik WHERE -clause som definierar hur man hämtar posterna. Eventuellt också sortering ( BY / BREAK BY )
GET de faktiska uppgifterna - det kan vara den FIRST , NEXT , PREV (för föregående) eller LAST matchande posten.
Syntax
- DEFINERA FRÅGA fråganamn FÖR buffertnamn. // Allmän frågedefinition för en buffert
- DEFINERA FRÅGA fråga-namn FÖR buffert-namn1, buffert-namn2. // Gå med två buffertar
- DEFINERA FRÅGA fråga-namn FÖR buffertnamnsfält (fält1-fält2). // Endast retreive field1 och field2
- DEFINERA FRÅGA fråga-namn FÖR buffertnamn UTFATT (fält3). // Återuppta alla fält utom fält3.
Grundläggande fråga
/* Define a query named q1 for the Customer table */
DEFINE QUERY q1 FOR Customer.
/* Open the query for all Customer records where the state is "tx" */
OPEN QUERY q1 FOR EACH Customer WHERE Customer.state ='TX'.
/* Get the first result of query q1 */
GET FIRST q1.
/* Repeat as long as query q1 has a result */
DO WHILE NOT QUERY-OFF-END('q1'):
/* Display Customer.Name in a frame called frame1 with 10 rows */
DISPLAY Customer.Name WITH FRAME frame1 10 DOWN.
/* Move down the target line where to display the next record */
DOWN WITH FRAME frame1.
/* Get the next result of query q1 */
GET NEXT q1.
END.
/* Display how many results query q1 had. */
DISPLAY NUM-RESULTS('q1') LABEL "Number of records".
/* Close the query */
CLOSE QUERY q1.
Utgång (tredje skärmen i Windows gui):
Multibordsfråga
Denna fråga kommer att gå med i tre tabeller: Kund, Order och Orderline.
Användningen av OF uttalandet som i childtable OF parenttable antar att index är konstruerade på ett specifikt sätt. Så är fallet i sports2000-databasen.
DEFINE QUERY q1 FOR Customer, Order, Orderline.
OPEN QUERY q1 FOR EACH Customer WHERE Customer.state = 'TX'
, EACH Order OF customer WHERE order.custnum < 1000
, EACH orderline OF order.
GET FIRST q1.
DO WHILE NOT QUERY-OFF-END('q1'):
DISPLAY Customer.Name Order.OrderNum OrderLine.LineNum
WITH FRAME frameA 20 DOWN.
DOWN WITH FRAME frameA.
GET NEXT q1.
END.
CLOSE QUERY q1.
Resultat: I Windows GUI:
Flytta poisition med en fråga med nästa, första, föregående och sista
DEFINE QUERY q1 FOR Customer.
OPEN QUERY q1 FOR EACH Customer.
GET FIRST q1.
loop:
REPEAT:
IF AVAILABLE Customer THEN DO:
DISPLAY Customer.NAME CustNum WITH FRAME frClient TITLE "Client data".
DISPLAY
"(P)revious" SKIP
"(N)ext" SKIP
"(F)irst" SKIP
"(L)ast" SKIP
"(Q)uit" SKIP
WITH FRAME frInstr
TITLE "Instructions".
END.
READKEY.
IF LASTKEY = ASC("q") THEN LEAVE loop.
ELSE IF LASTKEY = ASC("n") THEN
GET NEXT q1.
ELSE IF LASTKEY = ASC("p") THEN
GET PREV q1.
ELSE IF LASTKEY = ASC("l") THEN
GET LAST q1.
ELSE IF LASTKEY = ASC("f") THEN
GET FIRST q1.
END.
MESSAGE "Bye" VIEW-AS ALERT-BOX.