progress-4gl
Запросы
Поиск…
Вступление
Примеры будут основаны на копии демонстрационной базы данных Sports 2000 с настройкой Progress.
При работе с запрошенными запросами вам необходимо:
DEFINE запрос и задайте, какие буферы (таблицы) и поля он работает.
OPEN запрос с конкретным WHERE -clause , который определяет , как получить записи. Возможно также сортировка ( BY / BREAK BY )
GET фактические данные - это FIRST , NEXT , PREV (для предыдущей) или LAST совместимая запись.
Синтаксис
- DEFINE QUERY имя запроса для имени буфера. // Общее определение запроса для одного буфера
- DEFINE QUERY имя запроса FOR buffer-name1, buffer-name2. // Объединение двух буферов
- DEFINE QUERY имя запроса FOR buffer-name FIELDS (поле1 field2). // Только поле retreive1 и field2
- DEFINE QUERY query-name ДЛЯ имени буфера EXCEPT (поле3). // Retreive все поля, кроме поля3.
Основной запрос
/* Define a query named q1 for the Customer table */
DEFINE QUERY q1 FOR Customer.
/* Open the query for all Customer records where the state is "tx" */
OPEN QUERY q1 FOR EACH Customer WHERE Customer.state ='TX'.
/* Get the first result of query q1 */
GET FIRST q1.
/* Repeat as long as query q1 has a result */
DO WHILE NOT QUERY-OFF-END('q1'):
/* Display Customer.Name in a frame called frame1 with 10 rows */
DISPLAY Customer.Name WITH FRAME frame1 10 DOWN.
/* Move down the target line where to display the next record */
DOWN WITH FRAME frame1.
/* Get the next result of query q1 */
GET NEXT q1.
END.
/* Display how many results query q1 had. */
DISPLAY NUM-RESULTS('q1') LABEL "Number of records".
/* Close the query */
CLOSE QUERY q1.
Выход (третий экран в Windows gui):
Запрос нескольких таблиц
Этот запрос будет объединяться в три таблицы: заказчик, заказ и заказ.
Использование оператора OF как в childtable OF parenttable предполагает, что индексы построены определенным образом. Так обстоит дело в базе данных sports2000.
DEFINE QUERY q1 FOR Customer, Order, Orderline.
OPEN QUERY q1 FOR EACH Customer WHERE Customer.state = 'TX'
, EACH Order OF customer WHERE order.custnum < 1000
, EACH orderline OF order.
GET FIRST q1.
DO WHILE NOT QUERY-OFF-END('q1'):
DISPLAY Customer.Name Order.OrderNum OrderLine.LineNum
WITH FRAME frameA 20 DOWN.
DOWN WITH FRAME frameA.
GET NEXT q1.
END.
CLOSE QUERY q1.
Результат: В графическом интерфейсе Windows:
Перемещение позиции с запросом с использованием следующего, первого, предыдущего и последнего
DEFINE QUERY q1 FOR Customer.
OPEN QUERY q1 FOR EACH Customer.
GET FIRST q1.
loop:
REPEAT:
IF AVAILABLE Customer THEN DO:
DISPLAY Customer.NAME CustNum WITH FRAME frClient TITLE "Client data".
DISPLAY
"(P)revious" SKIP
"(N)ext" SKIP
"(F)irst" SKIP
"(L)ast" SKIP
"(Q)uit" SKIP
WITH FRAME frInstr
TITLE "Instructions".
END.
READKEY.
IF LASTKEY = ASC("q") THEN LEAVE loop.
ELSE IF LASTKEY = ASC("n") THEN
GET NEXT q1.
ELSE IF LASTKEY = ASC("p") THEN
GET PREV q1.
ELSE IF LASTKEY = ASC("l") THEN
GET LAST q1.
ELSE IF LASTKEY = ASC("f") THEN
GET FIRST q1.
END.
MESSAGE "Bye" VIEW-AS ALERT-BOX.