progress-4gl => Interrogazioni

introduzione

Gli esempi saranno basati su una copia del database demo Sports 2000 fornito con la configurazione di Progress.

Quando si lavora con le query in corso è necessario:

DEFINE la query e imposta quali buffer (tabelle) e campi funzionano contro.

OPEN la query con un WHERE -clause specifico che definisce come recuperare i record. Forse anche l'ordinamento ( BY / BREAK BY )

GET i dati effettivi, che possono essere il record FIRST , NEXT , PREV (per precedente) o LAST .

Sintassi

DEFINIZIONE QUERY nome-query FOR nome-buffer. // Definizione della query generale per un buffer
DEFINIZIONE QUERY nome-query FOR nome-buffer1, nome-buffer2. // Unione di due buffer
DEFINIZIONE QUERY nome-query PER nome-buffer CAMPI (campo1 campo2). // Recupera solo field1 e field2
DEFINIZIONE QUERY nome-query FOR nome-buffer EXCEPT (campo3). // Recupera tutti i campi tranne il campo3.

Query di base

/* Define a query named q1 for the Customer table */
DEFINE QUERY q1 FOR Customer.
/* Open the query for all Customer records where the state is "tx" */
OPEN QUERY q1 FOR EACH Customer WHERE Customer.state ='TX'.                                                                                                                                                                               
/* Get the first result of query q1 */
GET FIRST q1.                                                                                                                                                                                                                   

/* Repeat as long as query q1 has a result */
DO WHILE NOT QUERY-OFF-END('q1'):          
    /* Display Customer.Name in a frame called frame1 with 10 rows */
    DISPLAY Customer.Name WITH FRAME frame1 10 DOWN.
    /* Move down the target line where to display the next record */
    DOWN WITH FRAME frame1.
    /* Get the next result of query q1 */
    GET NEXT q1.
END.
/* Display how many results query q1 had. */
DISPLAY NUM-RESULTS('q1') LABEL "Number of records".

/* Close the query */
CLOSE QUERY q1.

Output (terza schermata in Windows gui):

Query a più tabelle

Questa query si unirà a tre tabelle: Cliente, Ordine e Ordine.

L'uso del OF economico come in childtable OF parenttable presuppone che gli indici sono costruiti in modo specifico. Questo è il caso nel database sports2000.

DEFINE QUERY q1 FOR Customer, Order, Orderline.

OPEN QUERY q1 FOR EACH Customer WHERE Customer.state = 'TX'
    , EACH Order OF customer WHERE order.custnum < 1000
    , EACH orderline OF order.

GET FIRST q1.
DO WHILE NOT QUERY-OFF-END('q1'):
    DISPLAY Customer.Name Order.OrderNum OrderLine.LineNum 
        WITH FRAME frameA 20 DOWN.
    DOWN WITH FRAME frameA.
    GET NEXT q1.
END.

CLOSE QUERY q1.

Risultato: nella GUI di Windows:

Spostare la poizione in una query usando next, first, prev e last

DEFINE QUERY q1 FOR Customer.

OPEN QUERY q1 FOR EACH Customer.

GET FIRST q1.

loop:
REPEAT:
    IF AVAILABLE Customer THEN DO:
        DISPLAY Customer.NAME CustNum WITH FRAME frClient TITLE "Client data".
        
        DISPLAY
            "(P)revious" SKIP 
            "(N)ext" SKIP
            "(F)irst" SKIP
            "(L)ast" SKIP
            "(Q)uit" SKIP
            WITH FRAME frInstr
                TITLE "Instructions".
    END.
    
    READKEY.

    IF LASTKEY = ASC("q") THEN LEAVE loop.
    ELSE IF LASTKEY = ASC("n") THEN
        GET NEXT q1.
    ELSE IF LASTKEY = ASC("p") THEN
        GET PREV q1.
    ELSE IF LASTKEY = ASC("l") THEN
        GET LAST q1.
    ELSE IF LASTKEY = ASC("f") THEN
        GET FIRST q1.

END.

MESSAGE "Bye" VIEW-AS ALERT-BOX.

Modified text is an extract of the original Stack Overflow Documentation

Autorizzato sotto CC BY-SA 3.0

Non affiliato con Stack Overflow

progress-4gl
Interrogazioni

Ricerca…

introduzione

Sintassi

Query di base

Query a più tabelle

Spostare la poizione in una query usando next, first, prev e last